systemtap.if

## <summary>instrumentation system for Linux.</summary>

########################################
## <summary>
##	All of the rules required to
##	administrate an stapserver environment.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	Role allowed access.
##	</summary>
## </param>
## <rolecap/>
#
interface(`stapserver_admin',`
	gen_require(`
		type stapserver_t, stapserver_conf_t, stapserver_log_t;
		type stapserver_var_run_t, stapserver_initrc_exec_t, stapserver_var_lib_t;
	')

	allow $1 stapserver_t:process { ptrace signal_perms };
	ps_process_pattern($1, stapserver_t)

	init_startstop_service($1, $2, stapserver_t, stapserver_initrc_exec_t)

	files_search_etc($1)
	admin_pattern($1, stapserver_conf_t)

	files_search_var_lib($1)
	admin_pattern($1, stapserver_var_lib_t)

	logging_search_logs($1)
	admin_pattern($1, stapserver_log_t)

	files_search_pids($1)
	admin_pattern($1, stapserver_var_run_t)
')