-
Notifications
You must be signed in to change notification settings - Fork 0
/
for_tetrahedra2.f90
2891 lines (2841 loc) · 109 KB
/
for_tetrahedra2.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!----------- Routines for simple tetrahedron method over irreducible tetrahedra --------
subroutine intweight1t(w, et,ef)
! This subroutine calculates the contribution to the integration weights at the four corners of a tetrahedron.
! The energies have to be given in increasing energy order.
implicit none
real*8, intent(out):: w(4) ! Weight at each corner
real*8, intent(in) :: et(4) ! Eigenenergies at the corners of the tetrahedron.
real*8, intent(in) :: ef ! Fermi energy.
! locals
integer :: index, i
real*8 :: c1,c2,c3,vo4
real*8 :: f31,f41,f32,f42
real*8 :: e31,e41,e32,e42
if( et(4) <= ef) then ! all energies above ef
index = 4
else
index=0
do i=1,4 ! how many corners of tetrahedra below ef
if( et(i) <= ef) index = index + 1
enddo
endif
vo4 = 1.0d0/4.0d0
select case(index)
case(0) ! all states are unoccupied
w(:) = 0.0d0
case(1) ! only the lowest energy is occupied.
do i=2,4
w(i) = (ef-et(1))/(et(i)-et(1))
enddo
c1 = w(2) * w(3) * w(4)
w(2) = c1 * w(2)
w(3) = c1 * w(3)
w(4) = c1 * w(4)
w(1) = 4.0d0 * c1 - w(2) - w(3) - w(4)
case(2) ! the two lower energies are occupied
f31 = (ef-et(1))/(et(3)-et(1))
f41 = (ef-et(1))/(et(4)-et(1))
f32 = (ef-et(2))/(et(3)-et(2))
f42 = (ef-et(2))/(et(4)-et(2))
e31 = (et(3)-ef)/(et(3)-et(1))
e41 = (et(4)-ef)/(et(4)-et(1))
e32 = (et(3)-ef)/(et(3)-et(2))
e42 = (et(4)-ef)/(et(4)-et(2))
c1 = f41 * f31
c2 = f41 * f32 * e31
c3 = f42 * f32 * e41
w(1) = c1 + (c1+c2)*e31 + (c1+c2+c3)*e41
w(2) = c1+c2+c3 + (c2+c3)*e32 + c3*e42
w(3) = (c1+c2)*f31 + (c2+c3)*f32
w(4) = (c1+c2+c3)*f41 + c3*f31
case(3) ! Only the highest energy is unoccupied
do i=1,3
w(i) = (et(4)-ef)/(et(4)-et(i))
enddo
c1 = w(1) * w(2) * w(3)
w(4) = 1.0d0 - c1 * (4.0d0 - w(1)-w(2)-w(3))
w(1) = 1.0d0 - c1 * w(1)
w(2) = 1.0d0 - c1 * w(2)
w(3) = 1.0d0 - c1 * w(3)
case(4) ! All states are occupied
w(:) = 1.d0
end select
w(:) = w(:)*vo4
end subroutine intweight1t
subroutine bloechlcor(blcor,et,ef)
! This subroutine calculates the correction to the integration weights for
! the improved tetrahedron method according to
! Bl\"ochl {\it et al}, Phys. Rev. B, {\bf 49}, 16223 (1994). The energies at the
! corner of the tetrahedron have to be given in increasing order.
implicit none
real*8, intent(out):: blcor(4) ! The correction to the integration weights
real*8, intent(in) :: et(4) ! Eigenenergies at the corners of the tetrahedron.
real*8, intent(in) :: ef ! the fermi energy
!
integer :: i, j, jm4, index
real*8 :: dte
real*8 :: sde
real*8, external :: dos1t
intrinsic mod
!
dte = dos1t(et,ef)/4.0d+1
blcor(:)=0.0d0
if(et(4) <= ef) then
index=4
else
index=0
do i=1,4
if (et(i) <= ef) index = index + 1
enddo
endif
select case(index)
case(0,4)
continue
case(1,2,3)
do i=1,4
sde = 0.0d0
do j=i,i+2
jm4=mod(j,4)+1
sde=sde +et(jm4)
enddo
sde=sde-3.0d0*et(i)
blcor(i)=sde*dte
enddo
end select
end subroutine bloechlcor
real*8 function intdos1t(et,ei)
! This subroutine calculates the contribution to the integrated density of states at an energy $\epsilon = $ \verb"ei"
! of one tetrahedron. The energies at the corner of the tetrahedron have to be given in increasing order.
!
implicit none
real*8, intent(in) :: et(4) ! Eigenenergies at the corners of the tetrahedron.
real*8, intent(in) :: ei ! energy at which the contribution to the DOS is calculated
! locals
integer :: index, i
real*8 :: br,denom,eij
real*8 :: e21,e31,e41,e32,e42,e43
!
if(et(4) <= ei) then
index = 4
else
index = 0
do i=1,4
if(et(i) <= ei) index = index + 1
enddo
endif
intdos1t = 0.0d0
select case(index)
case(0) ! all states are above ei
intdos1t = 0.0d0
case(1) ! e1 < ei < e2.
e21 = et(2)-et(1)
e31 = et(3)-et(1)
e41 = et(4)-et(1)
eij = ei -et(1)
denom = e21*e31*e41
intdos1t = eij*eij*eij/denom
case(2) ! e2 < ei < e3
e21 = et(2)-et(1)
e31 = et(3)-et(1)
e41 = et(4)-et(1)
e32 = et(3)-et(2)
e42 = et(4)-et(2)
eij = ei -et(2)
denom = e32*e42
br = e21*e21 + 3.0d0*eij*e21 + 3.0d0*eij*eij - (e31+e42)*eij*eij*eij/denom
denom = e31*e41
intdos1t = br/denom
case(3) ! e3 < ei < e4
e43 = et(4)-et(3)
e42 = et(4)-et(2)
e41 = et(4)-et(1)
eij = et(4)-ei
denom = e41*e42*e43
intdos1t = (1.0d0-eij*eij*eij/denom)
case(4) ! e4 < ei
intdos1t = 1.0d0
end select
end function intdos1t
real*8 function dos1t(et,ei)
! This subroutine calculates the contribution to the density of states at
! an energy $\epsilon = $ \verb"ei" of one tetrahedron, according to
! Bl\"ochl {\it et al}, Phys. Rev. B, {\bf 49}, 16223 (1994). The energies at the
! corner of the tetrahedron have to be given in increasing order.
implicit none
real*8, intent(in) :: et(4) ! Eigenenergies at the corners of the tetrahedron.
real*8, intent(in) :: ei ! energy at which the contribution to the dos1t is calculated
!
integer(4) :: index,i
real(8) :: br,denom,eij
real(8) :: e21,e31,e41,e32,e42,e43
if(et(4) <= ei)then
index=4
else
index=0
do i=1,4
if(et(i) <= ei) index = index + 1
enddo
endif
dos1t = 0.0d0
select case(index)
case(0,4) ! all states are either below or above ei
dos1t = 0.0d0
case(1) ! only the lowest energy is occupied.
e21 = et(2) - et(1)
e31 = et(3) - et(1)
e41 = et(4) - et(1)
eij = ei - et(1)
denom = e21*e31*e41
dos1t = 3.0d0*eij*eij/denom
case(2) ! e2 < ei < e3
e21 = et(2) - et(1)
e31 = et(3) - et(1)
e41 = et(4) - et(1)
e32 = et(3) - et(2)
e42 = et(4) - et(2)
eij = ei - et(2)
denom = e32*e42
br = e21+2.0d0*eij-(e31+e42)*eij*eij/denom
denom = e31*e41
dos1t = 3.0d0*br/denom
case(3) ! e3 < ei < e4
e43 = et(4) - et(3)
e42 = et(4) - et(2)
e41 = et(4) - et(1)
eij = et(4) - ei
denom = e41*e42*e43
dos1t = 3.0d0*eij*eij/denom
end select
end function dos1t
subroutine ksurf(wgh, et, ef)
! This subroutine calculates the integration over an energy surface in the
! k-mesh, the area of the Fermi surface inside the tetrahedron is calculated
! which is the essential item to decide the weight of the integration over
! each vertex.
! The energies have to be given in increasing energy order.
implicit none
real*8, intent(out) :: wgh(4) ! the weight at each corner
real*8, intent(in) :: et(4) ! the band energies or energy difference at k
real*8, intent(in) :: ef ! the energy or energy differnce surface
!
integer :: i, indx ! indx=Number of nodes below ef
real*8 :: delta21, delta31, delta41, delta32, delta42, delta43 ! energy differences
real*8 :: deles1, deles2, deles3, deles4 ! ef-eo(i)
real*8 :: den0 ! denominators
real*8 :: num0, num1 ! numerators
real*8 :: wt ! total weight
!
wgh(:) = 0.0d0
if ( ef < et(1) ) then
indx=0
else
indx=1
do i=2,4
if( et(i) <= ef) indx = indx + 1
enddo
endif
select case(indx)
case(0,4)
continue
case(1) ! Only et(1)< ef, one triangle
deles1 = ef - et(1)
delta21 = et(2)-et(1)
delta31 = et(3)-et(1)
delta41 = et(4)-et(1)
den0 = 6.0d0*delta21*delta31*delta41
num0 = deles1*deles1
! total wgh
wt = 3.0d0*num0/den0
num1 = num0*deles1
wgh(2) = num1/(delta21*den0)
wgh(3) = num1/(delta31*den0)
wgh(4) = num1/(delta41*den0)
wgh(1) = wt - wgh(2) - wgh(3) - wgh(4)
case(2) ! et(1)<et(2)<ef, two triangles
deles1 = ef - et(1)
deles2 = ef - et(2)
deles3 = et(3) - ef
deles4 = et(4) - ef
delta21 = et(2) - et(1)
delta31 = et(3) - et(1)
delta41 = et(4) - et(1)
delta32 = et(3) - et(2)
delta42 = et(4) - et(2)
delta43 = et(4) - et(3)
! total wgh
num0 = deles1*deles3 / (6.0d0*delta31*delta32*delta41)
num1 = deles2*deles4 / (6.0d0*delta32*delta41*delta42)
wt = 3.0d0 * (num0 + num1)
!
wgh(2) = deles3/delta32 * num0 + (deles3*delta42+deles2*delta31)/(delta41*delta42) * num1
wgh(3) = (deles1*delta32+deles2*delta31)/(delta31*delta32) * num0 + deles2/(delta32) * num1
wgh(4) = deles1/(delta41) * num0 + (deles1*delta42+deles2*delta41)/(delta41*delta42) * num1
wgh(1) = wt - wgh(2)-wgh(3)-wgh(4)
case(3) ! ee(1), ee(2) and ee(3) < efer, one triangle.
deles4 = et(4) - ef
delta41 = et(4) - et(1)
delta42 = et(4) - et(2)
delta43 = et(4) - et(3)
den0 = 6.0d0*delta41*delta42*delta43
if ( den0 < 1.0e-12) then
write(6,*)'ERROR in ksurf: flat band'
write(6,*) et
stop 'flat band'
endif
num0 = deles4*deles4
! total wgh
wt = num0* 3.0d0/den0
num1 = num0*deles4/den0
wgh(1) = num1/delta41
wgh(2) = num1/delta42
wgh(3) = num1/delta43
wgh(4) = wt - wgh(1)-wgh(2)-wgh(3)
end select
end subroutine ksurf
!----------- Routines for convolution tetrahedron method over k and k-q points --------
subroutine convw(ef,omgga,sgnfrq,cwt, iop_bzintq, enk, wtet, tetc, tetln, vol_small_tetra, nbnd, nkp, ntet, x_i, w_i, n_i)
! This subroutine calculates the integration weight of each k-point for all band pairs.
!
! if sgnfrq == 1: normal q-dependent bulk integration.
! Integrate[ fw_i(x,y,z) , {z,0,1},{y,0,1-z},{x,0,1-y-z}]
! where fw_i(x,y,z) = [(1-x-y-z), x, y, z] corresponds to the four corners of tetrahedra.
!
! if sgnfrq == 2: weights for the Polarization with real frequencies
! Real{ Integrate[ fw_i(x,y,z) * 1/( omg - E(x,y,z) + 0.01*1j), {z,0,1},{y,0,1-z},{x,0,1-y-z}] }, where fw_i(x,y,z) = [(1-x-y-z), x, y, z] corresponds to the four corners of tetrahedra.
! if iop_bzintq==-1: numeric integration, which needs x_i,w_i
! else: analytic integrationn
!
! if sgnfrq == 3: weights for the Polarization with imaginary frequencies.
! 2Real{ Integrate[ fw_i(x,y,z) * 1/( 1j*omg - E(x,y,z) ), {z,0,1},{y,0,1-z},{x,0,1-y-z}] }, where fw_i(x,y,z) = [(1-x-y-z), x, y, z] corresponds to the four corners of tetrahedra.
! if iop_bzintq==-1: numeric integration, which needs x_i,w_i
! else: analytic integration
!
! if sgnfrq == 4: the q-dependent surface integratio (the surface is defined by e_jb-e_ib=omeg.
! Adds surface integration for metallic case
!
! E(k)==ee1==e is the (partially) occupied band and E(k-q)==ee2==f is the (partially) empty band
!use order
!use tetra_internal
implicit none
integer, intent(in) :: nbnd, ntet, nkp
real(8), intent(out) :: cwt(nbnd,nbnd,nkp) ! the weight of each k-point for each band
real(8), intent(in) :: ef ! fermi energy
real(8), intent(in) :: omgga
integer, intent(in) :: sgnfrq
!
real*8, intent(in) :: enk(nbnd,nkp) ! Band energies
integer, intent(in) :: tetc(4,ntet) ! tetrahedra index
real*8, intent(in) :: wtet(ntet) ! weight of each tetrahedra
integer, intent(in) :: tetln(ntet) ! link between k and k-q tetrahedra
real*8, intent(out) :: vol_small_tetra
integer, intent(in) :: iop_bzintq ! which mode of calculation
real(8), intent(in) :: x_i(n_i), w_i(n_i) ! x-positions and weights for gauss integration quadrature in 1D
integer, intent(in) :: n_i
!
integer :: itet, i, ib, jb, kin
integer :: ik1(4), ik2(4)
real(8) :: term, wwwt
real(8) :: ee1(4), ee2(4), w1t(4), wcor(4)
external intweight1t
external convw1t
external convw1tsurf
external bloechlcor
!
intrinsic maxval
intrinsic minval
!
! tetln, vol_small_tetra, iop_bzintq, x_i, w_i, n_i
cwt = 0.0d0
wwwt = 0.0d0
select case (sgnfrq)
case(1) ! normal q-dependent bulk integration
! locals : itet, ib, i, ee1, jb, ee2, kin, w1t, wcor, ik1, vol_small_tetra,
! cwt should be accumulative we mak cwt shared
! shared enk, tetc, wtet, x_i, w_i, n_i
do itet=1,ntet
do ib=1,nbnd
do i=1,4
ee1(i) = enk( ib,tetc(i,itet)+1 )
enddo
if( maxval(ee1) < ef) then ! ee1 is fully occupied
do jb=1,nbnd
do i=1,4
ee2(i)=enk( jb, tetc(i,tetln(itet))+1 )
enddo
if( minval(ee2) > ef) then ! ee2 is completely empty
do i=1,4
kin = tetc(i,itet) + 1
cwt(ib,jb,kin) = cwt(ib,jb,kin) + wtet(itet)/4.0d0
enddo
else if ( maxval(ee2) > ef) then ! ee2 partially occupied
ee2(1:4) = ef-ee2(1:4) ! now turn to occupied with patially empty case, so that standard bz-integration works
w1t(1:4) = 0.0d0
wcor(1:4) = 0.0d0
call binary_insertion_sort(ee2,4) !call sort(4,ee2,ik2)
call intweight1t(w1t, ee2, 0.0d0)
call bloechlcor(wcor, ee2, 0.0d0)
do i=1,4
kin = tetc(i,itet) + 1
cwt(ib,jb,kin) = cwt(ib,jb,kin) + (w1t(i)+wcor(i))*wtet(itet)
enddo
endif
enddo
else if(minval(ee1) <= ef) then ! ee1 is partially occupied
do jb=1,nbnd
do i=1,4
ee2(i) = enk( jb, tetc(i,tetln(itet))+1 )
enddo
if ( minval(ee2) > ef ) then ! ee2 is completely empty
w1t(1:4) = 0.0d0
wcor(1:4) = 0.0d0
call binary_insertion_sort_indx(ik1, ee1, 4) ! call sort(4,ee1,ik1)
call intweight1t(w1t, ee1, ef )
call bloechlcor(wcor, ee1, ef )
do i=1,4
kin = tetc( ik1(i), itet) + 1
cwt(ib,jb,kin) = cwt(ib,jb,kin) + ( w1t(i) + wcor(i) ) * wtet(itet)
enddo
else ! ee2 is also partially empty, hence both ee1 and ee2 are partially occupied
w1t(1:4)=0.0d0
call convw1t(ee1,ee2,ef,w1t, omgga, sgnfrq, vol_small_tetra, iop_bzintq, x_i, w_i, n_i)
do i=1,4
kin = tetc(i,itet) + 1
cwt(ib,jb,kin) = cwt(ib,jb,kin) + w1t(i)*6*wtet(itet)
enddo
endif
enddo
endif
enddo
enddo ! itet
case(2:4) ! for the q-dependent bulk integration for Polarization
! locals : itet, ib, i, ee1, jb, ee2, kin, w1t, vol_small_tetra,
! cwt should be accumulative we mak cwt shared
! shared enk, tetc, wtet, x_i, w_i, n_i
! ee1 is the (partially) occupied band and ee2 is the (partially) empty band
do itet=1,ntet
!$OMP PARALLEL DO PRIVATE(ib, i, ee1, jb, ee2, kin, w1t, vol_small_tetra)&
!$OMP& SHARED(cwt)&
!$OMP& SCHEDULE(STATIC)
do ib=1,nbnd ! occupied band
do i=1,4
ee1(i) = enk( ib, tetc(i,itet)+1 )
enddo
if(minval(ee1) > ef) cycle ! ee1 is completely empty => value is zero because ee2 is empty as well
!write(6,'(A,I4,2x,4I4)') 'tetcorn=', itet, ((tetc(i,itet)+1),i=1,4)
!write(6,'(A,F7.4,1x,A,I4,1x,A,I3,1x,A,4F10.7)') 'om=', omgga, 'itet=', itet, 'ib=', ib, 'ee1=', ee1(:)
do jb=1,nbnd ! unoccupied band
do i=1,4
ee2(i) = enk( jb, tetc(i,tetln(itet))+1 )
enddo
if(maxval(ee2) <= ef) cycle ! ee2 is completely occupied =>0, because ee2 should be empty
!write(6,'(A,3I4,2x,4F10.7,2x,4F10.7)') 'ee=', itet, ib, jb, ee1(:), ee2(:)
w1t(1:4) = 0.0d0
call convw1t(ee1,ee2,ef,w1t, omgga, sgnfrq, vol_small_tetra, iop_bzintq, x_i, w_i, n_i)
do i=1,4
kin = tetc(i,itet) + 1
cwt(ib,jb,kin) = cwt(ib,jb,kin) + w1t(i)*6*wtet(itet)
enddo
!write(6,'(A,F7.4,1x,A,I4,1x,A,I3,1x,A,4F10.7,1x,A,4F12.7)') 'om=', omgga, 'itet=', itet, 'jb=', jb, 'ee1=', ee2(:), 'w=', w1t(:)*(6*wtet(itet))
enddo
enddo
!$OMP END PARALLEL DO
enddo
case default
continue
end select
return
end subroutine convw
subroutine convw1t(e, f, ef, weight, &
& omgga, sgnfrq, vol_small_tetra, iop_bzintq, x_i, w_i, n_i)
! if sgnfrq == 1:
! Integrate[ fw_i(x,y,z) , {z,0,1},{y,0,1-z},{x,0,1-y-z}]
! where fw_i(x,y,z) = [(1-x-y-z), x, y, z] corresponds to the four corners of tetrahedra.
! if sgnfrq == 2:
! Real{ Integrate[ fw_i(x,y,z) * 1/( omg - E(x,y,z) + 0.01*1j), {z,0,1},{y,0,1-z},{x,0,1-y-z}] }, where fw_i(x,y,z) = [(1-x-y-z), x, y, z] corresponds to the four corners of tetrahedra.
! if iop_bzintq==-1: numeric integration, which needs x_i,w_i
! else: analytic integrationn
! if sgnfrq == 3:
! 2Real{ Integrate[ fw_i(x,y,z) * 1/( 1j*omg - E(x,y,z) ), {z,0,1},{y,0,1-z},{x,0,1-y-z}] }, where fw_i(x,y,z) = [(1-x-y-z), x, y, z] corresponds to the four corners of tetrahedra.
! if iop_bzintq==-1: numeric integration, which needs x_i,w_i
! ellse: analytic integration
! if sgnfrq == 4:
! Adds surface integration for metallic case
!
! This subroutine calculates the contribution of one tetrahedron to the convolution weights in the case that both tetrahedra
! (the one at "k" and the linked one at "k-q") are partially occupied. For the case of nnod=7,8,
! we further use a big region minus a small region to deal with systematic error. This is for the bulk integration case.
!use polyhedron
!use tetra_internal, only: omgga, sgnfrq
implicit none
real(8), intent(in) :: e(4) ! band energies at k
real(8), intent(in) :: f(4) ! band energies at k-q
real(8), intent(out) :: weight(4) ! the weight at each corner
real(8), intent(in) :: omgga, ef ! the frequency and fermi energy
integer, intent(in) :: sgnfrq ! a sign to tell which weight to be calculated
real(8), intent(out) :: vol_small_tetra!
integer, intent(in) :: iop_bzintq ! which mode of calculation
real(8), intent(in) :: x_i(n_i), w_i(n_i) ! x-positions and weights for gauss integration quadrature in 1D
integer, intent(in) :: n_i
!
real(8), parameter :: pi = 3.14159265358979d0
integer :: i,inod,t_info
integer :: isub
real(8) :: wtemp(4,2)
real(8), allocatable :: t_corners(:,:)
integer(1), allocatable :: index(:,:) ! it indicates in which order the nodes have to be sent to genericprism
real(8) :: etmp(4), wtmp(4)
integer :: tindx(4)
!
integer(1) :: ntype(20) ! idem as pl, but for internal use
real(8) :: intnodes(3,20) ! the coordinates of the intersections of the planes
integer :: nnod ! number of nodes defining the polyhedron
integer :: info, nd2
!
!external setnodes
external generictetra
external genericfunf
external genericprism
!
external surfnodes
external unrepnodes
external relnodes
external sortnodes
!
!call setnodes(ntype, intnodes, nnod, e, f, ef)
!
! calculate the intersections between three planes that belongs to the surface of the tetrahedron
call surfnodes(0, ntype, intnodes, nnod, e, f, ef)
! Eliminate repetitions and asign the corresponding value to ntype
call unrepnodes(0, ntype, intnodes, nnod)
! Select those nodes that surround the integration region (e<=ef and f>=ef)
call relnodes(0,info, ntype, intnodes, nnod, e, f, ef)
if (info.ne.0) call setnod_debugerr
! Sort the nodes in the way needed by convw1t.
nd2 = 1
if (nnod > 6) nd2 = 2
allocate(index(nnod,nd2))
call sortnodes(info, ntype, nnod, index, nd2)
if (info.ne.0) call setnod_debugerr
select case(nnod)
case(0)
weight(1:4)=0.0d0
case(1)
weight(1:4)=0.0d0
case(2)
weight(1:4)=0.0d0
case(3)
weight(1:4)=0.0d0
if (sgnfrq.eq.4) then
if (dabs(omgga) < 1.0d-12) then
call binary_insertion_sort_indx(tindx, e, 4)
do i=1,4
etmp(i) = e(tindx(i))
enddo
call ksurf(wtmp, etmp, ef)
do i=1,4
weight(tindx(i)) = wtmp(i)*(-pi)
enddo
endif
endif
case(4)
allocate(t_corners(1:3,1:nnod))
t_corners(1:3,1:4) = intnodes(1:3,1:4)
call generictetra(t_corners, weight, 1, t_info, vol_small_tetra, e, f, omgga, ef, sgnfrq, iop_bzintq, x_i, w_i, n_i)
case(5)
allocate(t_corners(1:3,1:nnod))
do inod=1,5
t_corners(1:3,index(inod,1)) = intnodes(1:3,inod)
enddo
call genericfunf(t_corners, weight, 1, t_info, vol_small_tetra, e, f, omgga, ef, sgnfrq, iop_bzintq, x_i, w_i, n_i)
case(6)
allocate(t_corners(1:3,1:nnod))
do inod=1,6
t_corners(1:3,index(inod,1))=intnodes(1:3,inod)
enddo
call genericprism(t_corners, weight, 1, t_info, vol_small_tetra, e, f, omgga, ef, sgnfrq, iop_bzintq, x_i, w_i, n_i)
case(7)
allocate(t_corners(1:3,1:5))
do isub=1,2
do inod=1,7
if (index(inod,isub).ne.0) then
t_corners(1:3,index(inod,isub)) = intnodes(1:3,inod)
endif
enddo ! inod
call genericfunf(t_corners, wtemp(1:4,isub), 2, t_info, vol_small_tetra, e, f, omgga, ef, sgnfrq, iop_bzintq, x_i, w_i, n_i)
enddo ! isub
weight(1:4) = wtemp(1:4,1) + wtemp(1:4,2)
case(8)
allocate(t_corners(1:3,1:6))
do isub=1,2
do inod=1,8
if (index(inod,isub).ne.0) then
t_corners(1:3,index(inod,isub)) = intnodes(1:3,inod)
endif
enddo
call genericprism(t_corners, wtemp(1:4,isub), 4, t_info, vol_small_tetra, e, f, omgga, ef, sgnfrq, iop_bzintq, x_i, w_i, n_i)
enddo
weight(1:4)=wtemp(1:4,1)+wtemp(1:4,2)
case default
write(6,*) "ERROR in convw1t: nnod=",nnod
stop 'ERROR in convw1t'
end select
if(allocated(t_corners))deallocate(t_corners)
if(allocated(index))deallocate(index)
contains
subroutine setnod_debugerr
! Internal subroutine, repeats the setnodes cycle with write option for debugging
! call all the subroutines again with the write option, for debuging
call surfnodes(1, ntype, intnodes, nnod, e, f, ef)
call unrepnodes(1, ntype, intnodes, nnod)
call relnodes(1,info, ntype, intnodes, nnod, e, f, ef)
stop 'error in setnodes'
end subroutine setnod_debugerr
end subroutine convw1t
subroutine genericfunf(corners, w, ical, info, &
& vol_small_tetra, e, f, omgga, ef, sgnfrq, iop_bzintq, x_i, w_i, n_i)
! This subroutine integrates the convolution weight functions inside a generic
! pentahedron. It divides the pentahedron into the corresponding two tetrahedra
! and calls "generictetra" for each of them
implicit none
real(8), intent(out) :: w(4)
integer, intent(out) :: info
real(8), intent(in) :: corners(3,5)
integer, intent(in) :: ical
real(8), intent(out) :: vol_small_tetra!
real(8), intent(in) :: e(4) ! band energies at k
real(8), intent(in) :: f(4) ! band energies at k-q
real(8), intent(in) :: omgga, ef ! the frequency and fermi energy
integer, intent(in) :: sgnfrq ! a sign to tell which weight to be calculated
integer, intent(in) :: iop_bzintq ! which mode of calculation
real(8), intent(in) :: x_i(n_i), w_i(n_i) ! x-positions and weights for gauss integration quadrature in 1D
integer, intent(in) :: n_i
!
integer, parameter :: fout = 6
integer :: i, itet, inod,tinfo,insp
real(8) :: twt(4)
real(8) :: tcorners(3,4)
insp=0
info=0
w(1:4) = 0.0d0
do itet = 0,1
do inod=1,4
tcorners(1:3,inod) = corners(1:3,inod+itet)
enddo
call generictetra(tcorners, twt, 5, tinfo, vol_small_tetra, e, f, omgga, ef, sgnfrq, iop_bzintq, x_i, w_i, n_i)
if (tinfo.ne.0) then
insp = insp + tinfo*(itet+1)
endif
do i=1,4
w(i) = w(i) + twt(i)
enddo
enddo
if (insp.ne.0) then
info=1
write(fout,'(a7,i4,a8,i4)')'insp = ',insp,' ical = ',ical
do inod=1,5
write(fout,'(3f13.8)')corners(inod,1:3)
enddo
endif
end subroutine genericfunf
subroutine genericprism(corners, w, ical, info, &
& vol_small_tetra, e, f, omgga, ef, sgnfrq, iop_bzintq, x_i, w_i, n_i)
! This subroutine integrates the convolution weight functions inside a generic prism.
! It divides the prism into the corresponding three tetrahedra and calls "generictetra" for each of them.
!
implicit none
! The coordinates of the six corners of the prism: the first three form the triangle at the basis and
real(8), intent(in) :: corners(3,6) ! the last three the triangle at the top, so that the edges of the prism are (1,4), (2,5) and (3,6)
real(8), intent(out) :: w(4) ! the contribution of the prism to the weight at each corner of the containing tetrahedron.
integer, intent(in) :: ical
integer, intent(out) :: info
real(8), intent(out) :: vol_small_tetra!
real(8), intent(in) :: e(4) ! band energies at k
real(8), intent(in) :: f(4) ! band energies at k-q
real(8), intent(in) :: omgga, ef ! the frequency and fermi energy
integer, intent(in) :: sgnfrq ! a sign to tell which weight to be calculated
integer, intent(in) :: iop_bzintq ! which mode of calculation
real(8), intent(in) :: x_i(n_i), w_i(n_i) ! x-positions and weights for gauss integration quadrature in 1D
integer, intent(in) :: n_i
integer, parameter :: fout = 6
!
integer :: i, itet, inod, tinfo, infl
real(8) :: tcorners(3,4)
real(8) :: twt(4)
info = 0
infl = 0
w(1:4) = 0.0d0
do itet = 0,2
do inod=1,4
tcorners(1:3,inod) = corners(1:3, inod+itet)
enddo
call generictetra(tcorners, twt, 6, tinfo, vol_small_tetra, e, f, omgga, ef, sgnfrq, iop_bzintq, x_i, w_i, n_i)
infl = infl + tinfo*(itet+1)
do i=1,4
w(i) = w(i) + twt(i)
enddo
enddo
if (infl.ne.0) then
info = 1
!write(fout,'(a7,i4,a8,i4)')'infl = ',infl,' icap = ',ical
do inod=1,6
write(fout,'(3f13.8)')corners(inod,1:3)
enddo
endif
end subroutine genericprism
subroutine generictetra(corners, wt_out, ical, info, &
& vol_small_tetra, e, f, omgga, ef, sgnfrq, iop_bzintq, x_i, w_i, n_i)
!
! if sgnfrq == 1:
! Integrate[ fw_i(x,y,z) , {z,0,1},{y,0,1-z},{x,0,1-y-z}]
! where fw_i(x,y,z) = [(1-x-y-z), x, y, z] corresponds to the four corners of tetrahedra.
! if sgnfrq == 2:
! Real{ Integrate[ fw_i(x,y,z) * 1/( omg - E(x,y,z) + 0.01*1j), {z,0,1},{y,0,1-z},{x,0,1-y-z}] }, where fw_i(x,y,z) = [(1-x-y-z), x, y, z] corresponds to the four corners of tetrahedra.
! if iop_bzintq==-1: numeric integration, which needs x_i,w_i
! else: analytic integrationn
! if sgnfrq == 3:
! 2Real{ Integrate[ fw_i(x,y,z) * 1/( 1j*omg - E(x,y,z) ), {z,0,1},{y,0,1-z},{x,0,1-y-z}] }, where fw_i(x,y,z) = [(1-x-y-z), x, y, z] corresponds to the four corners of tetrahedra.
! if iop_bzintq==-1: numeric integration, which needs x_i,w_i
! ellse: analytic integration
! if sgnfrq == 4:
! Adds surface integration for metallic case
!
! This subroutine calculates the integrals:
!
! For the case of normal weight $sigfreq=1$:
! \begin{equation}
! \begin{align}
! w(1)=&\iiint\limits_T (1-x-y-z) dx dy dz \\
! w(2)=&\iiint\limits_T x dx dy dz \\
! w(3)=&\iiint\limits_T y dx dy dz \\
! w(4)=&\iiint\limits_T z dx dy dz
! \end{align}
! \end{equation}
!
! For the case of the weight including real frequency contribution,
! $sigfreq=2$:
!
! \begin{eqnarray}
! w(1)=\iiint\limits_T \frac{1-x-y-z}{\omega-\epsilon_{n'k-q}+\epsilon_{nk}}
! dx dy dz \nonumber \\
! w(2)=\iiint\limits_T \frac{x}{\omega-\epsilon_{n'k-q}+\epsilon_{nk}}
! dx dy dz \nonumber \\
! w(3)=\iiint\limits_T \frac{y}{\omega-\epsilon_{n'k-q}+\epsilon_{nk}}
! dx dy dz \nonumber \\
! w(4)=\iiint\limits_T \frac{z}{\omega-\epsilon_{n'k-q}+\epsilon_{nk}}
! dx dy dz
! \end{eqnarray}
!
! The whole contribution is got by setting $\omega$ to $-\omega$ and call this
! program again.
!
! For the case of weight including imaginary frequency, $sigfreq=3$:
!
! \begin{eqnarray}
! w(1)=\iiint\limits_T \frac{-2(1-x-y-z)\omega}{\omega^2+(\epsilon_{n'k-q}+\epsilon_{nk})^2}
! dx dy dz \nonumber \\
! w(2)=\iiint\limits_T \frac{-2x\omega}{\omega^2+(\epsilon_{n'k-q}+\epsilon_{nk})^2}
! dx dy dz \nonumber \\
! w(3)=\iiint\limits_T \frac{-2y\omega}{\omega^2+(\epsilon_{n'k-q}+\epsilon_{nk})^2}
! dx dy dz \nonumber \\
! w(4)=\iiint\limits_T \frac{-2z\omega}{\omega^2+(\epsilon_{n'k-q}+\epsilon_{nk})^2}
! dx dy dz
! \end{eqnarray}
!
! where $T$ is a tetrahedron of corners \verb"nodes(i,j)".
! For the case of surface integration weight, $sigfreq=4$:
!
! \begin{eqnarray}
! w(1)=\iiint\limits_T (1-x-y-z)\Delta(\epsilon_{nk}-\epsilon_{n'k-q}+\omega)
! dx dy dz \nonumber \\
! w(2)=\iiint\limits_T x\Delta(\epsilon_{nk}-\epsilon_{n'k-q}+\omega)
! dx dy dz \nonumber \\
! w(3)=\iiint\limits_T y\Delta(\epsilon_{nk}-\epsilon_{n'k-q}+\omega)
! dx dy dz \nonumber \\
! w(4)=\iiint\limits_T z\Delta(\epsilon_{nk}-\epsilon_{n'k-q}+\omega)
! dx dy dz
! \end{eqnarray}
!
! where $T$ is a tetrahedron of corners \verb"nodes(i,j)".
!use bzint, only: ztol_vol,iop_bzintq,tol_taylor
!use tetra_internal,only: sgnfrq, omgga,fout,vol_small_tetra,ldbg_bzint
implicit none
real(8), intent(in) :: corners(3,4) ! Coordinates of the four nodes
integer, intent(in) :: ical
integer, intent(out) :: info
real(8), intent(out) :: wt_out(4) ! The four weights corresponding to the original coordinates
real(8), intent(out) :: vol_small_tetra!
real(8), intent(in) :: e(4) ! band energies at k
real(8), intent(in) :: f(4) ! band energies at k-q
real(8), intent(in) :: omgga, ef ! the frequency and fermi energy
integer, intent(in) :: sgnfrq ! a sign to tell which weight to be calculated
integer, intent(in) :: iop_bzintq ! which mode of calculation
real(8), intent(in) :: x_i(n_i), w_i(n_i) ! x-positions and weights for gauss integration quadrature in 1D
integer, intent(in) :: n_i
!
interface
subroutine binary_insertion_sort_indx(indx, array,n)
integer, intent(out):: indx(n)
real*8, intent(in) :: array(n)
integer, intent(in) :: n
end subroutine binary_insertion_sort_indx
end interface
!
real(8), parameter :: tol_taylor = 10.0 ! the tolerance for the use of Taylor expansion
real(8), parameter :: ztol_vol = 1.e-10 ! tolerance for zero volume
real(8), parameter :: pi = 3.14159265358979d0
integer, parameter :: fout = 6
integer:: i,j,k
integer:: ind(4)
integer:: sigeq
real(8):: vol, det, max_de_small
real(8):: vec(3,3)
real(8):: delta_e_big_tet(4), delta_e_small_tet(4),wt_small_tet(4), wt_tmp(4),etmp(4), delta_e_small_tet_c(4)
logical, parameter :: PRINT = .False.
logical, parameter :: debug = .False.
!
! !EXTERNAL ROUTINES:
!
external ksurf
external sorteq
external stweight_imag
external stweight_itaylor
external stweight_real
external stweight_rtaylor
external stweight_numeric
!
det(i,j) = vec(2,i) * vec(3,j) - vec(2,j) * vec(3,i)
!
info=0
wt_out(1:4) = 0.0d0
wt_small_tet(1:4) = 0.0d0
wt_tmp(1:4) = 0.0d0
! Calculate the energy differences
do i=1,4
delta_e_big_tet(i) = f(i)-e(i)
enddo
! Calculate the volume of the small tetrahedron
do i=1,3
do j=1,3
vec(i,j) = corners(j,i+1)-corners(j,1)
enddo
enddo
vol=0.0d0
do i=1,3
j = mod(i,3)+1
k = mod(j,3)+1
vol = vol + vec(1,i)*det(j,k)
enddo
vol = abs(vol)
vol_small_tetra = vol
if (vol < ztol_vol) then
info = 1
if (debug) then
write(fout,*) 'WARNING:four vertices nearly in the same plane'
write(fout,*) 'ical = ',ical
write(fout,*) 'vol = ',vol
write(fout,*) 'nodes'
do i=1,4
write(fout,*) corners(1:3,i)
enddo
write(fout,*) 'vecs'
do i=1,3
write(fout,*) vec(i,1:3)
enddo
endif
wt_out(1:4)=0.0d0
! If the frequency is zero, the contribution from the Fermi surface has to be calculated
if ( sgnfrq.eq.4 ) then
call binary_insertion_sort_indx(ind, e, 4)
do i=1,4
etmp(i) = e(ind(i))
enddo
call ksurf(wt_small_tet, etmp, ef)
do i=1,4
wt_out(ind(i)) = wt_small_tet(i)*(-pi)
enddo
endif
return
endif
! For frequency dependent weights, calculate the energy diferences at the corners of the small tetrahedron and store the maximum absolute value
if (sgnfrq.ne.1) then
max_de_small=0.0d0
do i=1,4
delta_e_small_tet(i) = (delta_e_big_tet(2)-delta_e_big_tet(1)) * corners(1,i) + (delta_e_big_tet(3) - delta_e_big_tet(1)) * corners(2,i) + (delta_e_big_tet(4) - delta_e_big_tet(1)) * corners(3,i) + delta_e_big_tet(1)
if ( abs(delta_e_small_tet(i) ) > max_de_small ) max_de_small = abs(delta_e_small_tet(i))
enddo
endif
select case (sgnfrq)
case(1)
wt_small_tet(1:4) = 1.0d0/2.40d+1
case(2)
! real axis frequency polarization
if (iop_bzintq.eq.-1) then
call stweight_numeric (0, delta_e_small_tet, omgga, wt_small_tet, x_i, w_i, n_i) ! iop_omg==0=>real-axis
else
if (omgga > tol_taylor*max_de_small) then
call stweight_rtaylor(delta_e_small_tet, omgga, wt_small_tet)
else
call sorteq(delta_e_small_tet, ind, sigeq)
call stweight_real(delta_e_small_tet, omgga, sigeq, wt_tmp)
do i=1,4
wt_small_tet(ind(i)) = wt_tmp(i)
enddo
endif
endif
case(3)
! imaginary axis polarization
if(iop_bzintq.eq.-1) then
call stweight_numeric(1, delta_e_small_tet, omgga, wt_small_tet, x_i, w_i, n_i) ! iop_omg==1 => imaginary-axis
if(PRINT) write(fout,'(A,4g16.6)') '#wt=', wt_small_tet
else
if (omgga > tol_taylor*max_de_small) then
call stweight_itaylor(delta_e_small_tet, omgga, wt_small_tet)
else
call sorteq(delta_e_small_tet, ind, sigeq)
call stweight_imag(delta_e_small_tet, omgga, sigeq, wt_tmp, vol_small_tetra)
do i=1,4
wt_small_tet(ind(i)) = wt_tmp(i)
enddo
endif
endif
case(4)
call binary_insertion_sort_indx(ind, delta_e_small_tet, 4)
do i=1,4
delta_e_small_tet_c(i) = delta_e_small_tet(ind(i))
enddo
call ksurf(wt_tmp, delta_e_small_tet_c, omgga)
do i=1,4
wt_small_tet(ind(i)) = wt_tmp(i)*(-pi)
enddo
end select
wt_out(1) = sum(wt_small_tet(1:4))
do i=1,3
do j=1,4
wt_out(i+1) = wt_out(i+1) + wt_small_tet(j)*corners(i,j)
enddo
wt_out(1) = wt_out(1) - wt_out(i+1)
enddo
do i=1,4
wt_out(i) = wt_out(i)*vol
enddo
return
end subroutine generictetra
subroutine stweight_imag(deltae_vert,omeg,equiv_flag,weight_vert, vol_small_tetra)
! This subroutine calculates the weight on the whole small tetrahedron
! in which the bands at momentum k are fully occupied and (k-q) states are fully unoccupied.
! This is for the "sigfreq=3" (weights for the Polarization with imaginary frequencies)
!
! 1/(i*w-eps) = -2*eps/(w^2+eps^2)
!
implicit none
real(8), intent(out) :: weight_vert(4)! the weight on the whole tetrahedron.
real(8), intent(in) :: deltae_vert(4) ! difference of the energy in k-mesh tetrahedron vertices and k-q mesh tetrahedron vertices.
real(8), intent(in) :: omeg ! the frequency omega to be calculated
integer, intent(in) :: equiv_flag ! == 4, none is equal
! == 6, deltae_vert(1)=deltae_vert(2).
! == 8, deltae_vert(1)=deltae_vert(2) and deltae_vert(3)=deltae_vert(4).
! ==10, deltae_vert(1)=deltae_vert(2)=deltae_vert(3).
! ==16, deltae_vert(1)=deltae_vert(2)=deltae_vert(3)=deltae_vert(4).
real(8), intent(in) :: vol_small_tetra
!
real(8), parameter :: tol_unphys_weight = 1.0e+4 ! the tolerance for unphysical weights
integer :: j,k
integer :: ivert
real(8) :: aa, bb, cc, dd, bb1, bb3,bb4
real(8) :: vp
real(8) :: ev(4), tans(4), logs(4)
real(8) :: vdif(4,4)
logical:: lwarn =.false.
intrinsic datan
intrinsic dlog
intrinsic dsign
!
weight_vert(1:4) = 0.0d0
select case(equiv_flag)
case(4) ! for the case none of them are equal
do ivert=1,4
do j=1,4
k = mod(j+ivert-2,4) + 1
ev(k) = deltae_vert(j)
enddo
! vdif(:,:) = ev(:) - ev(:)
! tans(:) = atan( ev(:) / omeg )
! logs(:) = log( ev(:)**2 + omeg**2 )
call sub_set_vdif_tans_logs(vdif, tans, logs, ev)
aa = 2.0d0 * (omeg**2-ev(1)**2) * vdif(1,2) * vdif(1,3) * vdif(1,4) * vdif(2,3) * vdif(2,4) * vdif(3,4)
dd = 2.0d0 * omeg * ( 3.0d0*ev(1)**4 - omeg**2 * (ev(3)*ev(4) + ev(2)*(ev(3)+ev(4))) - 3.0d0 * ev(1)**2 * (omeg**2+ev(3)*ev(4)+ev(2)*(ev(3)+ev(4))) + 2.0d0*ev(1)*(omeg**2*(ev(3)+ev(4))+ev(2)*(omeg**2+3.0d0*ev(3)*ev(4))))
aa = aa + dd * vdif(2,3) * vdif(2,4) * vdif(3,4) * tans(1)
aa = aa + 2.0d0 * omeg * (omeg**2 - 3.0d0*ev(2)**2) * vdif(1,3)**2 * vdif(1,4)**2 * vdif(3,4) * tans(2)
aa = aa - 2.0d0 * omeg * (omeg**2 - 3.0d0*ev(3)**2) * vdif(1,2)**2 * vdif(1,4)**2 * vdif(2,4) * tans(3)
aa = aa + 2.0d0 * omeg * (omeg**2 - 3.0d0*ev(4)**2) * vdif(1,2)**2 * vdif(1,3)**2 * vdif(2,3) * tans(4)
dd = -3.0d0 * omeg**2 * ev(2)*ev(3)*ev(4) + ev(1)**4 * (ev(2)+ev(3)+ev(4))
dd = dd - 2.0d0 * ev(1)**3 * ( 3.0d0*omeg**2 + ev(3)*ev(4) + ev(2)*(ev(3)+ev(4)) )
dd = dd + 3.0d0 * ev(1)**2 * ( omeg**2 * ( ev(3) + ev(4) ) + ev(2)*( omeg**2 + ev(3) * ev(4) ) )
bb = dd * vdif(2,3) * vdif(2,4) * vdif(3,4) * logs(1)
bb = bb + ev(2) * ( 3.0d0*omeg**2 - ev(2)**2) * vdif(1,3)**2 * vdif(1,4)**2 * vdif(3,4) * logs(2)
bb = bb + ev(3) * (-3.0d0*omeg**2 + ev(3)**2) * vdif(1,2)**2 * vdif(1,4)**2 * vdif(2,4) * logs(3)
bb = bb - ev(4) * (-3.0d0*omeg**2 + ev(4)**2) * vdif(1,2)**2 * vdif(1,3)**2 * vdif(2,3) * logs(4)
cc = 6.0d0 * vdif(1,2)**2 * vdif(1,3)**2 * vdif(1,4)**2 * vdif(2,3) * vdif(2,4) * vdif(3,4)