mix in label in crate hash computation (bazelbuild#1083)

Consider the situation where we have two variants of the same crate:
```
rust_library(
    name = "foo",
    srcs = ["foo.rs"],
)

rust_library(
    name = "foo2",
    crate_name = "foo",
    srcs = ["foo.rs"],
)
```

A use case for this is for example when we want to define different variants
of a crate using different feature sets, e.g., define a rustc_private non-std
variant of a vendored crate of the standard library together with a more
standard version of the vendored crate that requires the standard library.

Currently, this is a fragile definition since the output rlib filename of both
of these is the same, e.g., `libfoo-$HASH.rlib`, where `$HASH` is
derived from the crate root source filename, in this case `foo.rs`. So whenever
we have a Bazel query that includes both of these, the build may fail with
errors like:
```
ERROR: file 'test/unit/crate_variants/libfoo-717083168.rlib' is generated by these conflicting actions:
Label: //test/unit/crate_variants:foo2, //test/unit/crate_variants:foo
```

This patch reduces the risk of such output filename collisions by mixing in
the rule label in the output hash calculation.

Author: krasimirgg

proto/proto.bzl

@@ -206,7 +206,7 @@ def _rust_proto_compile(protos, descriptor_sets, imports, crate_name, ctx, is_gr
     srcs.append(lib_rs)
 
     # And simulate rust_library behavior
-    output_hash = determine_output_hash(lib_rs)
+    output_hash = determine_output_hash(lib_rs, ctx.label)
     rust_lib = ctx.actions.declare_file("%s/lib%s-%s.rlib" % (
         output_dir,
         crate_name,

rust/private/clippy.bzl

@@ -97,7 +97,7 @@ def _clippy_aspect_impl(target, ctx):
         crate_info = crate_info,
         dep_info = dep_info,
         linkstamp_outs = linkstamp_outs,
-        output_hash = determine_output_hash(crate_info.root),
+        output_hash = determine_output_hash(crate_info.root, ctx.label),
         rust_flags = [],
         out_dir = out_dir,
         build_env_files = build_env_files,

rust/private/rust.bzl

@@ -249,7 +249,7 @@ def _rust_library_common(ctx, crate_type):
     # to include the library with a specific filename into a larger application.
     # (see https://github.com/bazelbuild/rules_rust/issues/405#issuecomment-993089889 for more details)
     if crate_type != "cdylib":
-        output_hash = determine_output_hash(crate_root)
+        output_hash = determine_output_hash(crate_root, ctx.label)
     else:
         output_hash = None
 

rust/private/utils.bzl

@@ -123,18 +123,19 @@ def get_lib_name(lib):
     else:
         return libname
 
-def determine_output_hash(crate_root):
+def determine_output_hash(crate_root, label):
     """Generates a hash of the crate root file's path.
 
     Args:
         crate_root (File): The crate's root file (typically `lib.rs`).
+        label (Label): The label of the target.
 
     Returns:
         str: A string representation of the hash.
     """
 
     # Take the absolute value of hash() since it could be negative.
-    h = hash(crate_root.path)
+    h = hash(crate_root.path) + hash(repr(label))
     if h < 0:
         h = -h
     return repr(h)

test/BUILD.bazel

@@ -5,7 +5,7 @@ load(
 
 rule_test(
     name = "hello_lib_rule_test",
-    generates = ["libhello_lib-145651613.rlib"],
+    generates = ["libhello_lib-683707109.rlib"],
     rule = "//test/rust:hello_lib",
 )
 

test/unit/crate_name/crate_name_test.bzl

@@ -61,14 +61,14 @@ def _slib_library_name_test_impl(ctx):
 
     Checks that the extra hash value appended to the library filename only
     contains one dash. Previously, the hash for `slib` was negative,
-    resulting in an extra dash in the filename (--codegen_extra_filename=--517943325).
+    resulting in an extra dash in the filename (--codegen_extra_filename=--NUM).
 
     Args:
       ctx: rule context.
     """
     env = analysistest.begin(ctx)
     tut = analysistest.target_under_test(env)
-    assert_argv_contains(env, tut.actions[0], "--codegen=extra-filename=-517943325")
+    assert_argv_contains(env, tut.actions[0], "--codegen=extra-filename=-2102077805")
     return analysistest.end(env)
 
 default_crate_name_library_test = analysistest.make(

test/unit/crate_variants/BUILD.bazel

@@ -0,0 +1,4 @@
+load(":crate_variants.bzl", "crate_variants_test_suite")
+
+############################ UNIT TESTS #############################
+crate_variants_test_suite(name = "crate_variants_test_suite")

test/unit/crate_variants/bar.rs

@@ -0,0 +1 @@
+

test/unit/crate_variants/crate_variants.bzl

@@ -0,0 +1,53 @@
+"""Unittests for rust rules."""
+
+load("@bazel_skylib//lib:unittest.bzl", "analysistest", "asserts")
+load("//rust:defs.bzl", "rust_common", "rust_library")
+
+def _crate_variants_test_impl(ctx):
+    env = analysistest.begin(ctx)
+    tut = analysistest.target_under_test(env)
+    transitive_crate_outputs = tut[rust_common.dep_info].transitive_crate_outputs.to_list()
+
+    # Both variants of "foo" occur as dependencies.
+    asserts.equals(env, len(transitive_crate_outputs), 2)
+    return analysistest.end(env)
+
+crate_variants_test = analysistest.make(_crate_variants_test_impl)
+
+def _crate_variants_test():
+    rust_library(
+        name = "foo",
+        srcs = ["foo.rs"],
+    )
+
+    rust_library(
+        name = "foo2",
+        crate_name = "foo",
+        srcs = ["foo.rs"],
+    )
+
+    rust_library(
+        name = "bar",
+        srcs = ["bar.rs"],
+        deps = [":foo", ":foo2"],
+    )
+
+    crate_variants_test(
+        name = "crate_variants_test",
+        target_under_test = ":bar",
+    )
+
+def crate_variants_test_suite(name):
+    """Entry-point macro called from the BUILD file.
+
+    Args:
+        name: Name of the macro.
+    """
+    _crate_variants_test()
+
+    native.test_suite(
+        name = name,
+        tests = [
+            ":crate_variants_test",
+        ],
+    )

test/unit/crate_variants/foo.rs

@@ -0,0 +1 @@
+