build.gradle

plugins {
  id 'groovy'
}

repositories {

  mavenCentral()
  maven {
    url 'https://repo.jenkins-ci.org/public/'
  }
}

test {
  systemProperty 'groovy.grape.enable', 'false'
  useJUnitPlatform()
}

compileGroovy {
  groovyOptions.forkOptions.jvmArgs = [ '-Dgroovy.grape.enable=false' ]
}
compileTestGroovy {
  groovyOptions.forkOptions.jvmArgs = [ '-Dgroovy.grape.enable=false' ]
}

dependencies {
  implementation group: 'org.codehaus.groovy', name: 'groovy-all', version: '2.5.22'
  implementation group: 'org.codehaus.groovy', name: 'groovy-dateutil', version: '2.5.22'

  implementation group: 'com.cloudbees', name: 'groovy-cps', version: '3773.v505e0052522c'
  testImplementation group: 'org.apache.commons', name: 'commons-lang3', version: '3.12.0'

  implementation group: 'org.jenkins-ci.main', name: 'jenkins-core', version: '2.409'
  implementation group: 'org.jenkins-ci.plugins.workflow', name: 'workflow-step-api', version: '625.vd896b_f445a_f8', ext: 'jar'
  implementation group: 'org.jenkinsci.plugins', name: 'pipeline-model-definition', version: '2.2169.vee7cd0efc13e', ext: 'jar'
  implementation 'org.jenkins-ci.plugins:job-dsl-core:1.87'
  implementation group: 'org.jenkins-ci.plugins', name: 'scm-api', version: '616.ve67136f6c77d', ext: 'jar'

  testImplementation group: 'org.spockframework', name: 'spock-core', version: '2.3-groovy-2.5'
  testImplementation group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.16.0'

  testImplementation group: 'com.lesfurets', name: 'jenkins-pipeline-unit', version: '1.17'
  testImplementation group: 'org.assertj', name: 'assertj-core', version: '3.24.2'
  testImplementation group: 'net.javacrumbs.json-unit', name: 'json-unit-fluent', version: '2.36.0'

  testRuntimeOnly 'org.objenesis:objenesis:3.3'
}


sourceSets {
  jobs {
    groovy {
      srcDirs 'jobs'
      compileClasspath += main.compileClasspath
    }
  }

  main {
    groovy {
      srcDirs = ['src']
    }
  }
  test {
    groovy {
      srcDirs = ['test']
    }
    resources {
      srcDirs = ['testResources']
    }

  }
}