build.gradle

plugins {
    id 'java'
    id 'com.diffplug.spotless' version '6.12.0'
    id 'jacoco'
    id "com.github.spotbugs" version "6.0.4"
}


group 'io.github.andrewfitzy'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.slf4j:slf4j-api:2.0.9'
    implementation 'com.fasterxml.jackson.core:jackson-core:2.16.1'
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.16.1'
    testImplementation 'org.slf4j:slf4j-simple:2.0.9'
    testImplementation 'org.junit.jupiter:junit-jupiter:5.8.1'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.1'
}

test {
    useJUnitPlatform()
    finalizedBy jacocoTestReport // report is always generated after tests run
    testLogging.showStandardStreams = true
    testLogging.exceptionFormat = 'full'
}

jacocoTestReport {
    dependsOn test // tests are required to run before generating the report
}

spotless {
    java {
        palantirJavaFormat('2.28.0')

        // make sure every file has the following copyright header.
        licenseHeader '/* (C)$YEAR */'
    }
}

tasks.spotbugsMain {
    reports.create("html") {
        required = true
        outputLocation = file("$buildDir/reports/spotbugs.html")
        setStylesheet("fancy-hist.xsl")
    }
}

tasks.register("initProject") {
    group = "Custom"
    description = "Init task for the project, run this after cloning"
    doLast {
        println("... Adding pre-commit hook")
        exec {
            commandLine("cp", "./.scripts/pre-commit", "./.git/hooks")
        }
        println("✅ Added Pre-commit Git Hook Script.")
    }
}