-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathApp-SymAmp.asm
3456 lines (3200 loc) · 88.2 KB
/
App-SymAmp.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;@ @
;@ S y m A m p @
;@ @
;@ (c) 2005-2022 by Prodatron / SymbiosiS (Jörn Mika) @
;@ @
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;todo
;- options
; - skip bad songs
; - autosort list
;- songlist load -> reset marked song/position
;- dynamic bitrate display fix for mp3
;- hauptprozess hängt sich manchmal bei song-add auf -> keine message von system-manager
;- clean up (kernel syslib, msgsnd, loader pro modul)
;modules/hardware
;- direct SF3 playback!
;- darky bass/treble/panning/master volume
;- opl4 panning
;- ayc support
;- ST2 auf turboR + korrektur
;new
;==============================================================================
;### CODE-TEIL ################################################################
;==============================================================================
lstmax equ 250 ;number of entries
;### Config
anaflg db 1
ctlrepf db 1
ctlshuf db 0
lstwin db -1 ;songlist window ID (>=0 -> active, =-1 -> not active, 1=open at start)
mixwin db -1 ;mixer window ID (>=0 -> active, =-1 -> not active)
prfwin db -1 ;preferences window ID (-1 = not opened)
sndset_vol db 255 ;volume (0-255)
sndset_pan db 128 ;panning (0-255)
sndset_bas db 128 ;bass (0-255)
sndset_tre db 128 ;treble (0-255)
sndset_ste db 1 ;stereo mode (0=mono, 1=stereo, 2=pseudo stereo, 3=partial stereo)
prgid db "SymAmp":ds 6
;### PRGPRZ -> Programm-Prozess
dskprzn db 2
sysprzn db 3
windatprz equ 3 ;Prozeßnummer
windatsup equ 51 ;Nummer des Superfensters+1 oder 0
prgwin db 0 ;Nummer des Haupt-Fensters
diawin db -1 ;Nummer des Dialog-Fensters
prgprz call SySystem_HLPINI
call prgdbl
ld a,(App_PrcID)
ld (prgwindat+windatprz),a
ld (prglstdat+windatprz),a
ld (properwin+windatprz),a
ld (prgwinmix+windatprz),a
ld (prgwinprf+windatprz),a
call sysini ;Computer-Typ abhängige Initialisierung
call gfxini ;Grafiken aus "Skin" kopieren
call lstini
call lstupd0
ld a,(lstwin) ;Songliste optional anzeigen
dec a
ld a,-1
ld (lstwin),a
call nz,lstopn
call cfgini
ld de,prgwindat
ld a,(App_BnkNum)
call SyDesktop_WINOPN ;open window
jp c,prgend
ld (prgwin),a ;Fenster wurde geöffnet -> Nummer merken
ld hl,prgtims ;Timer hinzufügen
ld a,(App_BnkNum)
call SyKernel_MTADDT
jp c,prgend
ld (prgprztab+0),a
jp sndpar
prgprz0 call msgget
jr nc,prgprz0
ld b,a
ld a,(prgtimn)
db #dd:cp h
jp z,ctlinc ;*** Message vom eigenen Timer bekommen
ld a,b
cp MSC_GEN_FOCUS ;*** Application soll sich Focus nehmen
jp z,prgfoc0
cp MSR_DSK_WFOCUS
jr z,prgfoc
cp MSR_DSK_WCLICK ;*** Fenster-Aktion wurde geklickt
jr nz,prgprz0
ld e,(iy+1)
ld a,(prgwin)
cp e
jr z,prgprz4
ld a,(lstwin)
cp e
jr nz,prgprz9
ld a,(iy+2) ;*** LIST-WINDOW
cp DSK_ACT_CLOSE
jp z,lstswt
jr prgprz7
prgprz9 ld a,(prfwin) ;*** PREFERENCES-WINDOW
cp e
jr nz,prgprz6
ld a,(iy+2)
cp DSK_ACT_CLOSE
jr nz,prgprz5
jp prfclo
prgprz6 ld a,(mixwin) ;*** MIXER-WINDOW
cp e
jr nz,prgprz8
ld a,(iy+2)
cp DSK_ACT_CLOSE
jr nz,prgprz5
jp mixswt
prgprz8 ld a,(diawin)
cp e
jr nz,prgprz0
ld a,(iy+2) ;*** DIALOG-WINDOW
cp DSK_ACT_CLOSE ;*** Close wurde geklickt
jp z,diacnc
jr prgprz5
prgprz4 ld a,(iy+2) ;*** HAUPT-FENSTER ODER SONGLIST
cp DSK_ACT_CLOSE ;*** Close wurde geklickt
jp z,prgend
prgprz7 cp DSK_ACT_KEY ;*** Taste wurde gedrückt
jp z,prgkey
prgprz5 cp DSK_ACT_MENU ;*** Menü wurde geklickt
jr z,prgprz2
cp DSK_ACT_CONTENT ;*** Inhalt wurde geklickt
jr nz,prgprz0
prgprz2 ld l,(iy+8)
ld h,(iy+9)
ld a,l
or h
jp z,prgprz0
ld a,(iy+3) ;A=Klick-Typ (0/1/2=Maus links/rechts/doppelt, 7=Tastatur)
jp (hl)
;### PRGHLP -> shows help
prghlp call SySystem_HLPOPN
jp prgprz0
;### PRGFOC -> Focus-Änderung von Hauptfenster verarbeiten
prgfoc ld e,(iy+1)
ld a,(prgwin)
cp e
jp nz,prgprz0
ld a,(prgwindat)
cp 3
jr nz,prgfoc1
ld a,(lstwin) ;** main window now minimized -> minimize list+equalizer, too
cp -1
jr z,prgfoc3
ld c,MSC_DSK_WINMIN ;minimize list window if existing
call ctlsta2
prgfoc3 ld a,(mixwin)
cp -1
jp z,prgprz0
ld c,MSC_DSK_WINMIN ;minimize equalizer window if existing
call ctlsta2
jp prgprz0
prgfoc1 xor a
ld (prgfoc5+1),a
ld a,(prglstdat) ;** main window now restored -> restore list+equalizer, too
cp 3
jr nz,prgfoc4
ld a,(lstwin)
cp -1
jr z,prgfoc4
ld (prgfoc5+1),a
ld c,MSC_DSK_WINMID
call ctlsta2
prgfoc4 ld a,(prgwinmix)
cp 3
jr nz,prgfoc5
ld a,(mixwin)
cp -1
jr z,prgfoc5
ld (prgfoc5+1),a
ld c,MSC_DSK_WINMID
call ctlsta2
prgfoc5 ld a,0
or a
jp z,prgprz0
prgfoc2 ld a,(prgwin)
ld c,MSC_DSK_WINTOP
call ctlsta2
jp prgprz0
prgfoc0 ld a,(prgwin)
ld b,a
ld c,MSC_DSK_WINMID
call msgsnd
jr prgfoc1
;### PRGKEY -> Taste auswerten
prgkeya equ 24
prgkeyt db "Z":dw ctlrew ;Z=Rückwärts
db "X":dw ctlply ;X=Play
db "C":dw ctlpau ;C=Pause
db "V":dw ctlstp ;V=Stop
db "B":dw ctlffw ;B=Vorwärts
db "L":dw ctlopn ;L=Laden
db "R":dw ctlrep ;R=Repeat
db "S":dw ctlshu ;S=Shuffle
db 139:dw ctlskf ;->=skip forward
db 138:dw ctlskb ;<-=skip backward
db 136:dw ctlvlu ;up=increase volume
db 137:dw ctlvld ;dw=decrease volume
db 156:dw lstswt ;Alt+E=Playlist
db "A":dw lstafi ;A=Add file
db 152:dw lstadi ;Alt+A=Add folder
db 008:dw lstrsl ;Del=Remove Selected
db 127:dw lstral ;Clr=Remove All
db 001:dw lstsal ;Ctrl+A=Select All
db 014:dw lstsno ;Ctrl+N=Select None
db 160:dw lstsiv ;Alt+I=Invert Selection
db "U":dw lsteup ;U=Up
db "D":dw lstedw ;D=Down
db 015:dw lstlod ;Ctrl+O=Load Playlist
db 019:dw lstsav ;Ctrl+S=Save Playlist
prgkey ld hl,prgkeyt
ld b,prgkeya
ld de,3
ld a,(iy+4)
call clcucs
prgkey1 cp (hl)
jr z,prgkey2
add hl,de
djnz prgkey1
jp prgprz0
prgkey2 inc hl
ld a,(hl)
inc hl
ld h,(hl)
ld l,a
ld a,7
jp (hl)
;### PRGEND -> Programm beenden
prgend call sndstp
call mp3del
ld hl,(App_BegCode+prgpstnum)
call SySystem_PRGEND
prgend0 rst #30
jr prgend0
;### PRGINF -> open info window
prginf ld b,1+64+128
ld hl,prgmsginf
call prginf0
jp prgprz0
prginf0 ld a,(App_BnkNum)
ld de,prgwindat
jp SySystem_SYSWRN
;### PRGERR -> Disc-Error-Fenster anzeigen
prgerr ret nc
call clcdez
ld (txterrlod2a),hl
ld b,1+64
ld hl,daterrlod
jr prginf0
;### PRGDBL -> Test, ob Programm bereits läuft
prgdbl xor a
ld (App_BegCode+prgdatnam),a
ld hl,prgid
ld b,l
ld e,h
ld l,a
ld c,MSC_SYS_PRGSRV
ld a,(App_BnkNum)
ld d,a
ld a,PRC_ID_SYSTEM
call msgsnd1
prgdbl1 db #dd:ld h,PRC_ID_SYSTEM
call msgget1
jr nc,prgdbl1
cp MSR_SYS_PRGSRV
jr nz,prgdbl1
ld a,"S"
ld (App_BegCode+prgdatnam),a
ld a,(App_MsgBuf+1)
or a
ret nz
ld a,(App_MsgBuf+9)
ld c,MSC_GEN_FOCUS
call msgsnd1
jp prgend
;==============================================================================
;### SONG-INFO ################################################################
;==============================================================================
;### PRPLST -> Infos über Listeneintrag anzeigen
prplst ld ix,lstentlst
ld hl,lstmem+4
ld a,(prgobjlst1)
or a
jp z,prgprz0
ld bc,4
ld de,17
prplst1 bit 7,(ix+1)
jr nz,prplst2
add hl,de
add ix,bc
dec a
jr nz,prplst1
jp prgprz0
prplst2 push hl
ld a,(ix+0)
call pthget
ld de,propertxt10
call prpinf3
pop hl
call prpinf3
ld a,7
call prpinf
jr prpopn
;### PRPSNG -> Infos über geladenen Song anzeigen
prpsng ld a,(sndinif)
or a
jp z,prgprz0
ld hl,sndfil
ld de,propertxt10
call prpinf3
ld a,19
call prpinf
;### PRPOPN -> Songinfo-Fenster öffnen
prpopn ld de,properwin
jp diaopn
;### PRPLST -> Song-Infos generieren
;### Eingabe A=Anzahl Objekte von Property-Fenster, DE=letztes Filenamen-Zeichen
prpinft db "skmst2mp3pt3modsa2",0
prpinfa dw propertxt2x,propertxt20,propertxt21,propertxt22,propertxt24,propertxt25,propertxt28
prpinf ld (propergrp),a
ld ix,-4
add ix,de
ld iy,prpinft
ld c,0
ld a,(ix+0)
cp "."
jr nz,prpinf6
ld de,3
ld b,1
prpinf7 ld a,(iy+0)
or a
jr z,prpinf6
cp (ix+1):jr nz,prpinf4
ld a,(iy+1):cp (ix+2):jr nz,prpinf4
ld a,(iy+2):cp (ix+3):jr z,prpinf5
prpinf4 add iy,de
inc b
jr prpinf7
prpinf5 ld c,b
prpinf6 ld b,0
ld hl,prpinfa
add hl,bc
add hl,bc
ld a,(hl)
inc hl
ld h,(hl)
ld l,a
ld (properdsc2b),hl
ld a,c
cp 3
ld hl,propertxt23
jr z,prpinf8
cp 4
ld hl,propertxt27
jr z,prpinf8
cp 5
ld hl,propertxt26
jr z,prpinf8
ld hl,propertxt2y
prpinf8 ld (properdsc2c),hl
ret
prpinf3 ld a,(hl)
ldi
or a
jr nz,prpinf3
dec de
ret
;==============================================================================
;### SPECTRUM ANALYZER ########################################################
;==============================================================================
anatab ds 10,1 ;Volume-Tabelle (1-13) für alle 16/10 Frequenzen
anatab0 ds 10,1
;### ANASWT -> Analyzer an-/ausschalten
anaswt ld a,(anaflg)
xor 1
ld (anaflg),a
call z,anaoff
jp prgprz0
;### ANAOFF -> Analyzer löschen
anaoff ld hl,anatab
ld de,anatab+1
ld (hl),1
ld bc,10+10-1
ldir
ld hl,gfx_analyz0+3
ld de,gfx_analyz1+3
ld bc,12*10
ldir
jr anaplt1
;### ANAPLT -> Plottet Analyzer
anaplt call anaupd
ret z
anaplt1 ld e,prgwin_ana
jp winupd
;### ANAUPD -> Analyzer-Grafik updaten
;### Ausgabe ZF=1 keine Änderung stattgefunden
anaupdf db 0 ;Flag, ob Änderung
anaupd xor a
ld (anaupdf),a
ld hl,anatab ;alte Lautstärken verringern
ld b,10
anaupd1 dec (hl)
jr nz,anaupd2
inc (hl)
anaupd2 inc hl
djnz anaupd1
ld a,(snddatchn)
anaupd8 dec a ;neue Lautstärken eintragen
push af
call anaupd7
pop af
jr nz,anaupd8
ld hl,anatab ;Grafik mit Differenzen updaten
ld de,anatab0
ld b,10
anaupd3 ld a,(de)
ld c,(hl)
ldi
inc c
sub c
jr z,anaupd4
push hl
push de
push bc
ld hl,gfx_analyz0+3
jr nc,anaupd5
ld hl,gfx_analyz2+3
ld d,a
add c
ld c,a
ld a,d
neg ;C=Start von unten, A=Länge
anaupd5 ld d,a ;D=Länge
ld a,13
sub c ;A=Start-Position (0-12)
add a
ld c,a
add a
add a
add c
ld c,a ;C=Y*10
ld a,10
sub b
add c
ld c,a ;C=Y*10+X=Offset
ld b,0 ;BC=Offset
ld a,d ;A=Länge
ex de,hl
ld hl,gfx_analyz1+3
add hl,bc
ex de,hl ;DE=Zielgrafik
add hl,bc ;HL=Quellgrafik
ld (anaupdf),a
anaupd6 ldi
ld bc,-11
add hl,bc
ex de,hl
add hl,bc
ex de,hl
dec a
jr nz,anaupd6
pop bc
pop de
pop hl
anaupd4 djnz anaupd3
ld a,(anaupdf)
or a
ret
anaupd7 call sndval
ld c,a
add a
add c
add a:add a ;A=A*12
srl a:srl a:srl a:srl a ;A=A*12/16
inc a
ld e,a
ld a,l
add a:add a:add l:add a ;A=A*10
srl a:srl a:srl a:srl a ;A=A*10/16
ld l,a
ld h,0
ld bc,anatab
add hl,bc
ld (hl),e
ret
;==============================================================================
;### PLAY-LIST ################################################################
;==============================================================================
;### LSTINI -> Playlist init (sets filename pointers)
lstini ld hl,lstmem
ld b,lstmax
ld ix,lstentlst
ld d,0
lstini1 ld (ix+0),d
ld (ix+1),d
ld (ix+2),l
ld (ix+3),h
ld e,17
add hl,de
ld e,4
add ix,de
djnz lstini1
;### LSTNUM -> Playlist renumbering (generates numbers in front of filenames)
lstnum xor a
ld ix,lstentlst
lstnum1 ld hl,prgobjlst1
cp (hl)
ret nc
inc a
ld c,a
ld l,(ix+2)
ld h,(ix+3)
ld de,3
add hl,de
ld (hl)," "
sbc hl,de
inc e
add ix,de
ld e,"0"
lstnum2 cp 100
jr c,lstnum3
sub 100
inc e
jr lstnum2
lstnum3 ld d,a
ld a,e
cp "0"
jr z,lstnum4
ld (hl),a
inc hl
lstnum4 ld a,d
ex de,hl
call clcdez
ex de,hl
ld (hl),e
inc hl
ld (hl),d
inc hl
ld (hl),"."
ld a,c
jr lstnum1
;### LSTOPN -> Öffnet Playlist
lstopn ld hl,lstwin
ld de,prglstdat
call winopn0
ret c
ld hl,prgwinmen4+2
set 1,(hl)
ret
;### LSTSWT -> Schaltet Playliste an/aus
lstswt ld a,(lstwin)
inc a
jr nz,lstswt1
call lstopn
jp c,prgprz0
jp prgfoc2
lstswt1 ld hl,prgwinmen4+2
res 1,(hl)
ld hl,lstwin
jp winclo0
;### LSTUPD -> Baut Liste neu auf inklusive Größe
lstupd call lstupd0
ld a,(lstwin)
ld c,MSC_DSK_WINSLD
call ctlsta2
ld a,(lstwin)
ld c,MSC_DSK_WINDIN
ld e,0
jp ctlsta2
lstupd0 ld a,(prgobjlst1)
or a
jr nz,lstupd1
ld a,2
lstupd1 ld l,a
ld h,0
add hl,hl
add hl,hl
add hl,hl
inc hl
inc hl
ld (prglstobj+16+12),hl
ld (prglstclc+16+12),hl
ld (prglstdat+18),hl
ret
;### LSTREF -> Baut Liste neu auf
lstref ld e,1
ld c,MSC_DSK_WINDIN
ld a,(lstwin)
jp ctlsta2
;### LSTRSL -> Entfernt selektierte Einträge
lstrsl ld a,(prgobjlst1)
sub 1
jp c,prgprz0
ld l,a ;a=last entry
ld h,0
add hl,hl:add hl,hl
ld de,lstentlst+1
add hl,de ;hl=row data
lstrsl1 bit 7,(hl)
jr z,lstrsl2
push af
push hl
ld c,a
call lstrem
pop hl
pop af
lstrsl2 ld de,-4
add hl,de
sub 1
jr nc,lstrsl1
ld a,(prgobjlst1)
or a
jr nz,lstrsl3
ld (lstpthnum),a
lstrsl3 call lstnum
call lstupd
jp lstsno
;### LSTLAS -> finds entry with last string
;### Output IY=entry, DE=string
lstlas ld ix,lstentlst ;ix=entry pointer
ld a,(prgobjlst1) ;a=counter
inc a ;(was already decreased by lstrem)
ld de,lstmem ;de=latest string
push ix:pop iy ;iy=entry with latest string
ld bc,4
lstlas1 ld l,(ix+2)
ld h,(ix+3)
or a
sbc hl,de
jr c,lstlas2
add hl,de ;new stringadr > old
ex de,hl ;store as new latest
push ix:pop iy ;update entry
lstlas2 add ix,bc
dec a
jr nz,lstlas1
ret
;### LSTREM -> removes one entry
;### Input C=entry (0-x)
lstrem ld hl,prgobjlst1
ld a,(hl) ;a=total
sub 1
ret c ;no entry -> finish
ld (hl),a
sub c
push af ;a=total - 1 - entry = entries behind removed
push bc
call lstlas ;iy=entry with latest string, de=latest string
pop hl
ld h,0
add hl,hl
add hl,hl
ld bc,lstentlst+2
add hl,bc ;hl=dest pointer
push hl
ld a,(hl)
inc hl
ld h,(hl)
ld l,a ;hl=dest string
ex de,hl ;hl=latest string, de=dest string
ld (iy+2),e
ld (iy+3),d ;entry with latest string now points to dest string
ld bc,17
ldir ;copy latest to dest
pop de
dec de:dec de
ld hl,4
add hl,de ;hl=area to move
pop af ;a=entries behind to move forward
ret z
ld c,a
ld b,0
sla c:rl b
sla c:rl b
ldir ;move entries forward
ret
;### LSTRAL -> Entfernt alle Einträge
lstral xor a
ld (prgobjlst1),a
ld (lstpthnum),a
call lstral1
jp prgprz0
lstral1 call lstupd
jp lstref
;### LSTSAL -> Selektiert alle Einträge
lstsal ld hl,lstentlst+1
ld b,lstmax
ld de,4
lstsal1 set 7,(hl)
add hl,de
djnz lstsal1
call lstref
jp prgprz0
;### LSTSNO -> Deselektiert alle Einträge
lstsno ld hl,lstentlst+1
ld b,lstmax
ld de,4
lstsno1 res 7,(hl)
add hl,de
djnz lstsno1
call lstref
jp prgprz0
;### LSTSIV -> Invertiert Selektion
lstsiv ld hl,lstentlst+1
ld b,lstmax
ld de,4
lstsiv1 ld a,(hl)
xor 128
ld (hl),a
add hl,de
djnz lstsiv1
call lstref
jp prgprz0
;### LSTEUP -> Selektierte Einträge einen Platz nach oben
lsteup ld a,(prgobjlst1)
sub 1
jp c,prgprz0
jp z,prgprz0
ld ix,lstentlst+4
ld b,a
ld de,4
ld a,1
lsteup0 ld (lsteup1+2),a
lsteup1 bit 7,(ix+1)
jr z,lsteup2
ld a,(ix+0):ld c,(ix-4):ld (ix-4),a:ld (ix+0),c
ld a,(ix+1):ld c,(ix-3):ld (ix-3),a:ld (ix+1),c
ld a,(ix+2):ld c,(ix-2):ld (ix-2),a:ld (ix+2),c
ld a,(ix+3):ld c,(ix-1):ld (ix-1),a:ld (ix+3),c
lsteup2 add ix,de
djnz lsteup1
call lstnum
call lstref
jp prgprz0
;### LSTEDW -> Selektierte Einträge einen Platz nach unten
lstedw ld a,(prgobjlst1)
sub 1
jp c,prgprz0
jp z,prgprz0
ld b,a
ld l,a
ld h,0
add hl,hl:add hl,hl
ex de,hl
ld ix,lstentlst
add ix,de
ld de,-4
ld a,-3
jr lsteup0
;### LSTADD -> adds filename to list
;### Input BC=filename (0-terminated), A=pathID
;### Output CF=1 memory full
lstadd push af
ld hl,prgobjlst1
ld a,(hl)
cp lstmax
jr z,lstadd0
inc (hl)
ld l,a
ld h,0
ld e,l
ld d,h
add hl,hl
add hl,hl ;*4
push hl
add hl,hl
add hl,hl
add hl,de ;*17
ld de,lstmem
add hl,de
push hl
ld de,4
add hl,de
ex de,hl ;de=dest string
ld l,c
ld h,b
ldi
ld b,12
lstadd1 ld a,(hl)
call clclcs
ld (de),a
inc hl
inc de
djnz lstadd1
pop de
pop hl
pop af
ld bc,lstentlst
add hl,bc
ld (hl),a ;store path ID
inc hl:inc hl
ld (hl),e ;store string address
inc hl
ld (hl),d
ret
lstadd0 pop af
scf
ret
;### LSTAFI -> Fügt Datei hinzu
lstafim db 0 ;0=Datei hinzufügen, 1=Verzeichnis hinzufügen
lstafi ld c,0
ld a,(prgobjlst1)
cp lstmax
jr c,lstafi4
ld hl,daterrlfe
call lstafi1
jp prgprz0
lstafi4 ld a,c
ld (lstafim),a
ld hl,lstmsk
ld a,(App_BnkNum)
rrc c
or c
ld c,8
ld ix,100
ld iy,10000
ld de,prgwindat
call SySystem_SELOPN
or a
jp nz,prgprz0
call lstafi0
jp prgprz0
lstafi0 ld hl,lstfil
push hl
call ctlnam0 ;HL=Pfad -> HL=Name (directly behind "/")
pop de ;DE=Pfad
push hl
or a
sbc hl,de
ld c,l ;c=pathlen including "/"
pop hl
ret z ;kein Pfad gefunden -> Fehler, nicht hinzufügen
push hl
ex de,hl
call pthfnd ;A=path number (0-x), DE=path, CF=1 memory full
pop bc ;bc=name
ld hl,daterrlfp
jr c,lstafi1 ;too many pathes
ld hl,lstafim
dec (hl)
jr z,lstadi1
call lstadd ;add single file
ld hl,daterrlfe
jr c,lstafi1 ;too many entries
call lstnum
jp lstral1
lstafi1 ld b,1+64
jp prginf0
;### LSTADI -> Fügt Verzeichnis hinzu
dirmsk db "skmst2binmp3pt3modsa2",0
lstadib ds 32
lstadi ld c,1
jp lstafi4
lstadi1 push de
ld (lstadi7+1),a ;store path ID
xor a ;*** Speicher für Dir reservieren
ld e,a
ld bc,5500
push bc
rst #20:dw jmp_memget
pop bc
pop de
ret c
ld (prgmemtab+0),a
ld (prgmemtab+1),hl
ld (prgmemtab+3),bc
ex de,hl ;*** Directory laden
ld ix,(App_BnkNum-1)
db #dd:ld l,16+8
ld iy,0
call SyFile_DIRINP
jp c,lstadi0
ld c,l
ld b,h ;BC=Anzahl Einträge
ld hl,(prgmemtab+1) ;HL=Zeiger auf Daten
lstadi2 push bc
push hl
ld de,lstadib ;*** Eintrag aus Directory holen
ld a,(prgmemtab+0)
ld c,a
ld a,(App_BnkNum)
add a:add a:add a:add a
add c
ld bc,32
rst #20:dw jmp_bnkcop
ld hl,lstadib+9 ;*** Test, ob unterstützte Erweiterung
lstadi8 ld a,(hl)
inc hl
or a
jr z,lstadi6 ;kein Punkt gefunden -> kein Extension, also kein gültiges File
cp "."
jr nz,lstadi8
push hl
pop ix
ld hl,dirmsk-1
lstadi9 inc hl
ld a,(hl) ;Test, ob gültige Filemaske
or a
jr z,lstadi6 ;keine gültige Filemaske gefunden -> Ende
ld c,a
inc hl
ld b,(hl)
inc hl
ld a,(ix+2)
call clclcs
cp (hl)
jr nz,lstadi9
ld a,(ix+0)
call clclcs
cp c
jr nz,lstadi9
ld a,(ix+1)
call clclcs
cp b
jr nz,lstadi9
ld bc,lstadib+9 ;*** gültigen Eintrag Liste hinzufügen
lstadi7 ld a,0
call lstadd
lstadi6 ld hl,lstadib+9
call strlen
ld hl,9+1
add hl,bc
pop bc
add hl,bc
pop bc
ld a,(prgobjlst1)
cp lstmax
jr z,lstadi5
dec bc
ld a,c
or b