-
Notifications
You must be signed in to change notification settings - Fork 4
/
grns_driver.f90
2598 lines (2586 loc) · 103 KB
/
grns_driver.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
SUBROUTINE GEN_GRNS(MYID,MASTER,MGCOMM, TMPDIR, LCGRNS, LNSRF, &
SRC,M1D,FRQ,MSH, IERR)
!
! Generates the Greens functions for frequencies/sources to model. If we were
! just doing body waves we could do these calculations on the fly however,
! surface waves cause a limitation in that their apparent slowness in y is
! frequency dependent. The outer loop on frequency and inner loop on sources
! has been combined and parallelized. The algorithm is blocking so it isn't the
! most efficient but I really don't care. You are going to chew computer time
! with this code anyway, wait the extra minute.
!
! A word on the source time function. Here it is hardwired to unity so that
! we later can convolve our source time function. For a forward simulation this
! of course is a somewhat silly strategy but in inversion our source time function
! may be updated at each it iteration and we may want to recycle our old Green's
! functions so convolution after the fact becomes an attractive approach.
!
! As discussed later I'm not thrilled with the surface wave calculation. I wouldn't
! use this code beyond the fundamental period.
! - B Baker January 2013
!
! INPUT MEANING
! ----- -------
! FREQ frequencies to model
! LCGRNS True -> calculate greens functions,
! False -> recycle greens functions and read read pytab
! MASTER master process ID
! MGCOMM global communicator
! MYID process ID
! NFREQ number of frequencies
! TMPDIR temprorary directory for files
!
! OUTPUT MEANING
! ------ -------
! IERR error flag
! PYTAB py at frequency and source (through common)
! VFAST max velocity in 1D models (through common)
!
!.... variable declarations
IMPLICIT NONE
INCLUDE 'mpif.h'
INCLUDE 'fwd_struc.h'
TYPE (MESH_INFO) MSH
TYPE (SRC_INFO) SRC
TYPE (MOD1D_INFO) M1D
TYPE (FRQ_INFO) FRQ
CHARACTER(*), INTENT(IN) :: TMPDIR
INTEGER*4, INTENT(IN) :: MYID,MASTER,MGCOMM
LOGICAL*4 LCGRNS, LNSRF
INTEGER*4, INTENT(OUT) :: IERR
!.... local variables
!COMPLEX*8, ALLOCATABLE :: UE(:)
COMPLEX*8 UE(1)
REAL*8, ALLOCATABLE :: CCRAY(:), CCLOV(:), PYTABB(:), &
BUFF(:)
COMPLEX*16 STF
REAL*8 PERIOD, XMLAT0,XMLON0, XMLAT1,XMLON1, VBASE, PI180, CVBASE, VFAST
INTEGER*4 LOOP, MYLOC, IPROC, ISRC, IFREQ, IPY, NPROCS, MAXMOD, NWORK, &
INDX, MPIERR
LOGICAL*4 LEX, LSHIFT, LISDIR
PARAMETER(STF = DCMPLX(1.D0,0.0))
PARAMETER(PI180 = 0.017453292519943295D0)
!
!----------------------------------------------------------------------------------------!
!
!.... initialize
IERR = 0
IF (MYID == MASTER) WRITE(*,*)
CALL MPI_BCAST(LCGRNS,1,MPI_LOGICAL, MASTER,MGCOMM,MPIERR)
IF (.NOT.LCGRNS) THEN
IF (MYID == MASTER) WRITE(*,*) 'gen_grns: Reading old py table'
GOTO 800
ENDIF
CALL MPI_COMM_SIZE(MGCOMM,NPROCS,MPIERR)
!
!.... could just be reading
IF (MYID == MASTER) THEN
LEX = LISDIR('./grns')
IF (LEX) CALL SYSTEM('rm -rf ./grns')
CALL SYSTEM('mkdir ./grns')
ENDIF
CALL MPI_BARRIER(MGCOMM,MPIERR)
XMLAT0 = msh%XLATMIN
XMLON0 = msh%XLONMIN
XMLAT1 = msh%XLATMAX
XMLON1 = msh%XLONMAX
LSHIFT = .FALSE. !shift phase velocity velocity
MAXMOD = MAXVAL(src%MODE(1:src%NSRC),1) + 1
ALLOCATE(CCRAY(20))
ALLOCATE(CCLOV(20))
ALLOCATE(PYTABB(frq%NFREQ*src%NSRC))
IF (MAXMOD > 1 .AND. MYID == MASTER) THEN
WRITE(*,*) 'gen_grns: Warning max mode > 0. I dont know what will happen'
WRITE(*,*) 'gen_grns: You should have little confidence it will work'
ENDIF
CCRAY(1:20) = 0.D0
CCLOV(1:20) = 0.D0
PERIOD = 0.D0
PYTABB(1:frq%NFREQ*src%NSRC) = 0.D0
VFAST = 0.D0
!
!.... loop on frequencies and sources
DO 100 LOOP=1,frq%NFREQ*src%NSRC,NPROCS
MYLOC = LOOP + MYID
ISRC = MOD(MYLOC,src%NSRC)
IF (ISRC == 0) ISRC = src%NSRC !multiple is evenly divisible
IFREQ = (MYLOC - ISRC)/src%NSRC + 1
IPY = (IFREQ - 1)*src%NSRC + ISRC !py index
DO 101 IPROC=0,NPROCS-1
IF (MYID == IPROC .AND. IFREQ <= frq%NFREQ .AND. ISRC <= src%NSRC) THEN
WRITE(*,9500) MYID,ISRC,frq%FREQ(IFREQ)
9500 FORMAT(' --------------------------------------------------------',/, &
' - gen_grns: Process:',I5,' -',/, &
' - Calculating 1D solution for source:',I5,' -',/, &
' - At frequency:',F12.5,' Hz -',/, &
' --------------------------------------------------------',/)
ENDIF
CALL MPI_BARRIER(MGCOMM,MPIERR)
101 CONTINUE
INDX = (ISRC - 1)*frq%NFREQ + IFREQ
IF (ISRC > src%NSRC .OR. IFREQ > frq%NFREQ) GOTO 1001 !nothing for you to do
IF (src%SRCTYP(ISRC)(1:1) == 'P') THEN !body waves
VBASE = CVBASE(src%SRCTYP(ISRC),src%CSIDE(ISRC), m1d%NL1D_LT,m1d%NL1D_RT, &
m1d%VP1D_LT,m1d%VS1D_LT, m1d%VP1D_RT,m1d%VS1D_RT)
PYTABB(INDX) = DSIN(src%BAZN(ISRC)*PI180)*DSIN(src%AOI(ISRC)*PI180)/VBASE
IF (DABS(PYTABB(INDX)) < 1.D-10) PYTABB(INDX) = 0.D0
CALL GRNS_BDY(src%SRCTYP(ISRC), NDIM,msh%NDOF,msh%NNPE, .TRUE., &
m1d%NL1D_LT,m1d%NL1D_RT, src%CSIDE(ISRC), NDIM, ISRC, &
frq%FREQ(IFREQ),msh%FREQ0,src%AOI(ISRC),src%BAZN(ISRC), &
msh%XBLKL,msh%XBLKR, msh%ZBASE_INT, &
msh%XMOD0,msh%XMOD1, STF, msh%IDOFSE, &
m1d%VP1D_LT,m1d%VS1D_LT,m1d%RH1D_LT, &
m1d%QP1D_LT,m1d%QS1D_LT, m1d%Z1D_LT, &
m1d%VP1D_RT,m1d%VS1D_RT,m1d%RH1D_RT, &
m1d%QP1D_RT,m1d%QS1D_RT, m1d%Z1D_RT, &
msh%XLOCSE,msh%ZLOCSE, UE,IERR)
IF (IERR /= 0) THEN
WRITE(*,*) 'gen_grns: An error occurred in grns_bdy on process:',MYID
GOTO 1000
ENDIF
VFAST = DMAX1(VFAST,VBASE)
ELSEIF (src%SRCTYP(ISRC)(1:1) == 'S') THEN !surface waves
!print *, myid,srctyp(isrc), ndim,ndof,nnpe, nl1d_lt,nl1d_rt, cside(isrc)
!print *, ifreq,isrc
!print *, mode(ifreq),freq(ifreq), slat(isrc),slon(isrc),sdep(isrc),smag(isrc)
CALL GRNS_SRF(TMPDIR, LNSRF, &
MYID,src%SRCTYP(ISRC), NDIM,msh%NDOF,msh%NNPE, .TRUE.,LSHIFT, &
m1d%NL1D_LT,m1d%NL1D_RT, src%CSIDE(ISRC), NDIM, &
src%MODE(ISRC), ISRC,msh%FREQ0,frq%FREQ(IFREQ), src%BAZN(ISRC),&
src%SLAT(ISRC),src%SLON(ISRC),src%SDEP(ISRC),src%SMAG(ISRC), &
src%STRIKE(ISRC),src%DIP(ISRC),src%RAKE(ISRC), &
msh%XBLKL,msh%XBLKR, msh%XMOD0,msh%XMOD1, &
XMLAT0,XMLON0,XMLAT1,XMLON1, &
STF,msh%IDOFSE, &
m1d%VPD_RLLT,m1d%VSD_RLLT,m1d%ROD_RLLT,m1d%HDD_RLLT, &
m1d%VPD_LVLT,m1d%VSD_LVLT,m1d%ROD_LVLT,m1d%HDD_LVLT, &
m1d%VPD_RLRT,m1d%VSD_RLRT,m1d%ROD_RLRT,m1d%HDD_RLRT, &
m1d%VPD_LVRT,m1d%VSD_LVRT,m1d%ROD_LVRT,m1d%HDD_LVRT, &
m1d%QP1D_LT,m1d%QP1D_RT, m1d%QS1D_LT,m1d%QS1D_RT, &
m1d%Z1D_LT, m1d%Z1D_RT, msh%XLOCSE,msh%ZLOCSE, &
PERIOD,CCRAY,CCLOV, UE,IERR)
IF (IERR /= 0) THEN
WRITE(*,*) 'gen_grns: An error occurred in grns_srf on process:',MYID
GOTO 1000
ENDIF
!
!.......... average the phase velocity for higher modes?
! NAVG = 0
! IF (SRCTYP(ISRC)(2:2) == 'L') THEN
! DO IMODE=0,MODE(ISRC)-1
! IF (CCLOV(IMODE) > 0.D0)
! NAVG = NAVG + 1
! PYTABB(INDX) = CCLOV(IMODE+1)
! ENDIF
! ENDDO
! ELSE
! DO IMODE=0,MODE(ISRC)-1
! IF (CCRAY(IMODE) > 0.D0)
! NAVG = NAVG + 1
! PYTABB(INDX) = CCRAY(IMODE+1)
! ENDIF
! ENDDO
! ENDIF
! IF (NAVG > 0) &
! PYTABB(INDX) = DSIN(BAZN(ISRC)*PI180)/PYTABB(INDX)/DFLOAT(NAVG)
IF (src%SRCTYP(ISRC)(2:2) == 'L') THEN
PYTABB(INDX) = DSIN(src%BAZN(ISRC)*PI180)/(CCLOV(1)*1.D3)
VFAST = DMAX1(VFAST,CCLOV(1)*1.D3)
ELSE
PYTABB(INDX) = DSIN(src%BAZN(ISRC)*PI180)/(CCRAY(1)*1.D3)
VFAST = DMAX1(VFAST,CCRAY(1)*1.D3)
ENDIF
IF (DABS(PYTABB(INDX)) < 1.D-10) PYTABB(INDX) = 0.D0
!LNEW = .FALSE.
ELSE !i don't know what to do
WRITE(*,*) 'gen_grns: Invalid source type!',MYID
IERR = 1
GOTO 1000
ENDIF
1001 CONTINUE
100 CONTINUE
1000 CONTINUE !error break
IF (IERR /= 0) THEN
WRITE(*,*) 'gen_grns: An error occurred on process:',MYID
RETURN
ENDIF
!
!.... have head node figure out py table
NWORK = frq%NFREQ*src%NSRC
ALLOCATE(BUFF(NWORK))
CALL MPI_ALLREDUCE(PYTABB,BUFF,NWORK, MPI_DOUBLE_PRECISION,MPI_SUM, MGCOMM,MPIERR)
CALL MPI_ALLREDUCE(VFAST,m1d%VFAST,1, MPI_DOUBLE_PRECISION,MPI_MAX, MGCOMM,MPIERR)
m1d%VFAST_BDY = m1d%VFAST
m1d%VFAST_SRF = m1d%VFAST
INDX = 0
DO 10 ISRC=1,src%NSRC
DO 11 IFREQ=1,frq%NFREQ
INDX = INDX + 1
src%PYTAB(IFREQ,ISRC) = BUFF(INDX)
11 CONTINUE
10 CONTINUE
DEALLOCATE(BUFF)
DEALLOCATE(PYTABB)
!
!.... also have head node dump the py table
IF (MYID == MASTER) &
CALL WRITE_PYTAB(frq%NFREQ,frq%NFREQ,src%NSRC, m1d%VFAST,m1d%VFAST_BDY,m1d%VFAST_SRF, &
frq%FREQ,src%PYTAB, IERR)
!
!.... done with the 1D models
IF (MYID == MASTER) THEN
WRITE(*,*) 'gen_grns: Deallocating 1D models...'
WRITE(*,*)
ENDIF
!
!.... break ahead for read only
800 CONTINUE
IF (MYID == MASTER .AND. .NOT.LCGRNS) THEN
CALL READ_PYTAB(frq%NFREQ,frq%NFREQ,src%NSRC, frq%FREQ, &
m1d%VFAST,m1d%VFAST_BDY,m1d%VFAST_SRF,src%PYTAB,IERR)
IF (IERR /= 0) WRITE(*,*) 'gen_grns: Error reading py table'
ENDIF
IF (.NOT.LCGRNS) THEN
CALL MPI_BCAST(m1d%VFAST,1,MPI_DOUBLE_PRECISION, MASTER,MGCOMM,MPIERR)
DO 12 ISRC=1,src%NSRC
CALL MPI_BCAST(src%PYTAB(1:frq%NFREQ,ISRC),frq%NFREQ,MPI_DOUBLE_PRECISION, &
MASTER,MGCOMM,MPIERR)
12 CONTINUE
ENDIF
IF (ASSOCIATED(m1d%VP1D_LT)) DEALLOCATE(m1d%VP1D_LT)
IF (ASSOCIATED(m1d%VS1D_LT)) DEALLOCATE(m1d%VS1D_LT)
IF (ASSOCIATED(m1d%RH1D_LT)) DEALLOCATE(m1d%RH1D_LT)
IF (ASSOCIATED(m1d%QP1D_LT)) DEALLOCATE(m1d%QP1D_LT)
IF (ASSOCIATED(m1d%QS1D_LT)) DEALLOCATE(m1d%QS1D_LT)
IF (ASSOCIATED(m1d% Z1D_LT)) DEALLOCATE(m1d% Z1D_LT)
IF (ASSOCIATED(m1d%VPD_RLLT)) DEALLOCATE(m1d%VPD_RLLT)
IF (ASSOCIATED(m1d%VSD_RLLT)) DEALLOCATE(m1d%VSD_RLLT)
IF (ASSOCIATED(m1d%ROD_RLLT)) DEALLOCATE(m1d%ROD_RLLT)
IF (ASSOCIATED(m1d%HDD_RLLT)) DEALLOCATE(m1d%HDD_RLLT)
IF (ASSOCIATED(m1d%VPD_LVLT)) DEALLOCATE(m1d%VPD_LVLT)
IF (ASSOCIATED(m1d%VSD_LVLT)) DEALLOCATE(m1d%VSD_LVLT)
IF (ASSOCIATED(m1d%ROD_LVLT)) DEALLOCATE(m1d%ROD_LVLT)
IF (ASSOCIATED(m1d%HDD_LVLT)) DEALLOCATE(m1d%HDD_LVLT)
IF (ASSOCIATED(m1d%VP1D_RT)) DEALLOCATE(m1d%VP1D_RT)
IF (ASSOCIATED(m1d%VS1D_RT)) DEALLOCATE(m1d%VS1D_RT)
IF (ASSOCIATED(m1d%RH1D_RT)) DEALLOCATE(m1d%RH1D_RT)
IF (ASSOCIATED(m1d%QP1D_RT)) DEALLOCATE(m1d%QP1D_RT)
IF (ASSOCIATED(m1d%QS1D_RT)) DEALLOCATE(m1d%QS1D_RT)
IF (ASSOCIATED(m1d% Z1D_RT)) DEALLOCATE(m1d% Z1D_RT)
IF (ASSOCIATED(m1d%VPD_RLRT)) DEALLOCATE(m1d%VPD_RLRT)
IF (ASSOCIATED(m1d%VSD_RLRT)) DEALLOCATE(m1d%VSD_RLRT)
IF (ASSOCIATED(m1d%ROD_RLRT)) DEALLOCATE(m1d%ROD_RLRT)
IF (ASSOCIATED(m1d%HDD_RLRT)) DEALLOCATE(m1d%HDD_RLRT)
IF (ASSOCIATED(m1d%VPD_LVRT)) DEALLOCATE(m1d%VPD_LVRT)
IF (ASSOCIATED(m1d%VSD_LVRT)) DEALLOCATE(m1d%VSD_LVRT)
IF (ASSOCIATED(m1d%ROD_LVRT)) DEALLOCATE(m1d%ROD_LVRT)
IF (ASSOCIATED(m1d%HDD_LVRT)) DEALLOCATE(m1d%HDD_LVRT)
RETURN
END
! !
!========================================================================================!
! !
SUBROUTINE GEN_GRNS_SB(MYID,MASTER,MGCOMM, TMPDIR, LCGRNS,LNSRF, &
SRC,M1D,FRQ,MSH, IERR)
!
! Generates the Greens functions for frequencies/sources to model. If we were
! just doing body waves we could do these calculations on the fly however,
! surface waves cause a limitation in that their apparent slowness in y is
! frequency dependent. The outer loop on frequency and inner loop on sources
! has been combined and parallelized. The algorithm is blocking so it isn't the
! most efficient but I really don't care. You are going to chew computer time
! with this code anyway, wait the extra minute.
!
! A word on the source time function. Here it is hardwired to unity so that
! we later can convolve our source time function. For a forward simulation this
! of course is a somewhat silly strategy but in inversion our source time function
! may be updated at each it iteration and we may want to recycle our old Green's
! functions so convolution after the fact becomes an attractive approach.
!
! As discussed later I'm not thrilled with the surface wave calculation. I wouldn't
! use this code beyond the fundamental period.
!
! The modification is this handles mixed frequency source lists
! - B Baker May 2013
!
! INPUT MEANING
! ----- -------
! FREQ frequencies to model
! LCGRNS True -> calculate greens functions,
! False -> recycle greens functions and read read pytab
! MASTER master process ID
! MGCOMM global communicator
! MYID process ID
! NFREQ number of frequencies
! TMPDIR temporary directory for files
!
! OUTPUT MEANING
! ------ -------
! IERR error flag
! PYTAB py at frequency and source (through common)
! VFAST max velocity in 1D models (through common)
!
!.... variable declarations
IMPLICIT NONE
INCLUDE 'mpif.h'
INCLUDE 'fwd_struc.h'
TYPE (MESH_INFO) MSH
TYPE (SRC_INFO) SRC
TYPE (MOD1D_INFO) M1D
TYPE (FRQ_INFO) FRQ
CHARACTER(*), INTENT(IN) :: TMPDIR
INTEGER*4, INTENT(IN) :: MYID,MASTER,MGCOMM
LOGICAL*4 LCGRNS, LNSRF
INTEGER*4, INTENT(OUT) :: IERR
!.... local variables
COMPLEX*8 UE(1)
REAL*8, ALLOCATABLE :: CCRAY(:), CCLOV(:), PYTABB(:), &
BUFF(:)
INTEGER*4, ALLOCATABLE :: IFREQ_TAB(:), ISRC_TAB(:)
COMPLEX*16 STF
REAL*8 PERIOD, XMLAT0,XMLON0, XMLAT1,XMLON1, VBASE, PI180, CVBASE, &
VFAST_SRF, VFAST_BDY
INTEGER*4 LOOP, MYLOC, IPROC, ISRC, IFREQ, IPY, NPROCS, MAXMOD, NWORK, &
JFREQ, JSRC, INDX, MPIERR
LOGICAL*4 LEX, LISDIR, LSHIFT
PARAMETER(STF = DCMPLX(1.D0,0.0))
PARAMETER(PI180 = 0.017453292519943295D0)
!
!----------------------------------------------------------------------------------------!
!
!.... initialize
IERR = 0
IF (MYID == MASTER) WRITE(*,*)
CALL MPI_BCAST(LCGRNS,1,MPI_LOGICAL, MASTER,MGCOMM,MPIERR)
IF (.NOT.LCGRNS) THEN
IF (MYID == MASTER) WRITE(*,*) 'gen_grns_sb: Reading old py table'
GOTO 800
ENDIF
CALL MPI_COMM_SIZE(MGCOMM,NPROCS,MPIERR)
!
!.... could just be reading
IF (MYID == MASTER) THEN
LEX = LISDIR('./grns')
IF (LEX) CALL SYSTEM('rm -rf ./grns')
CALL SYSTEM('mkdir ./grns')
ENDIF
CALL MPI_BARRIER(MGCOMM,MPIERR)
XMLAT0 = msh%XLATMIN
XMLON0 = msh%XLONMIN
XMLAT1 = msh%XLATMAX
XMLON1 = msh%XLONMAX
LSHIFT = .FALSE. !shift phase velocity
MAXMOD = MAXVAL(src%MODE(1:src%NSRC),1) + 1
ALLOCATE(CCRAY(20))
ALLOCATE(CCLOV(20))
ALLOCATE(PYTABB(frq%NFREQ*src%NSRC))
IF (MAXMOD > 1 .AND. MYID == MASTER) THEN
WRITE(*,*) 'gen_grns_sb: Warning max mode > 0. I dont know what will happen'
WRITE(*,*) 'gen_grns_sb: You should have little confidence it will work'
ENDIF
CCRAY(1:20) = 0.D0
CCLOV(1:20) = 0.D0
PERIOD = 0.D0
PYTABB(1:frq%NFREQ*src%NSRC) = 0.D0
VFAST_BDY = 0.D0
VFAST_SRF = 0.D0
NWORK = frq%NFREQ_SRF*src%NSRC_SRF + frq%NFREQ_BDY*src%NSRC_BDY
ALLOCATE(ISRC_TAB(NWORK))
ALLOCATE(IFREQ_TAB(NWORK))
IF (MYID == MASTER) THEN
CALL GEN_FRSRC_TAB(NWORK,frq%NFREQ,src%NSRC, src%SRCTYP,frq%CFTYPE, &
IFREQ_TAB,ISRC_TAB)
ENDIF
CALL MPI_BCAST(IFREQ_TAB,NWORK,MPI_INTEGER, MASTER,MGCOMM,MPIERR)
CALL MPI_BCAST(ISRC_TAB ,NWORK,MPI_INTEGER, MASTER,MGCOMM,MPIERR)
!
!.... loop on frequencies and sources
DO 100 LOOP=1,NWORK,NPROCS !frq%NFREQ*src%NSRC,NPROCS
MYLOC = LOOP + MYID
! ISRC = MOD(MYLOC,src%NSRC)
! IF (ISRC == 0) ISRC = src%NSRC !multiple is evenly divisible
! IFREQ = (MYLOC - ISRC)/src%NSRC + 1
IFREQ = frq%NFREQ + 1
ISRC = src%NSRC + 1
IF (MYLOC <= NWORK) THEN
IFREQ = IFREQ_TAB(MYLOC)
ISRC = ISRC_TAB(MYLOC)
ENDIF
IPY = (IFREQ - 1)*src%NSRC + ISRC !py index
DO 101 IPROC=0,NPROCS-1
! IF (MYID == IPROC .AND. IFREQ <= frq%NFREQ .AND. ISRC <= src%NSRC) THEN
IF (MYID == MASTER) THEN
JFREQ = frq%NFREQ + 1
JSRC = src%NSRC + 1
IF (MYLOC + IPROC <= NWORK) THEN
JFREQ = IFREQ_TAB(MYLOC+IPROC)
JSRC = ISRC_TAB(MYLOC+IPROC)
ENDIF
IF (JFREQ <= frq%NFREQ .AND. JSRC <= src%NSRC) &
WRITE(*,9500) MYID+IPROC,JSRC,frq%FREQ(JFREQ)
9500 FORMAT(' -----------------------------------------------------------',/, &
' - gen_grns_sb: Process:',I5,' -',/, &
' - Calculating 1D solution for source:',I5,' -',/, &
' - At frequency:',F12.5,' Hz -',/, &
' -----------------------------------------------------------',/)
ENDIF
CALL MPI_BARRIER(MGCOMM,MPIERR)
101 CONTINUE
INDX = (ISRC - 1)*frq%NFREQ + IFREQ
IF (ISRC > src%NSRC .OR. IFREQ > frq%NFREQ) GOTO 1001 !nothing for you to do
!
!....... body waves
IF (src%SRCTYP(ISRC)(1:1) == 'P' .AND. frq%CFTYPE(IFREQ) == 'B') THEN !body waves
VBASE = CVBASE(src%SRCTYP(ISRC),src%CSIDE(ISRC), m1d%NL1D_LT,m1d%NL1D_RT, &
m1d%VP1D_LT,m1d%VS1D_LT, m1d%VP1D_RT,m1d%VS1D_RT)
PYTABB(INDX) = DSIN(src%BAZN(ISRC)*PI180)*DSIN(src%AOI(ISRC)*PI180)/VBASE
IF (DABS(PYTABB(INDX)) < 1.D-10) PYTABB(INDX) = 0.D0
CALL GRNS_BDY(src%SRCTYP(ISRC), NDIM,msh%NDOF,msh%NNPE, .TRUE., &
m1d%NL1D_LT,m1d%NL1D_RT, src%CSIDE(ISRC), NDIM, ISRC, &
frq%FREQ(IFREQ),msh%FREQ0,src%AOI(ISRC),src%BAZN(ISRC), &
msh%XBLKL,msh%XBLKR,msh%ZBASE_INT, &
msh%XMOD0,msh%XMOD1, STF, msh%IDOFSE, &
m1d%VP1D_LT,m1d%VS1D_LT,m1d%RH1D_LT, &
m1d%QP1D_LT,m1d%QS1D_LT, m1d%Z1D_LT, &
m1d%VP1D_RT,m1d%VS1D_RT,m1d%RH1D_RT, &
m1d%QP1D_RT,m1d%QS1D_RT, m1d%Z1D_RT, &
msh%XLOCSE,msh%ZLOCSE, UE,IERR)
IF (IERR /= 0) THEN
WRITE(*,*) 'gen_grns_sb: An error occurred in grns_bdy on process:',MYID
GOTO 1000
ENDIF
VFAST_BDY = DMAX1(VFAST_BDY,VBASE)
!
!....... surface waves
ELSEIF (src%SRCTYP(ISRC)(1:1) == 'S' .AND. frq%CFTYPE(IFREQ) == 'S') THEN
CALL GRNS_SRF(TMPDIR, LNSRF, &
MYID,src%SRCTYP(ISRC), NDIM,msh%NDOF,msh%NNPE, .TRUE.,LSHIFT, &
m1d%NL1D_LT,m1d%NL1D_RT, src%CSIDE(ISRC), NDIM, &
src%MODE(ISRC), ISRC,msh%FREQ0,frq%FREQ(IFREQ), src%BAZN(ISRC),&
src%SLAT(ISRC),src%SLON(ISRC),src%SDEP(ISRC),src%SMAG(ISRC), &
src%STRIKE(ISRC),src%DIP(ISRC),src%RAKE(ISRC), &
msh%XBLKL,msh%XBLKR, msh%XMOD0,msh%XMOD1, &
XMLAT0,XMLON0,XMLAT1,XMLON1, &
STF,msh%IDOFSE, &
m1d%VPD_RLLT,m1d%VSD_RLLT,m1d%ROD_RLLT,m1d%HDD_RLLT, &
m1d%VPD_LVLT,m1d%VSD_LVLT,m1d%ROD_LVLT,m1d%HDD_LVLT, &
m1d%VPD_RLRT,m1d%VSD_RLRT,m1d%ROD_RLRT,m1d%HDD_RLRT, &
m1d%VPD_LVRT,m1d%VSD_LVRT,m1d%ROD_LVRT,m1d%HDD_LVRT, &
m1d%QP1D_LT,m1d%QP1D_RT, m1d%QS1D_LT,m1d%QS1D_RT, &
m1d%Z1D_LT, m1d%Z1D_RT, msh%XLOCSE,msh%ZLOCSE, &
PERIOD,CCRAY,CCLOV, UE,IERR)
IF (IERR /= 0) THEN
WRITE(*,*) 'gen_grns_sb: An error occurred in grns_srf on process:',MYID
GOTO 1000
ENDIF
IF (src%SRCTYP(ISRC)(2:2) == 'L') THEN
PYTABB(INDX) = DSIN(src%BAZN(ISRC)*PI180)/(CCLOV(1)*1.D3)
VFAST_SRF = DMAX1(VFAST_SRF,CCLOV(1)*1.D3)
ELSE
PYTABB(INDX) = DSIN(src%BAZN(ISRC)*PI180)/(CCRAY(1)*1.D3)
VFAST_SRF = DMAX1(VFAST_SRF,CCRAY(1)*1.D3)
ENDIF
IF (DABS(PYTABB(INDX)) < 1.D-10) PYTABB(INDX) = 0.D0
!LNEW = .FALSE.
ELSE !i may not know what to do
IF (src%SRCTYP(ISRC)(1:1) /= 'S' .AND. src%SRCTYP(ISRC)(1:1) /= 'P') THEN
WRITE(*,*) 'gen_grns_sb: Invalid source type!',MYID
IERR = 1
GOTO 1000
ENDIF
IF (frq%CFTYPE(IFREQ) /= 'S' .AND. frq%CFTYPE(IFREQ) /= 'B') THEN
WRITE(*,*) 'gen_grns_sb: Invalid frequency type!',MYID
IERR = 1
GOTO 1000
ENDIF
ENDIF
1001 CONTINUE
100 CONTINUE
1000 CONTINUE !error break
IF (IERR /= 0) THEN
WRITE(*,*) 'gen_grns: An error occurred on process:',MYID
RETURN
ENDIF
!
!.... have head node figure out py table
NWORK = frq%NFREQ*src%NSRC
ALLOCATE(BUFF(NWORK))
CALL MPI_ALLREDUCE(PYTABB,BUFF,NWORK, MPI_DOUBLE_PRECISION,MPI_SUM, MGCOMM,MPIERR)
CALL MPI_ALLREDUCE(VFAST_BDY,m1d%VFAST_BDY,1, MPI_DOUBLE_PRECISION,MPI_MAX, &
MGCOMM,MPIERR)
CALL MPI_ALLREDUCE(VFAST_SRF,m1d%VFAST_SRF,1, MPI_DOUBLE_PRECISION,MPI_MAX, &
MGCOMM,MPIERR)
IF (m1d%VFAST_BDY > 0.D0) THEN
m1d%VFAST = m1d%VFAST_BDY
ELSE
m1d%VFAST = m1d%VFAST_SRF
ENDIF
INDX = 0
DO 10 ISRC=1,src%NSRC
DO 11 IFREQ=1,frq%NFREQ
INDX = INDX + 1
src%PYTAB(IFREQ,ISRC) = BUFF(INDX)
11 CONTINUE
10 CONTINUE
DEALLOCATE(BUFF)
DEALLOCATE(PYTABB)
DEALLOCATE(ISRC_TAB)
DEALLOCATE(IFREQ_TAB)
!
!.... also have head node dump the py table
IF (MYID == MASTER) &
CALL WRITE_PYTAB(frq%NFREQ,frq%NFREQ,src%NSRC, m1d%VFAST,m1d%VFAST_BDY,m1d%VFAST_SRF, &
frq%FREQ,src%PYTAB, IERR)
!
!.... done with the 1D models
IF (MYID == MASTER) THEN
WRITE(*,*) 'gen_grns: Deallocating 1D models...'
WRITE(*,*)
ENDIF
!
!.... break ahead for read only
800 CONTINUE
IF (MYID == MASTER .AND. .NOT.LCGRNS) THEN
CALL READ_PYTAB(frq%NFREQ,frq%NFREQ,src%NSRC, frq%FREQ, &
m1d%VFAST,m1d%VFAST_BDY,m1d%VFAST_SRF,src%PYTAB,IERR)
IF (IERR /= 0) WRITE(*,*) 'gen_grns: Error reading py table'
ENDIF
IF (.NOT.LCGRNS) THEN
CALL MPI_BCAST(m1d%VFAST ,1,MPI_DOUBLE_PRECISION, MASTER,MGCOMM,MPIERR)
CALL MPI_BCAST(m1d%VFAST_SRF,1,MPI_DOUBLE_PRECISION, MASTER,MGCOMM,MPIERR)
CALL MPI_BCAST(m1d%VFAST_BDY,1,MPI_DOUBLE_PRECISION, MASTER,MGCOMM,MPIERR)
DO 12 ISRC=1,src%NSRC
CALL MPI_BCAST(src%PYTAB(1:frq%NFREQ,ISRC),frq%NFREQ,MPI_DOUBLE_PRECISION, &
MASTER,MGCOMM,MPIERR)
12 CONTINUE
ENDIF
IF (ASSOCIATED(m1d%VP1D_LT)) DEALLOCATE(m1d%VP1D_LT)
IF (ASSOCIATED(m1d%VS1D_LT)) DEALLOCATE(m1d%VS1D_LT)
IF (ASSOCIATED(m1d%RH1D_LT)) DEALLOCATE(m1d%RH1D_LT)
IF (ASSOCIATED(m1d%QP1D_LT)) DEALLOCATE(m1d%QP1D_LT)
IF (ASSOCIATED(m1d%QS1D_LT)) DEALLOCATE(m1d%QS1D_LT)
IF (ASSOCIATED(m1d% Z1D_LT)) DEALLOCATE(m1d% Z1D_LT)
IF (ASSOCIATED(m1d%VPD_RLLT)) DEALLOCATE(m1d%VPD_RLLT)
IF (ASSOCIATED(m1d%VSD_RLLT)) DEALLOCATE(m1d%VSD_RLLT)
IF (ASSOCIATED(m1d%ROD_RLLT)) DEALLOCATE(m1d%ROD_RLLT)
IF (ASSOCIATED(m1d%HDD_RLLT)) DEALLOCATE(m1d%HDD_RLLT)
IF (ASSOCIATED(m1d%VPD_LVLT)) DEALLOCATE(m1d%VPD_LVLT)
IF (ASSOCIATED(m1d%VSD_LVLT)) DEALLOCATE(m1d%VSD_LVLT)
IF (ASSOCIATED(m1d%ROD_LVLT)) DEALLOCATE(m1d%ROD_LVLT)
IF (ASSOCIATED(m1d%HDD_LVLT)) DEALLOCATE(m1d%HDD_LVLT)
IF (ASSOCIATED(m1d%VP1D_RT)) DEALLOCATE(m1d%VP1D_RT)
IF (ASSOCIATED(m1d%VS1D_RT)) DEALLOCATE(m1d%VS1D_RT)
IF (ASSOCIATED(m1d%RH1D_RT)) DEALLOCATE(m1d%RH1D_RT)
IF (ASSOCIATED(m1d%QP1D_RT)) DEALLOCATE(m1d%QP1D_RT)
IF (ASSOCIATED(m1d%QS1D_RT)) DEALLOCATE(m1d%QS1D_RT)
IF (ASSOCIATED(m1d% Z1D_RT)) DEALLOCATE(m1d% Z1D_RT)
IF (ASSOCIATED(m1d%VPD_RLRT)) DEALLOCATE(m1d%VPD_RLRT)
IF (ASSOCIATED(m1d%VSD_RLRT)) DEALLOCATE(m1d%VSD_RLRT)
IF (ASSOCIATED(m1d%ROD_RLRT)) DEALLOCATE(m1d%ROD_RLRT)
IF (ASSOCIATED(m1d%HDD_RLRT)) DEALLOCATE(m1d%HDD_RLRT)
IF (ASSOCIATED(m1d%VPD_LVRT)) DEALLOCATE(m1d%VPD_LVRT)
IF (ASSOCIATED(m1d%VSD_LVRT)) DEALLOCATE(m1d%VSD_LVRT)
IF (ASSOCIATED(m1d%ROD_LVRT)) DEALLOCATE(m1d%ROD_LVRT)
IF (ASSOCIATED(m1d%HDD_LVRT)) DEALLOCATE(m1d%HDD_LVRT)
RETURN
END
! !
!========================================================================================!
! !
SUBROUTINE GEN_FRSRC_TAB(NWORK,NFREQ,NSRC, SRCTYP,CFTYPE, IFREQ_TAB,ISRC_TAB)
!
! Generates a frequency source pair table
IMPLICIT NONE
CHARACTER(2), INTENT(IN) :: SRCTYP(NSRC)
CHARACTER(1), INTENT(IN) :: CFTYPE(NFREQ)
INTEGER*4, INTENT(IN) :: NWORK, NFREQ, NSRC
INTEGER*4, INTENT(OUT) :: IFREQ_TAB(NWORK), ISRC_TAB(NWORK)
!.... local variables
INTEGER*4 ITYPE, IFREQ, ISRC, INDX
!
!----------------------------------------------------------------------------------------!
!
INDX = 0
IFREQ_TAB(1:NWORK) = 0
ISRC_TAB(1:NWORK) = 0
DO 1 ITYPE=1,2
DO 2 IFREQ=1,NFREQ
IF (ITYPE == 1 .AND. CFTYPE(IFREQ) == 'S' .OR. &
ITYPE == 2 .AND. CFTYPE(IFREQ) == 'B') THEN
DO 3 ISRC=1,NSRC
IF (ITYPE == 1 .AND. SRCTYP(ISRC)(1:1) == 'S' .OR. &
ITYPE == 2 .AND. SRCTYP(ISRC)(1:1) == 'P') THEN
INDX = INDX + 1
IFREQ_TAB(INDX) = IFREQ
ISRC_TAB(INDX) = ISRC
ENDIF
3 CONTINUE !loop on sources
ENDIF
2 CONTINUE !Loop on frequencies
1 CONTINUE !loop on types
IF (INDX /= NWORK) WRITE(*,*) 'gen_fsrc_tab: Warning indx/= nwork'
RETURN
END
! !
!========================================================================================!
! !
SUBROUTINE LOAD_GRNS25(MDIM,NDOF,NNPE,NDIM, SRCTYP,ISRC, &
FREQ,STF,IDOFSE, &
UE,IERR)
!
! Loads the Greens functions onto ue vector for convolution with impedance matrix
!
! INPUT MEANING
! ----- -------
! IDOFSE maps bielak points to global DOFs
! ISRC current source number
! FREQ current frequency
! MDIM leading dimension for IDOFSE
! NDIM number of components in solution
! NDOF number of degrees of freedom
! NNPE number of nodal points in bielak layer
! SRCTYP source type; surface or body wave
! STF source time function
!
! OUTPUT MEANING
! ------ -------
! IERR error flag
! UE 1D solution on vector of length ndof
!
!.... variable declarations
IMPLICIT NONE
CHARACTER(2), INTENT(IN) :: SRCTYP
COMPLEX*8, INTENT(IN) :: STF
REAL*8, INTENT(IN) :: FREQ
INTEGER*4, INTENT(IN) :: IDOFSE(MDIM,*), MDIM, NNPE, NDOF, NDIM, ISRC
COMPLEX*8, INTENT(OUT) :: UE(NDOF)
INTEGER*4, INTENT(OUT) :: IERR
!.... local variables
COMPLEX*8, ALLOCATABLE :: UGRNS(:), VGRNS(:), WGRNS(:)
LOGICAL*4, ALLOCATABLE :: LNPINI(:)
INTEGER*4 JOB
!
!----------------------------------------------------------------------------------------!
!
!.... load greens functions
ALLOCATE(UGRNS(NNPE))
ALLOCATE(VGRNS(NNPE))
ALLOCATE(WGRNS(NNPE))
IF (SRCTYP(1:1) == 'P') THEN
JOB = 1
ELSE
JOB = 2
ENDIF
CALL READ_GRNS(MDIM, NNPE,NDIM,JOB,ISRC,.FALSE., FREQ, IDOFSE, &
UGRNS,VGRNS,WGRNS,IERR)
IF (IERR /= 0) THEN
WRITE(*,*) 'load_grns25: There was an error reading the Greens functions!'
RETURN
ENDIF
!.... stick onto ue
ALLOCATE(LNPINI(1:NNPE))
LNPINI(1:NNPE) = .TRUE.
CALL FILL_GRNS(MDIM,NDOF,NNPE, NDIM,LNPINI,IDOFSE, UGRNS,VGRNS,WGRNS, UE,IERR)
IF (IERR /= 0) THEN
WRITE(*,*) 'load_grns25: There was a warning when filling ue!'
IERR = 0
ENDIF
DEALLOCATE(LNPINI)
DEALLOCATE(UGRNS)
DEALLOCATE(VGRNS)
DEALLOCATE(WGRNS)
!.... convolve source time function
IF (STF /= CMPLX(1.0,0.0)) CALL CSCAL(NDOF,STF,UE,1)
RETURN
END
! !
!========================================================================================!
! !
SUBROUTINE GRNS_BDY(SRCTYP, MDIM,NDOF,NNPE, LSAVE, &
NL1D_LT,NL1D_RT, CSIDE, NDIM, ISRC, &
FREQ,FREQ0,AOI,BAZN, &
XBLKL,XBLKR,ZBASE_INT, &
XMOD0,XMOD1, STF, IDOFSE, &
VP1D_LT,VS1D_LT,RH1D_LT, &
QP1D_LT,QS1D_LT,Z1D_LT, &
VP1D_RT,VS1D_RT,RH1D_RT, &
QP1D_RT,QS1D_RT,Z1D_RT, &
XLOCSE,ZLOCSE, UE,IERR)
!
! Calculates the Green's functions at nodal points in the 'E'
! domain.
!
! Also note that the convention is Z (or w) positive up in finite
! elements. If the model is striking east-west, (i.e., azmod = 0),
! then X is positive North, and Y is positive East. Hence if the
! back azimuth (baz) is 180 degrees the incoming wave will be
! advancing in the +X (pure north) direction. In general, the
! slowness vector (px, py, pz) will be:
! (sin(ai)cos(baz-pi), sin(ai)sin(baz-pi), cos(ai))/v
! The azimuth of the model is defined by the direction of the +X
! axis relative to north. Hence for a non-zero azmod we modify
! above form for (px,py,pz) to be
! (sin(ai)cos(baz-pi-azmod), sin(ai)sin(baz-pi-azmod), cos(ai))/v
! However, bazn has been corrected when read in
!
! INPUT MEANING
! ----- -------
! AOI angle of incidence degrees
! BAZN corrected back azimuth, degrees (see above)
! CSIDE model side to take as 1D base model
! IDOFSE DOF pointer for nodes elements in Bielak domain
! ISRC source number
! FREQ frequency of interest (Hz)
! FREQ0 reference frequency for dispersion
! LSAVE True -> save Greens fns in bielak boundary
! False -> return on ue vector
! MDIM leading dimension for IDOFSE
! NDIM number of spatial dimensions
! NDOF number of degrees of freedom
! NL1D_LT number of points in left 1D model
! NL1D_RT number of points in right 1D model
! NNPE number of nodal points in Bielak domain
! RH1D_LT density 1d model on left
! RH1D_RT density 1d model on right
! SRCTYP source type
! STF source time function to convolve
! QP1D_LT 1D P quality factor left
! QS1D_LT 1D S quality factor left
! QP1D_RT 1D P quality factor right
! QS1D_RT 1D S quality factor right
! VP1D_LT vp 1d model on left
! VP1D_RT vp 1d model on right
! VS1D_LT vs 1d model on left
! VS1D_RT vs 1d model on right
! XBLKL left bielak/internal boundary
! XBLKR right bielak/internal boundary
! XLOCSE x locations of points in Bielak domain
! XMOD0 left Bielak/absorbing boundary position in x
! XMOD1 right Bielak/absorbing boundary position in x
! ZBAES_INT bottom of interior model
! ZLOCSE z locations of points in Bielak domain
!
! OUTPUT MEANING
! ------ -------
! IERR error flag
! UE Greens functions at nodal points in Bielak domain (LSAVE = FALSE)
!
!.... variable declarations
IMPLICIT NONE
CHARACTER(2), INTENT(IN) :: SRCTYP
CHARACTER(1), INTENT(IN) :: CSIDE
COMPLEX*16, INTENT(IN) :: STF
REAL*8, INTENT(IN) :: XLOCSE(NNPE), ZLOCSE(NNPE), &
VP1D_LT(NL1D_LT), VS1D_LT(NL1D_LT), RH1D_LT(NL1D_LT), Z1D_LT(NL1D_LT), &
VP1D_RT(NL1D_RT), VS1D_RT(NL1D_RT), RH1D_RT(NL1D_RT), Z1D_RT(NL1D_RT), &
QP1D_RT(NL1D_RT), QP1D_LT(NL1D_LT), QS1D_RT(NL1D_RT), QS1D_LT(NL1D_LT), &
FREQ,FREQ0,AOI,BAZN, XBLKL,XBLKR, XMOD0,XMOD1, ZBASE_INT
INTEGER*4, INTENT(IN) :: IDOFSE(MDIM,*), MDIM,NDOF,NNPE, &
NL1D_LT,NL1D_RT, NDIM, ISRC
LOGICAL*4, INTENT(IN) :: LSAVE
COMPLEX*8, INTENT(OUT) :: UE(*)
INTEGER*4, INTENT(OUT) :: IERR
!.... local variables
CHARACTER(1), ALLOCATABLE :: CLP(:)
COMPLEX*16, ALLOCATABLE :: UGRN1D(:), WGRN1D(:)
COMPLEX*8, ALLOCATABLE :: UGRNS(:), VGRNS(:), WGRNS(:)
REAL*8, ALLOCATABLE :: ZPTS1D(:)
LOGICAL*4, ALLOCATABLE :: LNPINI(:)
COMPLEX*16 CCAZ, CSAZ, U,V,W
REAL*8 POFF, OMEGA, PX, PY, CAZ, SAZ, XOFF, YOFF, ARG, &
TOL, TWOPI, PI180, VPBASE,VSBASE, &
SIGNPX, SIGNPY
INTEGER*4 NNP1D, INP1D,INPE
INTEGER*4 LOCATE8
LOGICAL*4 LFLIP, LDISP
PARAMETER(TOL = 1.11D-7)
PARAMETER(TWOPI = 6.2831853071795862D0)
PARAMETER(PI180 = 0.017453292519943295D0) !pi/180
PARAMETER(LFLIP = .TRUE.)
PARAMETER(YOFF = 0.D0) !we say that y is in the plane
!
!----------------------------------------------------------------------------------------!
!
!.... input errors
IERR = 0
IF (SRCTYP(2:2) == 'H') THEN
WRITE(*,*) 'grns_bdy: Error srctyp:',SRCTYP,' not yet programmed'
IERR = 1
RETURN
ENDIF
!.... initialize
ALLOCATE(UGRNS(NNPE))
ALLOCATE(VGRNS(NNPE))
ALLOCATE(WGRNS(NNPE))
UGRNS(1:NNPE) = CMPLX(0.,0.)
VGRNS(1:NNPE) = CMPLX(0.,0.)
WGRNS(1:NNPE) = CMPLX(0.,0.)
ALLOCATE(LNPINI(NNPE))
LNPINI(1:NNPE) = .FALSE.
ALLOCATE(ZPTS1D(NNPE+1))
ALLOCATE(CLP(NNPE))
!
!.... set phase shift offset based on direction of propagation
IF (CSIDE == 'L') THEN !wave moving in +x, left is zero time
POFF = XMOD0
SIGNPX = 1.D0
ELSE !wave moving in -x, right is zero time
POFF = XMOD1
SIGNPX =-1.D0
ENDIF
SIGNPY = 1.D0
! IF (BAZN >= 0.D0 .AND. BAZN <= 180.D0) THEN !lower half plane +y
IF (BAZN >= 180.D0 .AND. BAZN <= 360.D0) THEN !Lower half plane; +y
! SIGNPY = 1.D0 !moving +y in finite elements
ELSE !upper half plane
! SIGNPY =-1.D0 !moving -y in finite elements
ENDIF
! CAZ = SIGNPX*DABS(DCOS(BAZN*PI180)) !>0 moving left to right
! SAZ = SIGNPY*DABS(DSIN(BAZN*PI180)) !>0 moving towards observer
CAZ = SIGNPX*DABS(DCOS(BAZN*PI180)) !>0 moving left to right
SAZ = DSIN(BAZN*PI180)
IF (DABS(CAZ) < 1.11D-15) CAZ = 0.D0
IF (DABS(SAZ) < 1.11D-15) SAZ = 0.D0
CCAZ = DCMPLX(CAZ,0.D0)
CSAZ = DCMPLX(SAZ,0.D0)
OMEGA = TWOPI*FREQ
!
!.... extract baesment velocity
IF (CSIDE == 'L') THEN
VPBASE = VP1D_LT(NL1D_LT)
VSBASE = VS1D_LT(NL1D_LT)
ELSE
VPBASE = VP1D_RT(NL1D_RT)
VSBASE = VS1D_RT(NL1D_RT)
ENDIF
!
!.... calculate py
IF (SRCTYP(2:2) == 'P') THEN
PX = DSIN(AOI*PI180)*CAZ/VPBASE
PY = DSIN(AOI*PI180)*SAZ/VPBASE
ELSE
PX = DSIN(AOI*PI180)*CAZ/VSBASE
PY = DSIN(AOI*PI180)*SAZ/VSBASE
ENDIF
LDISP = .TRUE. !assume dispersion
IF (FREQ0 == 0.D0) LDISP = .FALSE.
!
!.... generate the 1D solutions for the appropriate model
IF (CSIDE == 'L') THEN
CLP(1:NNPE) = 'L'
CALL SET_GRNS1D(NNPE,1,CLP,TOL,ZLOCSE, NNP1D,ZPTS1D)
ALLOCATE(UGRN1D(NNP1D))
ALLOCATE(WGRN1D(NNP1D))
IF (LDISP) THEN
CALL HASKATTN(NL1D_LT,NNP1D,SRCTYP,LFLIP, FREQ,FREQ0,AOI, &
Z1D_LT,VP1D_LT,VS1D_LT,RH1D_LT,QP1D_LT,QS1D_LT, &
ZPTS1D(1:NNP1D), UGRN1D,WGRN1D, IERR)
ELSE
CALL HASKGRN(NL1D_LT,NNP1D,SRCTYP,LFLIP, FREQ,AOI, Z1D_LT,VP1D_LT, &
VS1D_LT,RH1D_LT,ZPTS1D(1:NNP1D), UGRN1D,WGRN1D, IERR)
ENDIF
IF (IERR /= 0) THEN
WRITE(*,*) 'grns_bdy: Error calling haskgrn 1'
RETURN
ENDIF
ELSE
CLP(1:NNPE) = 'R'
CALL SET_GRNS1D(NNPE,2,CLP,TOL,ZLOCSE, NNP1D,ZPTS1D)
ALLOCATE(UGRN1D(NNP1D))
ALLOCATE(WGRN1D(NNP1D))
IF (LDISP) THEN
CALL HASKATTN(NL1D_RT,NNP1D,SRCTYP,LFLIP, FREQ,FREQ0,AOI, &
Z1D_RT,VP1D_RT,VS1D_RT,RH1D_RT,QP1D_RT,QS1D_RT, &
ZPTS1D(1:NNP1D), UGRN1D,WGRN1D, IERR)
ELSE
CALL HASKGRN(NL1D_RT,NNP1D,SRCTYP,LFLIP, FREQ,AOI, Z1D_RT,VP1D_RT, &
VS1D_RT,RH1D_RT,ZPTS1D(1:NNP1D), UGRN1D,WGRN1D, IERR)
ENDIF
IF (IERR /= 0) THEN
WRITE(*,*) 'grns_bdy: Error calling haskgrn 1'
RETURN
ENDIF
ENDIF
DEALLOCATE(CLP)
!
!.... set points
DO 100 INPE=1,NNPE
INP1D = LOCATE8(NNP1D,TOL,ZLOCSE(INPE),ZPTS1D)
IF (INP1D < 1) THEN
WRITE(*,*) 'grns_bdy: Could not locate point!'
IERR = 1
GOTO 55
ENDIF
LNPINI(INPE) = .TRUE.
!
!....... calculate offset and phase shifter
XOFF = XLOCSE(INPE) - POFF
ARG =-OMEGA*(XOFF*PX + YOFF*PY) !-omega*p.x
!
!....... rotate for (u,v,w) response
U = UGRN1D(INP1D)*CCAZ !u component, pure radial
V = UGRN1D(INP1D)*CSAZ !v component, pure transverse
W = WGRN1D(INP1D) !w component, pure vertical
!
!....... convolve STF and shift
U = U*CDEXP(DCMPLX(0.D0,ARG))*STF!phase shift/convolve
V = V*CDEXP(DCMPLX(0.D0,ARG))*STF!phase shift/convolve
W = W*CDEXP(DCMPLX(0.D0,ARG))*STF!phase shift/convolve
IF (SRCTYP(2:2) == 'P' .OR. SRCTYP(2:2) == 'S') THEN !incoming P/SV
UGRNS(INPE) = CMPLX(U)
VGRNS(INPE) = CMPLX(V)
ELSE !incoming SH polarization
UGRNS(INPE) =-CMPLX(V)
VGRNS(INPE) = CMPLX(U)
ENDIF
WGRNS(INPE) =-CMPLX(W)!point up now
100 CONTINUE
55 CONTINUE
!
!.... fill in the DOFs or save ?
IF (.NOT.LSAVE) THEN
CALL FILL_GRNS(MDIM,NDOF,NNPE, NDIM,LNPINI,IDOFSE, UGRNS,VGRNS,WGRNS, UE,IERR)
IF (IERR /= 0) THEN
WRITE(*,*) 'grns_bdy: Serious warning in fill_grns'
IERR = 0
ENDIF
ELSE
DO 45 INPE=1,NNPE
IF (.NOT.LNPINI(INPE)) &
WRITE(*,*) 'grns_bdy: Serious warning in grns_bdy, unitialized point',INPE
45 CONTINUE
CALL SAVE_GRNS(NDIM, NNPE,NDIM,1,ISRC,.FALSE., FREQ,IDOFSE,UGRNS,VGRNS,WGRNS)
ENDIF
DEALLOCATE(UGRNS)
DEALLOCATE(WGRNS)
DEALLOCATE(UGRN1D)
DEALLOCATE(WGRN1D)
DEALLOCATE(ZPTS1D)
RETURN
END
!
!.... classify the points as left or right for this source
! ALLOCATE(CLP(NNPE))
! CALL CLASS_NNPE(NNPE,CSIDE,TOL,XBLKL,XBLKR, XLOCSE, CLP,IERR)
! IF (IERR /= 0) THEN
! WRITE(*,*) 'grns_bdy: Error calling class_nnpe!'
! RETURN
! ENDIF
!
!.... calculate the distance between the base model bases
! IF (CSIDE == 'L') THEN
! XOFF = DABS(XBLKR - POFF)
! ELSE !wave moving right to left
! XOFF = XBLKL - POFF
! ENDIF
! IF (SRCTYP(2:2) == 'P') THEN
! PX = DSIN(AOI*PI180)*CAZ/VPBASE
! PY = DSIN(AOI*PI180)*SAZ/VPBASE
! ELSE
! PX = DSIN(AOI*PI180)*CAZ/VSBASE
! PY = DSIN(AOI*PI180)*SAZ/VSBASE
! ENDIF
! ZBASE_BLK = MINVAL(ZLOCSE) !+z up
! CALL HASKGRN(NL1D_LT,1,SRCTYP,LFLIP, FREQ,AOI, Z1D_LT,VP1D_LT, &
! VS1D_LT,RH1D_LT,ZBASE_BLK, UL,WL, IERR)
! IF (IERR /= 0) THEN
! WRITE(*,*) 'grns_driver: Error calling haskgrn 1'
! RETURN
! ENDIF
! CALL HASKGRN(NL1D_RT,1,SRCTYP,LFLIP, FREQ,AOI, Z1D_RT,VP1D_RT, &
! VS1D_RT,RH1D_RT,ZBASE_BLK, UR,WR, IERR)