build.gradle

apply plugin: 'java'
apply plugin: 'application'

mainClassName = 'org.peidevs.waro.Main'

repositories {
    mavenCentral()
}

dependencies {
    implementation 'com.fasterxml.jackson.core:jackson-core:2.11.2'
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.11.2'
    implementation 'org.apache.httpcomponents:httpclient:4.5.10'

    implementation 'com.google.guava:guava:24.1-jre'
    implementation 'org.apache.commons:commons-lang3:3.10'
    implementation 'org.springframework:spring-context:5.2.5.RELEASE'

    testImplementation(platform("org.junit:junit-bom:5.9.1"))
    testImplementation("org.junit.jupiter:junit-jupiter")
}

sourceCompatibility = 19

run {
    standardInput = System.in
}

test {
    jvmArgs(['--enable-preview'])
    useJUnitPlatform()

    testLogging {
        events "passed", "failed"
    }
}

tasks.withType(JavaCompile) {
    options.compilerArgs += '--enable-preview'
}

tasks.withType(JavaExec) {
    jvmArgs += "--enable-preview"
}

installDist.doFirst {
    ant.delete(dir: project.stagingDir)
}

installDist {
    into project.stagingDir
}

// --------- integration tests

sourceSets {
    integration {
        java.srcDir "$projectDir/src/integration/java"
        resources.srcDir "$projectDir/src/integration/resources"
        compileClasspath += main.output + test.output
        runtimeClasspath += main.output + test.output
    }
}

configurations {
    integrationImplementation.extendsFrom testImplementation
    integrationRuntime.extendsFrom testRuntime
}

task testIntegration(type: Test) {
    testClassesDirs = sourceSets.integration.output.classesDirs
    classpath = sourceSets.integration.runtimeClasspath

    jvmArgs(['--enable-preview'])
    useJUnitPlatform()

    testLogging {
        events "passed", "failed"
    }
}

// --------- build scan

gradleEnterprise {
    buildScan {
        termsOfServiceUrl = "https://gradle.com/terms-of-service"
        termsOfServiceAgree = "yes"
        tag  "backend-engineer"
    }
}