Why Is this Infeasible?

[chelseas]

when I run this code

using InfiniteOpt, Ipopt
using Distributions, LinearAlgebra

m = InfiniteModel(optimizer_with_attributes(Ipopt.Optimizer))
@infinite_parameter(m, t in [0,60], num_supports=100)

@variables(m, begin
    # state variables
    x, Infinite(t)
    y, Infinite(t)
    vx, Infinite(t)
    vy, Infinite(t)
    b, Infinite(t)
    # control variables
    ax, Infinite(t), (start = 0)
    ay, Infinite(t), (start = 0)
end)

# objective
# d = MvNormal(zeros(2),[1. 0; 0 1]) #  can't use this
info(x,y) = exp(-.5*(([x;y] - [-1;1.])'*([x;y] - [-1;1.])))/(2*π) + exp(-.5*(([x;y] - [1;-1.])'*([x;y] - [1;-1.])))/(2*π) 
@objective(m, Max, ∫(info(x,y), t))

# initial conditions 
@constraint(m, x(0) == -5)
@constraint(m, y(0) == -5)
@constraint(m, vx(0) == 0)
@constraint(m, vy(0) == 0)
@constraint(m, b(0) == 100)

# set terminal conditions 
@constraint(m, x(60) == x(0))
@constraint(m, y(60) == y(0))
@constraint(m, vx(60) == 0)
@constraint(m, vy(60) == 0)
@constraint(m, ax(60) == 0)
@constraint(m, ay(60) == 0)

# define dynamics 
@constraint(m, ∂(x, t) == vx)
@constraint(m, ∂(y, t) == vy)
@constraint(m, ∂(vx, t) == ax)
@constraint(m, ∂(vy, t) == ay)
@constraint(m, ∂(b, t) == -.25*t)

# battery constraint 
@constraint(m, b(t) >= 0)

@time optimize!(m)

# plotting
x_opt = value.(x)
y_opt = value.(y)
# info 
xr = range(-10,10,length=100)
yr = range(-10,10,length=100) 
z = (info.(xr',yr));
using Plots
pythonplot()
contourf(xr,yr,z, color=:turbo, levels=20)
plot!(x_opt, y_opt, label= "trajectory")
xlabel!("x")
ylabel!("y")

plot(value.(t), value.(b), label="b")
plot!(value.(t), value.(x), label="x")
plot!(value.(t), value.(y), label="y")

plot(value.(t), value.(vx), label="vx")
plot!(value.(t), value.(vy), label="vy")

plot(value.(t), value.(ax), label="ax")
plot!(value.(t), value.(ay), label="ay")

I get:

Total seconds in IPOPT                               = 0.102

EXIT: Converged to a point of local infeasibility. Problem may be infeasible.
  0.241051 seconds (372.15 k allocations: 19.658 MiB, 9.60% gc time)

Why?

[pulsipher]

Converging to a point of infeasibility with Ipopt typically is caused by one of two things:

1. No values of the variables exist to satisfy all the constraints
2. Ipopt couldn't find a feasible point with the starting point provided.

I suspect in this case, the problem is 2. It is important to provide a good initial guess for all variables if possible to help Ipopt converge. I would recommend simulating your ODE system with a fixed control policy and then use those values to initialize the optimization model.

[pulsipher]

For example here is what I have done in the past with the SEIR optimal control example:

using InfiniteOpt, Ipopt, DifferentialEquations

# Set the SEIR parameters
γ, β, N, ξ = 0.303, 0.727, 1e5, 0.3
tf = 200
e0, i0, r0, s0 = 1 / N, 0, 0, 1 - 1 / N

# Simulate ODEs
u_sim = 0.5
function odes!(dx, x, p, t)
    dx[1] = -(1 - u_sim) * β * x[1] * x[3]
    dx[2] = (1 - u_sim) * β * x[1] * x[3] - ξ * x[2]
    dx[3] = ξ * x[2] - γ * x[3]
    dx[4] = γ * x[3]
end
prob = ODEProblem(odes!, [s0, e0, i0, r0], (0, tf))
sol = solve(prob)
guess_trajs = [(t) -> sol(t)[i] for i in 1:4] # functions of time

# Setup the model 
model = InfiniteModel(Ipopt.Optimizer)

# Define the infinite parameter
@infinite_parameter(model, t ∈ [0, tf], num_supports = 51)

# Add the variables
@variable(model, 0 ≤ s ≤ 1, Infinite(t), start = guess_trajs[1])
@variable(model, 0 ≤ e ≤ 1, Infinite(t), start = guess_trajs[2])
@variable(model, 0 ≤ i ≤ 1, Infinite(t), start = guess_trajs[3])
@variable(model, 0 ≤ r ≤ 1, Infinite(t), start = guess_trajs[4])
@variable(model, 0 ≤ u ≤ 0.8, Infinite(t), start = u_sim)

# Define the objective
@objective(model, Min, ∫(u, t))

# Define the initial conditions
@constraint(model, s(0) == s0)
@constraint(model, e(0) == e0)
@constraint(model, i(0) == i0)
@constraint(model, r(0) == r0)

# Define the SEIR equations
@constraint(model, ∂(s, t) == -(1 - u) * β * s * i)
@constraint(model, ∂(e, t) == (1 - u) * β * s * i - ξ * e)
@constraint(model, ∂(i, t) == ξ * e - γ * i)
@constraint(model, ∂(r, t) == γ * i)

# Define the infection rate limit
@constraint(model, i ≤ 0.02)

# solve it
optimize!(model

[chelseas]

When I pass These as starting points:

@variables(m, begin
    # state variables
    x, Infinite(t), (start = t -> -5)
    y, Infinite(t), (start = t -> -5)
    vx, Infinite(t), (start = t -> 0)
    vy, Infinite(t), (start = t -> 0)
    b, Infinite(t), (start = t -> 100 - 0.25*t)
    # control variables
    ax, Infinite(t), (start = t -> 0)
    ay, Infinite(t), (start = t -> 0)
end)

which corresponds to sitting still as b decreases.
I still get that it converged to an infeasible solution :///

[pulsipher]

Hi @chelseas, I took a closer look and found that the problem is that your problem is infeasible. The culprit is the battery ODE:

using InfiniteOpt, Ipopt

m = InfiniteModel(Ipopt.Optimizer)
@infinite_parameter(m, t in [0,60], num_supports = 100)

@variable(m, b, Infinite(t))

@constraint(m, b(0) == 100)
@constraint(m, ∂(b, t) == -.25*t)

@constraint(m, b >= 0) # this constraint makes it infeasible

optimize!(m)

Here, the ODE for b has no degrees of freedom and is totally determined with the initial condition. It's solution must be negative after a certain time. If we remove that constraint it works:

using InfiniteOpt, Ipopt

m = InfiniteModel(Ipopt.Optimizer)
@infinite_parameter(m, t in [0,60], num_supports = 100)

@variable(m, b, Infinite(t))

@constraint(m, b(0) == 100)
@constraint(m, ∂(b, t) == -.25*t)

optimize!(m)

Note that he final value of b ends up being -354.54. Naturally, this doesn't make sense for the battery charge state, so this appears to be a modeling error.

Moreover, as modeled your b has no effect on the objective or the other constraints, so it can just be removed. The bigger question is what problem are you trying to solve?