build.gradle

buildscript {
    ext.kotlin_version = '1.3.61'
    repositories {
        jcenter()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

apply plugin: 'java'
apply plugin: 'kotlin'

sourceSets {
    main.kotlin.srcDirs = [ 'src/main/kotlin' ]
}

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
    maven { url "https://dl.bintray.com/kyonifer/maven" }
    jcenter()
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlin_version"

    compile 'com.github.kwebio:kweb-core:0.5.17'

    //compile 'com.google.cloud:google-cloud-logging-logback:0.116.0-alpha'
    compile group: 'org.slf4j', name: 'slf4j-simple', version: '1.7.30'

    compile 'com.ibm.icu:icu4j:65.1'
    compile group: "com.kyonifer", name:"koma-core-ejml", version: "0.12"
    compile group: "com.kyonifer", name:"koma-plotting", version: "0.12"
    compile 'com.github.ajalt:colormath:1.4.0'
    compile 'com.beust:klaxon:5.0.1'
}

compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}
compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

jar {
    manifest {
        attributes 'Main-Class': 'com.github.heathwinning.AppKt'
    }
    from {
        configurations.compile.collect {
            it.isDirectory() ? it : zipTree(it)
        }
    }
}

task dockerBuild {
    dependsOn jar
    doLast {
        exec {
            commandLine 'docker', 'build', '-t', 'moneypools', '.'
        }
    }
}

task dockerRun {
    dependsOn dockerBuild
    doLast {
        exec {
            commandLine 'docker', 'run', '-m512M', '--cpus', '2', '-p', '8080:8080', '--rm', 'moneypools'
        }
    }
}

task gaeDeploy {
    dependsOn dockerBuild
    doLast {
        exec {
            commandLine 'gcloud', 'app', 'deploy'
        }
    }
}