build.gradle

plugins {
    id 'fabric-loom' version '1.7-SNAPSHOT'
    id 'maven-publish'
    id "io.freefair.lombok" version "8.6"
}

version = "${project.mod_version}-${project.minecraft_version}"
group = project.maven_group

base {
    archivesName = project.archives_base_name
}

repositories {
    // Add repositories to retrieve artifacts from in here.
    // You should only use this when depending on other mods because
    // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
    // See https://docs.gradle.org/current/userguide/declaring_repositories.html
    // for more information about repositories.
    mavenCentral()
    maven { url 'https://jitpack.io' }
    maven {
        name = 'Ladysnake Mods'
        url = 'https://maven.ladysnake.org/releases'
        content {
            includeGroup 'org.ladysnake'
            includeGroupByRegex 'io\\.github\\.onyxstudios.*'
        }
    }

    maven {
        url 'https://maven.terraformersmc.com/releases/'
    }
}


loom {
    mods {
        "darkkore-reborn" {
            sourceSet sourceSets.main
        }
    }

}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API. This is technically optional, but you probably want it anyway.
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    implementation "com.electronwill.night-config:toml:${project.night_config_version}"
    implementation "com.electronwill.night-config:json:${project.night_config_version}"

    implementation "com.github.DarkKronicle.Konstruct:addons:${project.konstruct_version}"
    implementation "com.github.DarkKronicle.Konstruct:core:${project.konstruct_version}"

    modImplementation("org.ladysnake:satin:${satin_version}") {
        exclude group: 'net.fabricmc.fabric-api'
    }

    include "org.ladysnake:satin:${satin_version}"

    include "com.github.DarkKronicle.Konstruct:addons:${project.konstruct_version}"
    include "com.github.DarkKronicle.Konstruct:core:${project.konstruct_version}"

    include "com.electronwill.night-config:toml:${project.night_config_version}"
    include "com.electronwill.night-config:json:${project.night_config_version}"
    include "com.electronwill.night-config:core:${project.night_config_version}"

    modCompileOnly "com.terraformersmc:modmenu:${project.modmenu_version}"

    implementation "org.apiguardian:apiguardian-api:1.1.2"
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.annotationProcessorPath = configurations.annotationProcessor
    it.options.release = 21
}



java {
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()

    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.base.archivesName.get()}" }
    }
}

// configure the maven publication
publishing {
    publications {
        create("mavenJava", MavenPublication) {
            artifactId = project.archives_base_name
            from components.java
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
}