-
Notifications
You must be signed in to change notification settings - Fork 15
/
gbtf.pro
416 lines (334 loc) · 8.08 KB
/
gbtf.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
:- module(gbtf,
[ mindepthG/1
, distG/1
, complete/3
, hole/5
, mark/3
, vary/3
] ).
:- dynamic gbtf:mindepthFact/2.
:- dynamic gbtf:distFact/3.
% wiki: GBTF
% ------------------------------------------------------------
%
% Determine mindepth for all nonterminals.
% Loop over productions until fixed point is found
% This is essentially an iterated fixed point computation.
%
mindepthG(g(_,Ps))
:-
mindepthG(Ps).
mindepthG(Ps)
:-
is_list(Ps),
% Up-front sanity check
definedNs(Ps,DNs),
usedNs(Ps,UNs),
subtract(UNs,DNs,UDNs),
require(UDNs == [], 'undefined nonterminals ~w', [UDNs]),
% Enter loop
mindepthG([],Ps).
mindepthG(NDs1,Ps)
:-
definedNs(Ps,Ns),
maplisttry(gbtf:mindepthN(Ps),Ns),
findall((N,D),mindepthFact(N,D),NDs2),
( NDs1 == NDs2 ->
testMindepth(Ps);
mindepthG(NDs2,Ps)
).
%
% Test mindepth fact base to be complete.
% This is an indirect test for reducedness/termination condition.
%
testMindepth(Ps)
:-
definedNs(Ps,Ns1),
findall(N,mindepthFact(N,_),Ns2),
subtract(Ns1,Ns2,Ns3),
require(Ns3 == [],'grammar not reduced/terminated w.r.t. ~w',[Ns3]).
%
% Determine mindepth for the productions of a nonterminal
% Existing mindepth facts are leveraged.
%
mindepthN(Ps1,N)
:-
def(Ps1,N,Ps2),
maplisttry(gbtf:mindepthX,Ps2,Ds),
min1(Ds,D),
retractall(gbtf:mindepthFact(N,_)),
assertz(gbtf:mindepthFact(N,D)),
!.
%
% Compute mindepth for a given BGF expression
%
mindepthX(p(_,_,X),D) :- mindepthX(X,D).
mindepthX(true,0).
mindepthX(t(_),0).
mindepthX(n(N),D2) :- mindepthFact(N,D1), D2 is D1 + 1.
mindepthX(s(_,X),D) :- mindepthX(X,D).
mindepthX('?'(_),0).
mindepthX('*'(_),0).
mindepthX('+'(X),D) :- mindepthX(X,D).
mindepthX(','(Xs),D)
:-
maplist(gbtf:mindepthX,Xs,Ds),
max1(Ds,D).
mindepthX(';'(Xs),D)
:-
maplisttry(gbtf:mindepthX,Xs,Ds),
min1(Ds,D).
%
% Given a list of options, determine the one with mindepth.
% The leftmost is chosen if there are multiple options with mindepth.
%
chooseByMindepth([O],O)
:-
mindepthX(O,_).
chooseByMindepth([O1,O2|Os],O)
:-
mindepthX(O1,D1),
chooseByMindepth(O1,D1,[O2|Os],O).
chooseByMindepth(O,_,[],O).
chooseByMindepth(O1,D1,[O2|Os],O)
:-
mindepthX(O2,D2),
( D2 < D1 ->
chooseByMindepth(O2,D2,Os,O) ;
chooseByMindepth(O1,D1,Os,O)
).
% ------------------------------------------------------------
%
% Determine dist between nonterminals.
% This is very similar to mindept problem.
%
distG(g(_,Ps))
:-
distG(Ps).
distG(Ps)
:-
is_list(Ps),
dist1(Ps),
distStar(Ps).
%
% Initialize dist relation with direct dependencies
%
dist1(Ps)
:-
definedNs(Ps,DNs),
member(DN,DNs),
def(Ps,DN,PsDN),
usedNs(PsDN,UNs),
member(UN,UNs),
\+ UN == DN,
assertz(gbtf:distFact(DN,UN,1)),
fail;
true.
%
% Compute dists between so-far unrelated nonterminals.
% Use a helper nonterminal in between and existing relationships with it.
% Fixed point is reached if no new relationships are obtainable in this manner.
%
distStar(Ps)
:-
dist2(Ps,NNDs),
( NNDs == [] ->
true;
(
member((N1,N2,D),NNDs),
assertz(gbtf:distFact(N1,N2,D)),
fail
;
distStar(Ps)
)
).
dist2(Ps,NNDs)
:-
definedNs(Ps,DNs),
findall((N1,N2,D),
(
member(N1,DNs),
member(N2,DNs),
\+ N1 == N2,
\+ gbtf:distFact(N1,N2,_),
findall(D12,
(
gbtf:distFact(N1,N3,D1),
gbtf:distFact(N3,N2,D2),
D12 is D1 + D2
),
Ds),
min1(Ds,D)
),
NNDs).
%
% Determine dist from a BGF expression to a nonterminal
%
distX(p(_,_,X),N,D)
:-
!,
distX(X,N,D).
distX(X,N,D)
:-
usedNs(X,UNs),
findall(D1,
(
member(UN,UNs),
( UN == N -> D1 = 0; gbtf:distFact(UN,N,D1) )
),
Ds),
min1(Ds,D).
%
% Given a list of options, determine the one with dist.
% The leftmost is chosen if there are multiple options with dist.
%
chooseByMindist([O1|Os],N,O)
:-
distX(O1,N,D1) ->
chooseByMindist(O1,D1,Os,N,O) ;
chooseByMindist(Os,N,O).
chooseByMindist(O,_,[],_,O).
chooseByMindist(O1,D1,[O2|Os],N,O)
:-
distX(O2,N,D2) ->
( D2 < D1 ->
chooseByMindist(O2,D2,Os,N,O) ;
chooseByMindist(O1,D1,Os,N,O)
) ;
chooseByMindist(O1,D1,Os,N,O).
% ------------------------------------------------------------
%
% Generate shortest completion
%
complete(G,P,n(P,T))
:-
P = p(_,_,X),
complete(G,X,T).
complete(G,n(N),T) :-
def(G,N,Ps),
chooseByMindepth(Ps,P),
complete(G,P,T).
complete(_,true,true).
complete(_,t(V),t(V)).
complete(G,s(S,X),s(S,T)) :- complete(G,X,T).
complete(G,','(Xs),','(Ts)) :- maplist(gbtf:complete(G),Xs,Ts).
complete(G,';'(Xs),';'(X,T)) :- chooseByMindepth(Xs,X), complete(G,X,T).
complete(_,'?'(_),'?'([])).
complete(_,'*'(_),'*'([])).
complete(G,'+'(X),'+'([T])) :- complete(G,X,T).
% ------------------------------------------------------------
%
% Generate shortest completion with hole.
% Parameters:
% - Grammar
% - Phrase for completion
% - Nonterminal for hole
% - Tree with hole
% - Logic variable for the hole.
%
hole(_,n(N),H,V,V) :- N == H.
hole(G,n(N),H,n(P,T),V)
:-
\+ N == H,
def(G,N,Ps),
chooseByMindist(Ps,H,P),
P = p(_,N,X),
hole(G,X,H,T,V).
hole(G,s(S,X),H,s(S,T),V) :- hole(G,X,H,T,V).
hole(G,'?'(X),H,'?'([T]),V) :- hole(G,X,H,T,V).
hole(G,'*'(X),H,'*'([T]),V) :- hole(G,X,H,T,V).
hole(G,'+'(X),H,'+'([T]),V) :- hole(G,X,H,T,V).
hole(G,','(Xs),H,','(Ts),V)
:-
chooseByMindist(Xs,H,X),
once(append(Xs1,[X|Xs2],Xs)),
hole(G,X,H,T,V),
maplist(gbtf:complete(G),Xs1,Ts1),
maplist(gbtf:complete(G),Xs2,Ts2),
append(Ts1,[T|Ts2],Ts).
hole(G,';'(Xs),H,';'(X,T),V)
:-
chooseByMindist(Xs,H,X),
hole(G,X,H,T,V).
% ------------------------------------------------------------
%
% Mark all spots for BC and UC.
%
mark(C,p(L,N,X1),p(L,N,X2))
:-
mark(C,X1,X2).
mark(uc,n(N),{n(N)}).
mark(bc,';'(Xs),{';'(Xs)}).
mark(bc,'?'(X),{'?'(X)}).
mark(bc,'*'(X),{'*'(X)}).
mark(bc,'+'(X),{'+'(X)}).
mark(C,s(S,X1),s(S,X2)) :- mark(C,X1,X2).
mark(C,'?'(X1),'?'(X2)) :- mark(C,X1,X2).
mark(C,'*'(X1),'*'(X2)) :- mark(C,X1,X2).
mark(C,'+'(X1),'+'(X2)) :- mark(C,X1,X2).
mark(C,','(Xs1),','(Xs2))
:-
append(Xs1a,[X1|Xs1b],Xs1),
append(Xs1a,[X2|Xs1b],Xs2),
mark(C,X1,X2).
mark(C,';'(Xs1),';'(Xs2))
:-
append(Xs1a,[X1|Xs1b],Xs1),
append(Xs1a,[X2|Xs1b],Xs2),
mark(C,X1,X2).
% ------------------------------------------------------------
%
% Exercise choices for the marked BGF expression.
% There must be a marker for this predicate to succeed at all.
% All unmarked particles are completed in the shortest manner.
%
vary(G,P1,n(P2,T))
:-
P1 = p(_,_,X),
vary(G,X,T),
unmarkG(P1,P2).
%
% Treat horizontal definitions as vertical ones.
% Inline chain productions on the fly.
%
vary(G,{n(N)},n(P,T))
:-
def(G,N,Ps),
( (Ps = [P], P = p(_,_,';'(Xs))) ->
vary(G,{';'(Xs)},T)
; ( (Ps = [P], P = p(_,_,n(M))) ->
vary(G,{n(M)},T)
; (
member(P,Ps),
P = p(_,_,X),
complete(G,X,T)
)
)
).
vary(G,{';'(Xs)},';'(X,T))
:-
member(X,Xs),
complete(G,X,T).
vary(_,{'?'(_)},'?'([])).
vary(G,{'?'(X)},'?'([T])) :- complete(G,X,T).
vary(_,{'*'(_)},'*'([])).
vary(G,{'*'(X)},'*'([T])) :- complete(G,X,T).
vary(G,{'+'(X)},'+'([T])) :- complete(G,X,T).
vary(G,{'+'(X)},'+'([T1,T2])) :- complete(G,X,T1), complete(G,X,T2).
vary(G,s(S,X),s(S,T)) :- vary(G,X,T).
vary(G,'?'(X),'?'([T])) :- vary(G,X,T).
vary(G,'*'(X),'*'([T])) :- vary(G,X,T).
vary(G,'+'(X),'+'([T])) :- vary(G,X,T).
vary(G,','(Xs),','(Ts))
:-
append(Xs1,[X|Xs2],Xs),
maplist(gbtf:complete(G),Xs1,Ts1),
vary(G,X,T),
maplist(gbtf:complete(G),Xs2,Ts2),
append(Ts1,[T|Ts2],Ts).
vary(G,';'(Xs),';'(X2,T))
:-
member(X1,Xs),
vary(G,X1,T),
unmarkG(X1,X2).
% ------------------------------------------------------------