build.gradle

plugins {
    id "com.gradleup.shadow" version "8.3.3" apply false
    id "architectury-plugin" version "3.4-SNAPSHOT"
    id "dev.architectury.loom" version "1.7-SNAPSHOT" apply false
    id "net.neoforged.licenser" version "0.7.+" apply false
    id "io.github.p03w.machete" version "2.+" apply false
}

architectury {
    minecraft = rootProject.minecraft_version
}

subprojects {
    apply plugin: "dev.architectury.loom"
    apply plugin: "io.github.p03w.machete"
    apply plugin: "net.neoforged.licenser"

    loom {
        silentMojangMappingsLicense()
    }

    dependencies {
        minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
        mappings loom.layered() {
            officialMojangMappings()
            parchment("org.parchmentmc.data:parchment-${rootProject.minecraft_version}:${rootProject.parchment_version}@zip")
        }
    }

    machete {
        ignoredTasks.add("shadowJar")
        ignoredTasks.add("jar")
    }

    license {
        header = rootProject.file('HEADER')
        skipExistingHeaders = false

        tasks {
            oe {
                files.from rootProject.fileTree("src", {
                    include "**/*.java"
                })
            }
        }
    }

    processResources {
        inputs.property "version", project.version

        filesMatching(["META-INF/neoforge.mods.toml", "fabric.mod.json"]) {
            expand "project": project
        }
    }
}

allprojects {
    apply plugin: "java"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    archivesBaseName = rootProject.archives_base_name
    version = "${rootProject.mod_version}+mc${rootProject.minecraft_version}-${project.name}"
    group = rootProject.maven_group

    repositories {
        maven {
            name "NeoForged"
            url "https://maven.neoforged.net/releases"
            content {
                excludeGroupByRegex "org.parchmentmc"
            }
        }
        maven {
            name "CurseMaven"
            url "https://cursemaven.com"

            content {
                includeGroup "curse.maven"
            }
        }
        maven {
            name "KosmX's maven"
            url "https://repo.redlance.org/public" // TODO replace
        }
        maven {
            name "ParchmentMC"
            url "https://maven.parchmentmc.org"
        }
        maven {
            name = "Fuzs Mod Resources"
            url = "https://raw.githubusercontent.com/Fuzss/modresources/main/maven/"
        }
    }

    tasks.withType(JavaCompile).configureEach {
        options.encoding = "UTF-8"
        options.release.set 21
    }

    java {
        withSourcesJar()
    }

    publishing {
        repositories {
        }
    }
}