build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven { url "https://plugins.gradle.org/m2/" }
    }

    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
        classpath "org.jetbrains.dokka:dokka-gradle-plugin:$dokkaVersion"
        classpath "gradle.plugin.io.gitlab.arturbosch.detekt:detekt-gradle-plugin:$detektVersion"
        classpath "com.diffplug.spotless:spotless-plugin-gradle:$spotlessVersion"
    }
}


/// Plugins
// Compilation
apply plugin: "java"
apply plugin: "kotlin"

// Documentation
apply plugin: "org.jetbrains.dokka"

// Static analysis
apply plugin: "jacoco"
apply plugin: "com.diffplug.gradle.spotless"


/// Dependencies
repositories {
    mavenCentral()
    maven { url "https://plugins.gradle.org/m2/" }
}

dependencies {
    implementation group: "io.github.microutils", name: "kotlin-logging", version: kotlinLoggingVersion
    implementation group: "org.slf4j", name: "slf4j-simple", version: slf4jVersion
    implementation group: "org.cafejojo.schaapi.models", name: "java-project", version: schaapiModelsVersion
    implementation group: "org.cafejojo.schaapi.models", name: "maven-installer", version: schaapiModelsVersion
    implementation group: "org.junit.jupiter", name: "junit-jupiter-api", version: junitJupiterApiVersion
    implementation group: "org.apache.maven.shared", name: "maven-invoker", version: mavenInvokerVersion
    implementation group: "com.github.javaparser", name: "javaparser-symbol-solver-core", version: javaparserVersion
    implementation group: "org.jacoco", name: "org.jacoco.core", version: jacocoCoreVersion

    testCompile group: "org.assertj", name: "assertj-core", version: assertjVersion
    testCompile group: "org.jetbrains.spek", name: "spek-api", version: spekVersion
    testRuntime group: "org.jetbrains.spek", name: "spek-junit-platform-engine", version: spekVersion
    testCompile group: "org.junit.jupiter", name: "junit-jupiter-engine", version: junitVersion
}


/// Configuration
// Kotlin
compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}
compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

// JUnit / Spek
test {
    testLogging {
        exceptionFormat = "full"
    }

    useJUnitPlatform() {
        includeEngines "junit-jupiter", "spek"
    }

    // Jacoco
    jacoco {
        append = true
    }
}

jacoco {
    toolVersion = jacocoVersion
}

jacocoTestReport {
    reports {
        csv.enabled = false
        html.enabled = true
        xml.enabled = true
    }
}

// Detekt
apply from: "gradle/detekt.gradle"

// Spotless
spotless {
    kotlin {
        ktlint()
    }
}