-
Notifications
You must be signed in to change notification settings - Fork 9
/
build.gradle
361 lines (310 loc) · 10.6 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
buildscript {
repositories {
maven { url "https://plugins.gradle.org/m2/" }
mavenCentral()
}
}
plugins {
id 'maven-publish'
id 'jacoco'
id 'signing'
id 'org.sonarqube' version '5.1.0.4882'
id 'com.diffplug.spotless' version '6.25.0'
id 'io.codearte.nexus-staging' version '0.30.0'
id 'project-report'
id 'org.cyclonedx.bom' version '1.6.1' // no bom.json created in later versions
}
allprojects {
apply plugin: 'idea'
idea.module.inheritOutputDirs = true
// Task for creating gradle.lockfile per module. Needed for Trivy vulnerability scan.
task resolveAndLockAll {
doFirst {
assert gradle.startParameter.writeDependencyLocks
}
doLast {
configurations.findAll {
it.canBeResolved
}.each { it.resolve() }
}
}
}
// we need a repository for the combination of jacoco and sonarcloud
repositories {
mavenCentral()
}
/**
* Some modules must use the 'java-platform'. Since you can't apply plugins 'java' and 'java-platform'
* at the same time, they are excluded in some steps.
*/
List<String> javaPlatformModules = Arrays.asList("sda-commons-bom", "sda-commons-dependencies")
/**
* There are some additional modules that are excluded from publishing
*/
List<String> unpublishedModules = javaPlatformModules + Arrays.asList("sda-commons-dependency-check")
project.ext.unpublishedModules = unpublishedModules
spotless {
groovyGradle {
greclipse()
indentWithSpaces(2)
}
}
/**
* Settings for all modules
*/
subprojects {
apply plugin: 'maven-publish'
apply plugin: 'com.diffplug.spotless'
apply plugin: 'signing'
apply plugin: 'project-report'
group 'org.sdase.commons'
repositories {
mavenCentral()
}
// create file that includes all dependencies in "build/deps"
task allDeps(type: DependencyReportTask) {
outputFile(new File("${rootProject.buildDir}/deps", "${project.name}.txt"))
}
check.dependsOn allDeps
// Disable publication of Gradle Module Metadata
tasks.withType(GenerateModuleMetadata) {
enabled = false
}
spotless {
if (!javaPlatformModules.contains(project.name)) {
java {
googleJavaFormat('1.17.0')
}
}
groovyGradle {
greclipse()
indentWithSpaces(2)
}
}
version = System.getenv('SEMANTIC_VERSION')
// Don't configure publishing for the example projects
if (!it.name.endsWith("-example")) {
signing {
def signingKey = findProperty("signingKey")
def signingPassword = findProperty("signingPassword")
useInMemoryPgpKeys(signingKey, signingPassword)
sign publishing.publications
}
tasks.withType(Sign) {
// skip signing a publication to maven local
onlyIf { !gradle.taskGraph.hasTask(publishMavenPublicationToMavenLocal) }
}
publishing {
publications {
maven(MavenPublication) {
pom {
name = project.group + ":" + project.name
description = 'A libraries to bootstrap services easily that follow the patterns and specifications promoted by the SDA SE'
url = 'https://github.com/SDA-SE/sda-dropwizard-commons'
licenses {
license {
name = 'MIT License'
url = 'https://raw.githubusercontent.com/SDA-SE/sda-dropwizard-commons/main/LICENSE'
}
}
organization {
name = 'SDA SE Open Industry Solutions'
url = 'https://sda.se'
}
issueManagement {
system = 'GitHub'
url = 'https://github.com/SDA-SE/sda-dropwizard-commons/issues'
}
developers {
developer {
id = 'maintainer'
name = 'SDA SE Open Industry Solutions Maintainer'
email = '[email protected]'
}
}
scm {
connection = 'scm:git:https://github.com/SDA-SE/sda-dropwizard-commons.git'
developerConnection = 'scm:git:https://github.com/SDA-SE/sda-dropwizard-commons.git'
url = 'https://github.com/SDA-SE/sda-dropwizard-commons'
}
}
}
}
repositories {
maven {
name = "sdaIntern"
def releasesRepoUrl = "https://nexus.sda-se.io/repository/sda-se-releases/"
def snapshotsRepoUrl = "https://nexus.sda-se.io/repository/sda-se-snapshots/"
url = version.endsWith('-SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
credentials {
username System.getenv('SDA_NEXUS_USER')
password System.getenv('SDA_NEXUS_PASSWORD')
}
}
maven {
name 'mavenCentral'
def releasesRepoUrl =
System.getenv('SONATYPE_STAGING_REPOSITORY_ID')
? "https://oss.sonatype.org/service/local/staging/deployByRepositoryId/${System.getenv('SONATYPE_STAGING_REPOSITORY_ID')}"
: "https://oss.sonatype.org/service/local/staging/deploy/maven2"
def snapshotsRepoUrl = "https://oss.sonatype.org/content/repositories/snapshots"
url = version.endsWith('-SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
credentials {
username System.getenv('SDA_SONATYPE_USER')
password System.getenv('SDA_SONATYPE_PASSWORD')
}
}
}
}
}
}
/**
* Configure all regular submodules (all except the bom and dependency module)
*
* Problem is: You can't apply plugins 'java' and 'java-platform' at the same time.
*/
configure(subprojects.findAll { !javaPlatformModules.contains(it.name) }) {
apply plugin: 'java-library'
apply plugin: 'jacoco'
// activate dependency locking for most configurations
var ignoredConfigurationPatternsForDependencyLocking = Set.of("test.*", "jacoco.*")
configurations.matching { configuration ->
var match = !ignoredConfigurationPatternsForDependencyLocking.any { configuration.name.matches(it) }
if (!match) {
// println "Ignoring dependency locking for '${it.name}:${configuration.name}'"
}
return match
}.each {configuration ->
// println "Activating dependency locking for '${it.name}:${configuration.name}'"
configuration.resolutionStrategy.activateDependencyLocking()
}
java {
// preferring `sourceCompatibility` over `toolchains` to be able to do builds with different
// Java versions
sourceCompatibility = JavaVersion.VERSION_17
}
tasks.withType(JavaCompile) {
options.encoding = 'UTF-8'
}
// Configure JaCoCo to export the reports in XML format
jacocoTestReport {
reports {
xml.required = true
}
}
// Configure sonar to use the aggregated global report file
sonarqube {
properties {
property "sonar.coverage.jacoco.xmlReportPaths", '../build/reports/jacoco/report.xml'
}
}
dependencies {
api enforcedPlatform(project(':sda-commons-dependencies'))
}
configurations {
all*.exclude group: 'javax.servlet', module: 'javax.servlet-api' // prefer jakarta.servlet-api
all*.exclude group: 'org.glassfish.hk2.external', module: 'jakarta.inject' // prefer jakarta.inject:jakarta.inject-api
all*.exclude group: 'commons-logging', module: 'commons-logging' // prefer jcl-over-slf4j
all*. exclude group: 'org.eclipse.jetty.toolchain', module: 'jetty-jakarta-servlet-api' // prefer jakarta.servlet:jakarta-servlet-api
all*. exclude group: 'com.sun.activation', module: 'jakarta.activation' // prefer jakarta.servlet:jakarta-activation
all*. exclude group : 'org.apache.httpcomponents', module: 'httpclient' // prefer org.apache.httpcomponents.client5
}
test {
useJUnitPlatform()
}
configurations.configureEach {
it.resolutionStrategy {
failOnVersionConflict()
}
}
}
/**
* Add publishing configuration for Java modules.
*
* More Infos:
* - sda-commons-bom and sda-commons-dependencies uses own publishing because it's just a BOM
* - example modules and dependency-check should not be published at all
*/
configure(subprojects.findAll {
!unpublishedModules.contains(it.name) && !it.name.endsWith("-example")
}) {
java {
withJavadocJar()
withSourcesJar()
}
javadoc {
options.addStringOption('encoding', 'UTF-8')
}
publishing {
publications {
maven(MavenPublication) {
from components.java
}
}
}
jar {
into("META-INF/maven/$project.group/$project.name") {
from { generatePomFileForMavenPublication }
rename ".*", "pom.xml"
}
}
}
/**
* Add publishing configuration for Java platforms.
*/
configure(subprojects.findAll { javaPlatformModules.contains(it.name) }) {
apply plugin: 'java-platform'
publishing {
publications {
maven(MavenPublication) {
from components.javaPlatform
}
}
}
}
// Reconfigure the testReport task to display the results of all modules into a single report
task testReport(type: TestReport) {
destinationDirectory = project.layout.buildDirectory.dir("reports/allTests")
// Include the results from the `test` task in all subprojects
testResults.from(
subprojects.findAll { !javaPlatformModules.contains(it.name) }*.test.binaryResultsDirectory
)
}
// Create a combined XML report of all modules in the root project
task codeCoverageReport(type: JacocoReport) {
executionData fileTree(project.rootDir.absolutePath).include("**/build/jacoco/*.exec")
subprojects.findAll { !unpublishedModules.contains(it.name) }.each {
// noinspection GroovyAssignabilityCheck
sourceSets it.sourceSets.main
}
reports {
xml.required = true
xml.outputLocation = project.layout.buildDirectory.file("reports/jacoco/report.xml")
}
dependsOn ":testReport"
}
// Automatically close and release the staging repository that gets created
// during the upload to maven central.
nexusStaging {
username System.getenv('SDA_SONATYPE_USER')
password System.getenv('SDA_SONATYPE_PASSWORD')
packageGroup "org.sdase.commons"
// Read the stagingRepositoryId from the environment
stagingRepositoryId.set(System.getenv('SONATYPE_STAGING_REPOSITORY_ID'))
}
sonarqube {
properties {
property 'sonar.projectKey', 'SDA-SE_sda-dropwizard-commons'
property 'sonar.organization', 'sda-se'
property 'sonar.host.url', 'https://sonarcloud.io'
property 'sonar.token', System.getenv('SONAR_LOGIN_TOKEN')
property 'sonar.pullrequest.provider', 'GitHub'
property 'sonar.pullrequest.github.repository', System.getenv('GITHUB_REPOSITORY')
if (System.getenv('GITHUB_PR') != null) {
property 'sonar.pullrequest.key', System.getenv('GITHUB_PR')
}
if (System.getenv('SONAR_SCM_REVISION') != null) {
property 'sonar.scm.revision', System.getenv('SONAR_SCM_REVISION')
}
}
}