Create extension to configure Spring maven repositories

Create a small Groovy script that can be used in `settings.gradle`
files to extend `repositories` to support the various maven
repositories required for our build.

See spring-projectsgh-42333

Author: philwebb

build.gradle

@@ -9,9 +9,14 @@ defaultTasks 'build'
 
 allprojects {
 	group "org.springframework.boot"
+}
+
+subprojects {
+	apply plugin: "org.springframework.boot.conventions"
 
 	repositories {
 		mavenCentral()
+		spring.mavenRepositories()
 		if (version.contains('-')) {
 			maven { url "https://repo.spring.io/milestone" }
 		}
@@ -25,6 +30,3 @@ allprojects {
 	}
 }
 
-subprojects {
-	apply plugin: "org.springframework.boot.conventions"
-}

buildSrc/SpringRepositorySupport.groovy

@@ -0,0 +1,134 @@
+/*
+ * Copyright 2012-2024 the original author or authors.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *      https://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+//
+// This script can be used in the `pluginManagement` block of a `settings.gradle` file to provide
+// support for spring maven repositories.
+//
+// To use the script add the following as the first line in the `pluginManagement` block:
+//
+//     evaluate(new File("${rootDir}/buildSrc/SpringRepositorySupport.groovy")).apply(this)
+//
+// You can then use `spring.mavenRepositories()` to add the Spring repositories required for the
+// version being built.
+//
+
+def apply(settings) {
+	def version =  property(settings, 'version')
+	def buildType = property(settings, 'spring.build-type')
+	SpringRepositoriesExtension.addTo(settings.pluginManagement.repositories, version, buildType)
+	settings.gradle.allprojects {
+		SpringRepositoriesExtension.addTo(repositories, version, buildType)
+	}
+}
+
+private def property(settings, name) {
+	def parentValue = settings.gradle.parent?.rootProject?.findProperty(name)
+	return (parentValue != null) ? parentValue : settings.ext[name]
+}
+
+return this
+
+class SpringRepositoriesExtension {
+
+	private final def repositories
+	private final def version
+	private final def buildType
+	private final def environment
+
+	@javax.inject.Inject
+	SpringRepositoriesExtension(repositories, version, buildType) {
+		this(repositories, version, buildType, System::getenv)
+	}
+
+	SpringRepositoriesExtension(repositories, version, buildType, environment) {
+		this.repositories = repositories
+		this.version = version
+		this.buildType = buildType
+		this.environment = environment
+	}
+
+	def mavenRepositories() {
+		addRepositories { }
+	}
+
+	def mavenRepositories(condition) {
+		if (condition) addRepositories { }
+	}
+
+	def mavenRepositoriesExcludingBootGroup() {
+		addRepositories { maven ->
+			maven.content { content ->
+				content.excludeGroup("org.springframework.boot")
+			}
+		}
+	}
+
+	private void addRepositories(action) {
+		addCommercialRepository("release", "/spring-enterprise-maven-prod-local", action)
+		if (this.version.contains("-")) {
+			addOssRepository("milestone", "/milestone", action)
+		}
+		if (this.version.endsWith("-SNAPSHOT")) {
+			addCommercialRepository("snapshot", "/spring-enterprise-maven-dev-local", action)
+			addOssRepository("snapshot", "/snapshot", action)
+		}
+	}
+
+	private void addOssRepository(id, path, action) {
+		def name = "spring-oss-" + id
+		def url = "https://repo.spring.io" + path
+		addRepository(name, url, action)
+	}
+
+	private void addCommercialRepository(id, path, action) {
+		if (!"commercial".equalsIgnoreCase(this.buildType)) return
+		def name = "spring-commercial-" + id
+		def url = fromEnv("COMMERCIAL_%SREPO_URL", id, "https://usw1.packages.broadcom.com" + path)
+		def username = fromEnv("COMMERCIAL_%SREPO_USERNAME", id)
+		def password = fromEnv("COMMERCIAL_%SREPO_PASSWORD", id)
+		addRepository(name, url, { maven ->
+			maven.credentials { credentials ->
+				credentials.setUsername(username)
+				credentials.setPassword(password)
+			}
+			action(maven)
+		})
+	}
+
+	private void addRepository(name, url, action) {
+		this.repositories.maven { maven ->
+			maven.setName(name)
+			maven.setUrl(url)
+			action(maven)
+		}
+	}
+
+	private String fromEnv(template, id) {
+		return fromEnv(template, id, null)
+	}
+
+	private String fromEnv(template, id, defaultValue) {
+		String value = this.environment.apply(template.formatted(id.toUpperCase() + "_"))
+		value = (value != null) ? value : this.environment.apply(template.formatted(""))
+		return (value != null) ? value : defaultValue
+	}
+
+	static def addTo(repositories, version, buildType) {
+		repositories.extensions.create("spring", SpringRepositoriesExtension.class, repositories, version, buildType)
+	}
+
+}

buildSrc/build.gradle

@@ -15,12 +15,8 @@ java {
 	targetCompatibility = 17
 }
 
-
-if ("${springFrameworkVersion}".contains("-")) {
-	repositories {
-		maven { url "https://repo.spring.io/milestone" }
-		maven { url "https://repo.spring.io/snapshot" }
-	}
+repositories {
+	spring.mavenRepositories("${springFrameworkVersion}".contains("-"))
 }
 
 checkstyle {
@@ -51,6 +47,7 @@ dependencies {
 	testImplementation("org.assertj:assertj-core:${assertjVersion}")
 	testImplementation("org.hamcrest:hamcrest:${hamcrestVersion}")
 	testImplementation("org.junit.jupiter:junit-jupiter:${junitJupiterVersion}")
+	testImplementation("org.mockito:mockito-core:${mockitoVersion}")
 	testImplementation("org.springframework:spring-test")
 
 	testRuntimeOnly("org.junit.platform:junit-platform-launcher")

buildSrc/settings.gradle

@@ -1,14 +1,15 @@
 pluginManagement {
+	new File(rootDir.parentFile, "gradle.properties").withInputStream {
+		def properties = new Properties()
+		properties.load(it)
+		properties.forEach(settings.ext::set)
+		gradle.rootProject {
+			properties.forEach(project.ext::set)
+		}
+	}
+	evaluate(new File("${rootDir}/SpringRepositorySupport.groovy")).apply(this)
 	repositories {
 		mavenCentral()
 		gradlePluginPortal()
 	}
 }
-
-gradle.rootProject((project) -> {
-	new File(rootDir.parentFile, "gradle.properties").withInputStream {
-		def properties = new Properties()
-		properties.load(it)
-		properties.forEach(project.ext::set)
-	}
-});