build.gradle

plugins {
    id 'groovy'
    id "maven-publish"
    id 'java-library'
    id "signing"
    id 'io.github.gradle-nexus.publish-plugin' version '1.1.0'
}

repositories {
    mavenCentral()
}

java {
    withJavadocJar()
    withSourcesJar()
}

tasks.withType(GenerateModuleMetadata) {
    enabled = false
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            pom {
                name = project.name
                description = project.description
                inceptionYear = '2021'
                licenses {
                    license {
                        name = 'The Apache Software License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution = 'repo'
                    }
                }
                issueManagement {
                    system = 'github'
                    url = 'https://github.com/doctoolchain/asciidoctorj-jira-extension/issues'
                }
                scm {
                    url = 'https://github.com/doctoolchain/asciidoctorj-jira-extension'
                }
                url = 'https://github.com/doctoolchain/asciidoctorj-jira-extension'
                from components.java
                developers {
                    developer {
                        id = 'uniqueck'
                        name = 'Constantin Krüger'
                        email = 'github@constantin-krueger.com'
                    }
                }
            }
        }
    }
}

apply from: "$projectDir/gradle/signing.gradle"

nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://s01.oss.sonatype.org/service/local/"))
            snapshotRepositoryUrl.set(uri("https://s01.oss.sonatype.org/content/repositories/snapshots/"))
            username = findProperty("nexusUsername") ?: System.getenv("OSSRH_USERNAME")
            password = findProperty("nexusPassword") ?: System.getenv("OSSRH_PASSWORD")
        }
    }
}



dependencies {
    implementation group: 'org.codehaus.groovy', name: 'groovy-all', version: '3.0.8', ext: 'pom'
    testImplementation platform( group: 'org.spockframework', name: 'spock-bom', version:'2.0-groovy-3.0')
    testImplementation group: 'org.spockframework', name: 'spock-core', version: '2.0-groovy-3.0'
    implementation group: 'com.github.groovy-wslite', name: 'groovy-wslite', version:'1.1.3'
    implementation group: 'org.asciidoctor', name: 'asciidoctorj', version:'[2.0,)'
    testImplementation group: 'org.junit.jupiter', name:'junit-jupiter-api', version:'5.8.0'
    testRuntimeOnly group: 'org.junit.jupiter', name:'junit-jupiter-engine', version: '5.7.2'
    testImplementation group: 'com.github.tomakehurst', name:'wiremock-jre8', version:'2.30.0'
}

test {
    useJUnitPlatform()
    testLogging {
        events "passed", "skipped", "failed"
    }
}