Zsh ZLE file picker

[mdhooge]

Hello

I started implementing a file picker using Zsh ZLE feature (I can't remember where I saw the original idea…).

When you press Alt-N at the CLI prompt, nnn pops-up in file picker mode. You can then select as many files as you want, in different folders, and when you quit, the filenames are inserted where the cursor was.
If the cursor is touching some text, this text is handed to nnn.

nnn-file-widget() {
  # Extract "shell word" at cursor position (respecting quotes)
  local _cursor=$CURSOR
  zle .select-a-shell-word -N

  # Helper
  nnn-pick()
  {
    IFS=$'\n'
    local items=( $(command nnn -p- $1 < "$TTY") )
    if (( #items > 0 )); then
      items=( ${(q-)items} )
      print -n "${(j: :)items} "
    fi
  }

  # Adapt behaviour to buffer content
  if (($CURSOR < _cursor)); then
    # Nothing at cursor, restore state before calling nnn
    CURSOR=${_cursor}
    REGION_ACTIVE=0
    zle -U "$(nnn-pick)"
  else
    # Provide content under cursor to nnn
    zle .kill-region
    local result="$(nnn-pick ${CUTBUFFER## })"
    if (( #result == 0 )); then
      # Nothing selected, restore content
      zle .yank
    else
      # Replace content with what nnn returned
      zle -U " $result"
    fi
  fi

  # TODO single-op undo
  # TODO Handle vicmd properly
  zle .redisplay
}
zle -N nnn-file-widget
bindkey -M vicmd '\en' nnn-file-widget
bindkey -M viins '\en' nnn-file-widget

[N-R-K]

When you press Alt-N at the CLI prompt, nnn pops-up in file picker mode. You can then select as many files as you want, in different folders, and when you quit, the filenames are inserted where the cursor was.

Very cool. I like it.

If the cursor is touching some text, this text is handed to nnn.

But I don't like this part one bit. If your text looks like a dir nnn will end up creating that dir if it didn't exist. I accidentally ended up creating some nonsensical dirs in my $HOME due to it.

[mdhooge]

If your text looks like a dir nnn will end up creating that dir if it didn't exist

Yes, that makes sense. What do you suggest?
It's very easy to just insert the chosen filenames, with a space before and after (to avoid polluting text at cursor). Or maybe test if the text under cursor exists, or at least its dirname…