How can I typealias and/or extend a generic type such as Pair?

[jjmaestro]

I was wondering how could I extend or typealias a generic type like Pair. Here's some examples I've tried:

typealias KV = Pair

foo = KV(1, 2)

or

typealias KV = Pair<String, Int>

foo = KV("foo", 42)

or

open Pair

class KV extends Pair {}

foo = KV(1, 2)

In all these cases, when I run pk eval I get the following error:

–– Pkl Error ––
Cannot find method `KV`.

3 | foo = KV(1, 2)
          ^^^^^^^^
at kv1#foo (file:///tmp/kv1.pkl, line 3)

Did you mean any of the following?
KV.apply(...)

106 | text = renderer.renderDocument(value)
             ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
at pkl.base#Module.output.text (https://github.com/apple/pkl/blob/0.25.3/stdlib/base.pkl#L106)

The only thing I got to work was something like:

typealias KV = Pair<String, Int> 

foo: KV = Pair("foo", 42)

which is useful, but not as useful as if I could just alias Pair and/of extend it so that I can add custom functions to it.

Is there a way to extend these base types?

Thanks!

[HT154]

You've brushed up against an important core language feature of Pkl: types and methods have different namespaces. Methods can exist with the same name as types within the same module and pkl:base's Pair, List, and Map are a few examples of this.

In this case, you should be able to define a KV "constructor" method in your module to achieve what you're looking for:

function KV(key: String, value: Int): KV = Pair<String, Int>(key, value)

You can see that similar is done for Pair here:

pkl/stdlib/base.pkl

Line 1966 in 7da643f

external const function Pair<First, Second>(first: First, second: Second): Pair<First, Second>

[jjmaestro]

Ah! I see, thanks! That's valuable information!

So, with your help I got the typealias part working :D:

typealias KV = Pair<String, Int>

const function KV(key: String, value: Int): KV = Pair(key, value)

foo = KV("foo", 42)
bar = foo is KV

And that works, thanks! 🎉

$ pkl eval kv1.pkl

foo = Pair("foo", 42)
bar = true

The "minor detail" is that it still serializes as Pair and not KV but that's just a nit.

[jjmaestro]

I've also hit another issue with the constructor :-/ It looks like some namespace issue, when I have:

open module kv

typealias KV = Pair<String, Int> 

const function KV(key: String, value: Int): KV = Pair(key, value)

and then I do

extends "kv.pkl"

bar = KV("key", 42)

it works:

bar = Pair("key", 42)

But if I then try to use KV as the type of a property inside a class like so:

open module kv

typealias KV = Pair<String, Int> 

const function KV(key: String, value: Int): KV = Pair(key, value)

class Label {
  labels: KV|Listing<KV>
}

I then can't do the following:

amends "kv.pkl"  // or extends, it fails with both

bar = KV("key", 42)
label = new Label { labels = KV("key", 42) }

I get this error:

$ pkl eval testkv.pkl

–– Pkl Error ––
Cannot find method `KV`.

4 | label = new Label { labels = KV("key", 42) }
                                 ^^^^^^^^^^^^^
at testkv#label.labels (file:///tmp/testkv.pkl, line 4)

Did you mean any of the following?
KV(key, value).apply(...)
KV.apply(...)

106 | text = renderer.renderDocument(value)
             ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
at pkl.base#Module.output.text (https://github.com/apple/pkl/blob/0.25.3/stdlib/base.pkl#L106)

So, it seems like the KV "constructor" function works "outside" a class but I can't use it to create new values "inside" a class? :-?

[jjmaestro]

OK, @stackoverflow answered this last question in the Discord chat :) Thanks!!

It's an issue with the scoping, I have to do module.KV for it to work:

amends "kv.pkl"

bar = KV("key", 42)
label = new Label { labels = module.KV("key", 42) }

[jjmaestro]

However, if I wanted to not just typealias but add more functionality to Pair, that is, if I want to extend Pair, I'm trying the following:

open class Pair

class KV extends Pair {
  function bar() =
    42
}

const function KV(key: String, value: Int): KV =
  new KV { key = key; value = value }


foo = KV("foo", 42)

And I get the following error:

$ pkl eval kv2.pkl

–– Pkl Error ––
Cannot find property `key` in object of type `kv2#KV`.

9 | new KV { key = key; value = value }
             ^^^
at kv2#KV (file:///test/kv2.pkl, line 9)

Available properties:
(none)

12 | foo = KV("foo", 42)
           ^^^^^^^^^^^^^
at kv2#foo (file:///test/kv2.pkl, line 12)

106 | text = renderer.renderDocument(value)
             ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
at pkl.base#Module.output.text (https://github.com/apple/pkl/blob/0.25.3/stdlib/base.pkl#L106)

That's surprising! because it clearly says kv2#KV so I'd expect that class to have the same properties as Pair:

pkl/stdlib/base.pkl

Lines 1971 to 1983 in 7da643f

	external class Pair<out First, out Second> extends Any {
	/// The first element of this pair.
	external first: First
	/// The second element of this pair.
	external second: Second
	/// Alias for [first].
	external key: First
	/// Alias for [second].
	external value: Second
	}

Any ideas on this one? 🙏 and/or #478 which is the same/related but even a bit more complex.

Thanks!!

[jjmaestro]

After chatting in Discord with @stackoverflow and @holzensp here's a few things:

• @holzensp thinks that "in this instance, Pkl interprets open class Pair as a new definition of an empty class". That's why it works at first but then it fails to find key.

• Generic types that are not open or abstract can't be extended because the current implementation of generic types requires, for every generic type, a native type in the interpreter. E.g. you can extend Collection

So, TL;DR I can't extend Pair :)