Justfile

root := justfile_directory()

export TYPST_ROOT := root

[private]
default:
  @just --list --unsorted

# generate manual
doc:
  typst compile docs/manual.typ docs/manual.pdf
  typst compile --pages 1 gallery/example.typ thumbnail-light.svg
  typst compile --pages 1 --input theme=dark gallery/example.typ thumbnail-dark.svg
  typst compile --pages 1 --input solution=true gallery/example.typ thumbnail-light-solved.svg
  typst compile --pages 1 --input solution=true --input theme=dark gallery/example.typ thumbnail-dark-solved.svg
  for f in $(find gallery -maxdepth 1 -name '*.typ'); do \
    f="$(dirname "$f")/$(basename "$f" .typ)"; \
    typst compile "$f.typ"; \
    typst compile "$f.typ" "$f-solved.pdf" --input solution=true; \
  done

# run test suite
test *args:
  tt run {{ args }}

# update test cases
update *args:
  tt update {{ args }}

# package the library into the specified destination folder
package target:
  ./scripts/package "{{target}}"

# install the library with the "@local" prefix
install: (package "@local")

# install the library with the "@preview" prefix (for pre-release testing)
install-preview: (package "@preview")

[private]
remove target:
  ./scripts/uninstall "{{target}}"

# uninstalls the library from the "@local" prefix
uninstall: (remove "@local")

# uninstalls the library from the "@preview" prefix (for pre-release testing)
uninstall-preview: (remove "@preview")

# run ci suite
ci: test doc