build.gradle

// Just too many sub projects, so each can reference rootProject.version
version = ob_version

buildscript {
    ext {
        ob_version = '2.2.0'
        ob_native_version = ob_version // Be careful to diverge here; easy to forget and hard to find JNI problems
        ob_expected_version = project.hasProperty('expectedVersion') ? project.property('expectedVersion') : 'UNDEFINED'

        isLinux = System.getProperty("os.name").contains("Linux")
        isMac = !isLinux && System.getProperty("os.name").toLowerCase().contains("mac")
        isWin = System.getProperty("os.name").toLowerCase().contains("windows")
        is64 = System.getProperty("sun.arch.data.model") == "64"
        isLinux64 = isLinux && is64
        isMac64 = isMac && is64
        isWin64 = isWin && is64
    }

    repositories {
        jcenter()
    }
}

allprojects {
    repositories {
        jcenter()
        mavenCentral()
        mavenLocal()
    }
}

if (JavaVersion.current().isJava8Compatible()) {
    allprojects {
        tasks.withType(Javadoc) {
            options.addStringOption('Xdoclint:none', '-quiet')
        }
    }
}

def projectNamesToPublish = [
        'objectbox-java-api',
        'objectbox-java',
        'objectbox-kotlin',
        'objectbox-rxjava'
]

configure(subprojects.findAll { projectNamesToPublish.contains(it.name) }) {
    apply plugin: 'maven'
    apply plugin: 'signing'

    configurations {
        deployerJars
    }

    dependencies {
        deployerJars 'org.apache.maven.wagon:wagon-webdav:1.0-beta-2'
        deployerJars 'org.apache.maven.wagon:wagon-ftp:2.2'
    }

    signing {
        if (project.hasProperty('signing.keyId') && project.hasProperty('signing.password') &&
                project.hasProperty('signing.secretKeyRingFile')) {
            sign configurations.archives
        } else {
            println "Signing information missing/incomplete for ${project.name}"
        }
    }

    // Use afterEvaluate or all dependencies will be lost in the generated POM
    afterEvaluate {
        uploadArchives {
            repositories {
                mavenDeployer {
                    if (project.hasProperty('preferedRepo') && preferedRepo == 'local') {
                        repository url: repositories.mavenLocal().url
                    } else if (project.hasProperty('preferedRepo') && project.hasProperty('preferedUsername')
                            && project.hasProperty('preferedPassword')) {
                        configuration = configurations.deployerJars
                        // Replace for bintray's dynamic URL
                        preferedRepo = preferedRepo.replace('__groupId__', project.group)
                        preferedRepo = preferedRepo.replace('__artifactId__', project.archivesBaseName)
                        // println preferedRepo
                        repository(url: preferedRepo) {
                            authentication(userName: preferedUsername, password: preferedPassword)
                        }
                    } else if (project.hasProperty('sonatypeUsername') && project.hasProperty('sonatypePassword')) {
                        beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
                        def isSnapshot = version.endsWith('-SNAPSHOT')
                        def sonatypeRepositoryUrl = isSnapshot ?
                                "https://oss.sonatype.org/content/repositories/snapshots/"
                                : "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
                        repository(url: sonatypeRepositoryUrl) {
                            authentication(userName: sonatypeUsername, password: sonatypePassword)
                        }
                    } else {
                        println "Settings sonatypeUsername/sonatypePassword missing/incomplete for ${project.name}"
                    }

                    pom.project {
                        packaging 'jar'
                        url 'http://objectbox.io'

                        scm {
                            url 'https://github.com/objectbox/objectbox-java'
                            connection 'scm:git@github.com:objectbox/objectbox-java.git'
                            developerConnection 'scm:git@github.com:objectbox/objectbox-java.git'
                        }

                        developers {
                            developer {
                                id 'ObjectBox'
                                name 'ObjectBox'
                            }
                        }

                        issueManagement {
                            system 'GitHub Issues'
                            url 'https://github.com/objectbox/objectbox-java/issues'
                        }

                        organization {
                            name 'ObjectBox Ltd.'
                            url 'http://objectbox.io'
                        }
                    }
                }
            }
        }
    }
}

// this task is also used by the composite build ('objectbox-deploy'), check before making changes
task installAll {
    group 'deploy'
    dependsOn ':objectbox-java-api:install'
    dependsOn ':objectbox-java:install'
    dependsOn ':objectbox-kotlin:install'
    dependsOn ':objectbox-rxjava:install'
    doLast {
        println("Installed version $version")
    }
}

// this task is also used by the composite build ('objectbox-deploy'), check before making changes
task deployAll {
    group 'deploy'
    dependsOn ':objectbox-java-api:uploadArchives'
    dependsOn ':objectbox-java:uploadArchives'
    dependsOn ':objectbox-kotlin:uploadArchives'
    dependsOn ':objectbox-rxjava:uploadArchives'
}

// this task is also used by the composite build ('objectbox-deploy'), check before making changes
task verifyVersion {
    group 'verify'
    dependsOn ':objectbox-java:verifyVersion'
    doLast {
        assert ob_expected_version == version
    }
}

task wrapper(type: Wrapper) {
    group 'build setup'
    gradleVersion = '4.5.1'
    distributionType = Wrapper.DistributionType.ALL
}