CMakeLists.txt

cmake_minimum_required(VERSION 3.2 FATAL_ERROR)

project(rtunits LANGUAGES CXX C)

add_library(rtunits INTERFACE)

target_include_directories(rtunits INTERFACE .)

if (MSVC)
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
  # TODO: debug/release mode flags.
else()
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} \
      -Wall -Wconversion -Wsign-conversion -Wextra -Wshadow -Wpedantic \
      -fvisibility=hidden \
      -fmessage-length=80")
  set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -O0 -g")
  set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -O3 -fno-rtti")
endif()

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_POSITION_INDEPENDENT_CODE ON)

# -----------
# Google Test
# -----------
# Download and unpack googletest at configure time
configure_file(CMakeLists.txt.in googletest-download/CMakeLists.txt)
execute_process(COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" .
                RESULT_VARIABLE result
                WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/googletest-download )
if(result)
  message(FATAL_ERROR "CMake step for googletest failed: ${result}")
endif()
execute_process(COMMAND ${CMAKE_COMMAND} --build .
                RESULT_VARIABLE result
                WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/googletest-download )
if(result)
  message(FATAL_ERROR "Build step for googletest failed: ${result}")
endif()

# Prevent overriding the parent project's compiler/linker
# settings on Windows
set(gtest_force_shared_crt ON CACHE BOOL "" FORCE)

# WAR for warnings inside googletest.
get_property(compile_options DIRECTORY PROPERTY COMPILE_OPTIONS)
set_property(DIRECTORY APPEND PROPERTY COMPILE_OPTIONS -Wno-conversion)
# Add googletest directly to our build. This defines
# the gtest and gtest_main targets.
add_subdirectory(${CMAKE_CURRENT_BINARY_DIR}/googletest-src
                 ${CMAKE_CURRENT_BINARY_DIR}/googletest-build
                 EXCLUDE_FROM_ALL)
# WAR for warnings inside googletest.
set_property(DIRECTORY PROPERTY COMPILE_OPTIONS ${compile_options})
unset(compile_options)

# The gtest/gtest_main targets carry header search path
# dependencies automatically when using CMake 2.8.11 or
# later. Otherwise we have to add them here ourselves.
if (CMAKE_VERSION VERSION_LESS 2.8.11)
    include_directories("${gtest_SOURCE_DIR}/include")
endif()

# -----
# Tests
# -----
set(TESTS
    rtunits_test
)
enable_testing()
foreach(test ${TESTS})
  add_executable(${test} EXCLUDE_FROM_ALL ${test}.cpp)
  target_link_libraries(${test} gtest_main)
  add_test(NAME ${test} COMMAND ${test})
endforeach(test)

# Add "check" command that *builds and* runs tests, with verbose output.
# (The default "test" command neither builds nor gives verbose output).
add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --verbose
                  DEPENDS ${TESTS})