-
Notifications
You must be signed in to change notification settings - Fork 2
/
cube3d.sed
307 lines (218 loc) · 10.3 KB
/
cube3d.sed
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
#!/usr/bin/sed -f
# internal representation (largely speffz + weird extra characters):
# AaB
# d!b
# DcC
# EeF IiJ MmN QqR
# h@f l#j p$n t%r
# HgG LkK PoO TsS
# UuV
# x^v
# XwW
# initial cube state
1 {
x
s/$/AaBd!bDcCEeFIiJMmNQqRh@fl#jp$nt%rHgGLkKPoOTsSUuVx^vXwW/
x
}
# convert R F2 D' r -> RFFDDDMMMR
s/\/\/.*//
s/[^UDRLFBudrlfbMSExyz'2]//g
s/\(.\)2/\1\1/g
s/\(.\)'/\1\1\1/g
s/x/MMMLLLR/g
s/y/EEEUDDD/g
s/z/SFBBB/g
s/u/EEEU/g
s/d/ED/g
s/l/ML/g
s/r/MMMR/g
s/f/SF/g
s/b/SSSB/g
:move
/^$/ b done
/^U/ {
x
# A B D C D A C B
s/\(.\)\(.\)\(.\)\(...\)\(.\)\(.\)\(.\)/\5\2\1\4\7\6\3/
# a d b c d c a b
s/\(.\)\(.\)\(.\)\(.\)\(.\)\(.\)\(.\)\(.\)/\1\4\3\8\5\2\7\6/
# E I M Q I M Q E
s/\(.\{9\}\)\(.\)\(..\)\(.\)\(..\)\(.\)\(..\)\(.\)/\1\4\3\6\5\8\7\2/
# e i m q i m q e
s/\(.\{10\}\)\(.\)\(..\)\(.\)\(..\)\(.\)\(..\)\(.\)/\1\4\3\6\5\8\7\2/
# F J N R J N R F
s/\(.\{11\}\)\(.\)\(..\)\(.\)\(..\)\(.\)\(..\)\(.\)/\1\4\3\6\5\8\7\2/
b next
}
/^E/ {
x
# h l p t t h l p
s/\(.\{21\}\)\(.\)\(..\)\(.\)\(..\)\(.\)\(..\)\(.\)/\1\8\3\2\5\4\7\6/
# @ # $ % % @ $ %
s/\(.\{22\}\)\(.\)\(..\)\(.\)\(..\)\(.\)\(..\)\(.\)/\1\8\3\2\5\4\7\6/
# f j n r r f j n
s/\(.\{23\}\)\(.\)\(..\)\(.\)\(..\)\(.\)\(..\)\(.\)/\1\8\3\2\5\4\7\6/
b next
}
/^D/ {
x
# U V X W X U W V
s/\(.\{45\}\)\(.\)\(.\)\(.\)\(...\)\(.\)\(.\)\(.\)/\1\6\3\2\5\8\7\4/
# u x v w x w u v
s/\(.\{46\}\)\(.\)\(.\)\(.\)\(.\)\(.\)\(.\)\(.\)/\1\4\3\8\5\2\7\6/
# H L P T T H L P
s/\(.\{33\}\)\(.\)\(..\)\(.\)\(..\)\(.\)\(..\)\(.\)/\1\8\3\2\5\4\7\6/
# g k o s s g k o
s/\(.\{34\}\)\(.\)\(..\)\(.\)\(..\)\(.\)\(..\)\(.\)/\1\8\3\2\5\4\7\6/
# G K O S K O S G
s/\(.\{35\}\)\(.\)\(..\)\(.\)\(..\)\(.\)\(..\)\(.\)/\1\8\3\2\5\4\7\6/
b next
}
/^R/ {
x
# B J T V J V B T
s/\(..\)\(.\)\(.\{11\}\)\(.\)\(.\{27\}\)\(.\)\(....\)\(.\)/\1\4\3\8\5\2\7\6/
# b j t v j v t b
s/\(.\{5\}\)\(.\)\(.\{20\}\)\(.\)\(...\)\(.\)\(.\{19\}\)\(.\)/\1\4\3\8\5\2\7\6/
# C Q K W K C W Q
s/\(.\{8\}\)\(.\)\(.\{9\}\)\(.\)\(.\{19\}\)\(.\)\(.\{14\}\)\(.\)/\1\6\3\2\5\8\7\4/
# M N P O P M O N
s/\(.\{15\}\)\(.\)\(.\)\(.\)\(.\{21\}\)\(.\)\(.\)\(.\)/\1\6\3\2\5\8\7\4/
# m p n o p o m n
s/\(.\{16\}\)\(.\)\(.\{10\}\)\(.\)\(.\)\(.\)\(.\{10\}\)\(.\)/\1\4\3\8\5\2\7\6/
b next
}
/^M/ {
x
# a i s u s a u i
s/\(.\)\(.\)\(.\{11\}\)\(.\)\(.\{29\}\)\(.\)\(..\)\(.\)/\1\6\3\2\5\8\7\4/
# ! # % ^ % ! ^ #
s/\(....\)\(.\)\(.\{20\}\)\(.\)\(.....\)\(.\)\(.\{17\}\)\(.\)/\1\6\3\2\5\8\7\4/
# c q k w q w c k
s/\(.\{7\}\)\(.\)\(.\{11\}\)\(.\)\(.\{17\}\)\(.\)\(.\{14\}\)\(.\)/\1\4\3\8\5\2\7\6/
b next
}
/^L/ {
x
# E F H G H E G F
s/\(.\{9\}\)\(.\)\(.\)\(.\)\(.\{21\}\)\(.\)\(.\)\(.\)/\1\6\3\2\5\8\7\4/
# e h f g h g e f
s/\(.\{10\}\)\(.\)\(.\{10\}\)\(.\)\(.\)\(.\)\(.\{10\}\)\(.\)/\1\4\3\8\5\2\7\6/
# A I S U S A U I
s/\(.\)\(.\{11\}\)\(.\)\(.\{31\}\)\(.\)\(.\)/\5\2\1\4\6\3/
# D R L X R X D L
s/\(......\)\(.\)\(.\{13\}\)\(.\)\(.\{15\}\)\(.\)\(.\{14\}\)\(.\)/\1\4\3\8\5\2\7\6/
# d l r x t d l x
s/\(...\)\(.\)\(.\{20\}\)\(.\)\(.\{7\}\)\(.\)\(.\{15\}\)\(.\)/\1\6\3\2\5\8\7\4/
b next
}
/^F/ {
x
# I J L K L I K J
s/\(.\{12\}\)\(.\)\(.\)\(.\)\(.\{21\}\)\(.\)\(.\)\(.\)/\1\6\3\2\5\8\7\4/
# i l j k l k i j
s/\(.\{13\}\)\(.\)\(.\{10\}\)\(.\)\(.\)\(.\)\(.\{10\}\)\(.\)/\1\4\3\8\5\2\7\6/
# D M G V G D V M
s/\(.\{6\}\)\(.\)\(.\{8\}\)\(.\)\(.\{19\}\)\(.\)\(.\{11\}\)\(.\)/\1\6\3\2\5\8\7\4/
# c f p u f u c p
s/\(.\{7\}\)\(.\)\(.\{15\}\)\(.\)\(...\)\(.\)\(.\{18\}\)\(.\)/\1\4\3\8\5\2\7\6/
# C F P U F U C P
s/\(.\{8\}\)\(.\)\(..\)\(.\)\(.\{27\}\)\(.\)\(.....\)\(.\)/\1\4\3\8\5\2\7\6/
b next
}
/^S/ {
x
# d m g v g d v m
s/\(...\)\(.\)\(.\{12\}\)\(.\)\(.\{17\}\)\(.\)\(.\{15\}\)\(.\)/\1\6\3\2\5\8\7\4/
# ! @ $ ^ @ ^ ! $
s/\(....\)\(.\)\(.\{17\}\)\(.\)\(.....\)\(.\)\(.\{20\}\)\(.\)/\1\4\3\8\5\2\7\6/
# b e o x e x b o
s/\(.....\)\(.\)\(....\)\(.\)\(.\{29\}\)\(.\)\(.\{7\}\)\(.\)/\1\4\3\8\5\2\7\6/
b next
}
/^B/ {
x
# Q R T S T Q S R
s/\(.\{18\}\)\(.\)\(.\)\(.\)\(.\{21\}\)\(.\)\(.\)\(.\)/\1\6\3\2\5\8\7\4/
# q t r s t s q r
s/\(.\{19\}\)\(.\)\(.\{10\}\)\(.\)\(.\)\(.\)\(.\{10\}\)\(.\)/\1\4\3\8\5\2\7\6/
# A N H W N W A H
s/\(.\)\(.\{16\}\)\(.\)\(.\{15\}\)\(.\)\(.\{19\}\)\(.\)/\3\2\7\4\1\6\5/
# a h n w n a w h
s/\(.\)\(.\)\(.\{19\}\)\(.\)\(.\{7\}\)\(.\)\(.\{22\}\)\(.\)/\1\6\3\2\5\8\7\4/
# B E O X O B X E
s/\(..\)\(.\)\(.\{6\}\)\(.\)\(.\{31\}\)\(.\)\(.\{9\}\)\(.\)/\1\6\3\2\5\8\7\4/
}
:next
x
s/.//
b move
:done
x
h
# display
s/$/====\n/
# A V A A V V
s/\(.\).\{46\}\(.\).*/&+++++\1\1+++++====+++++\2\2+++++\n/
# A a d u V v d d A A a a u u V V
s/\(.\)\(.\).\(.\).\{42\}\(.\)\(.\)..\(.\).*/&+++\3\3\1\1\2\2+++====+++\4\4\5\5\6\6+++\n/
# a B d ! D D D d d ! ! a a b b
s/.\(.\)\(.\)\(.\)\(.\).\(.\).*/&+\5\5\3\3\4\4\1\1\2\2+====/
# U u ^ v W U U u u ^ ^ v v W W
s/.\{45\}\(.\)\(.\)..\(.\)\(.\)..\(.\).*/&+\1\1\2\2\3\3\4\4\5\5+\n/
# B ! b D c I N I D D c c ! ! b b B B N
s/..\(.\).\(.\)\(.\)\(.\)\(.\)....\(.\)....\(.\).*/&\6\4\4\5\5\2\2\3\3\1\1\7====/
# G T U x ^ w W G U U x x ^ ^ w w W W T
s/.\{35\}\(.\)......\(.\)..\(.\)..\(.\)\(.\)..\(.\)\(.\).*/&\1\3\3\4\4\5\5\6\6\7\7\2\n/
# b c C I i m N I I i c c C C b b m N N
s/.\{5\}\(.\).\(.\)\(.\).\{3\}\(.\)\(.\)..\(.\)\(.\).*/&\4\4\5\2\2\3\3\1\1\6\7\7====/
# g G T s x X w G G g x x X X w w s T T
s/.\{34\}\(.\)\(.\)......\(.\)\(.\)....\(.\)..\(.\)\(.\).*/&\2\2\1\5\5\6\6\7\7\4\3\3\n/
# C I i J M m N l n l I i i J C C M m m N n
s/.\{8\}\(.\)...\(.\)\(.\)\(.\)\(.\)\(.\)\(.\)......\(.\)....\(.\).*/&\8\2\3\3\4\1\1\5\6\6\7\9====/
# f t H g G T s S X f G g g H X X S s s T t
s/.\{23\}\(.\)......\(.\)..\(.\)\(.\)\(.\)......\(.\)\(.\)\(.\).\{6\}\(.\).*/&\1\5\4\4\3\9\9\8\7\7\6\2\n/
# i J M m l # $ n l l # i J J M M m $ n n
s/.\{13\}\(.\)\(.\)\(.\)\(.\).\{7\}\(.\)\(.\)..\(.\)\(.\).*/&\5\5\6\1\2\2\3\3\4\7\8\8====/
# h @ f t % H g s S f f @ g H H S S s % t t
s/.\{21\}\(.\)\(.\)\(.\)......\(.\)\(.\).\(.\)\(.\).\{8\}\(.\)\(.\).*/&\3\3\2\7\6\6\9\9\8\5\4\4\n/
# J l # j L L l # # j J
s/.\{14\}\(.\).\{9\}\(.\)\(.\)\(.\).\{9\}\(.\).*/&\5\2\3\3\4\1/
# M p $ n O M p $ $ n O
s/.\{15\}\(.\).\{11\}\(.\)\(.\)\(.\).\{11\}\(.\).*/&\1\2\3\3\4\5====/
# F h @ f H F f @ @ h H
s/.\{11\}\(.\).\{9\}\(.\)\(.\)\(.\).\{9\}\(.\).*/&\1\4\3\3\2\5/
# Q t % r S S r % % t Q
s/.\{18\}\(.\).\{11\}\(.\)\(.\)\(.\).\{11\}\(.\).*/&\5\4\3\3\2\1\n/
# # j p $ L k o O L L k # j j p p $ o O O
s/.\{25\}\(.\)\(.\)\(.\)\(.\).\{7\}\(.\)\(.\).\{2\}\(.\)\(.\).*/&\5\5\6\1\2\2\3\3\4\7\8\8====/
# e F Q q h @ % r F F e @ h h r r % q Q Q
s/.\{10\}\(.\)\(.\).\{6\}\(.\)\(.\).\(.\)\(.\).\{8\}\(.\)\(.\).*/&\2\2\1\6\5\5\8\8\7\4\3\3\n/
# j p L k K P o O L k k K j p P o o O
s/.\{26\}\(.\)\(.\).\{8\}\(.\)\(.\)\(.\)\(.\)\(.\)\(.\).*/&+\3\4\4\5\1\2\6\7\7\8+====/
# E e F Q q R h r F e e E h r R q q Q
s/.\{9\}\(.\)\(.\)\(.\).\{6\}\(.\)\(.\)\(.\)\(.\).\{10\}\(.\).*/&+\3\2\2\1\7\8\6\5\5\4+\n/
# E e q R k K P o k K K P P o e E E R R q
s/.\{9\}\(.\)\(.\).\{8\}\(.\)\(.\).\{16\}\(.\)\(.\)\(.\)\(.\).*/&+++\5\6\6\7\7\8+++====+++\2\1\1\4\4\3+++\n/
# E R K P K P E R
s/.\{9\}\(.\).\{10\}\(.\).\{17\}\(.\)\(.\).*/&+++++\3\4+++++====+++++\1\2+++++\n/
# there's probably a smarter way to do this
s/\n\(.\{28\}\)\n\(.\{28\}\)/\n,,,,\1\n,,\2,,/g
s/.*====\n/\n/
s/\([^[:space:]]\)\([^[:space:]]\)\([^[:space:]]\)\([^[:space:]]\)/\x1b[38;5;\1;48;5;\2_🭞🭜🭘\x1b[38;5;\3;48;5;\4_🭍🭑🬽/g
s/[ABCDabcd!]/231/g
s/[EFGHefgh@]/202/g
s/[IJKLijkl#]/34/g
s/[MNOPmnop$]/196/g
s/[QRSTqrst%]/21/g
s/[UVWXuvwx^]/220/g
y/_/m/
s/\n/\x1b[m\n/g
s/.......,......,....//g
s/[+=]/16/g
s/\n//
s/\n$//
p
g
d