build.gradle

allprojects {
    group 'fr.mrcubee.minecraft.library'
    version '1.0'
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'maven-publish'

    repositories {
        maven {
            url 'https://nexus.mrcubee.net/repository/minecraft/'
        }
        mavenCentral()
    }

    tasks.withType(JavaCompile).configureEach {
        options.compilerArgs += ["-source", "1.8", "-target", "1.8"]
    }

    compileJava.options.encoding = 'UTF-8'

    dependencies {
        compileOnly 'org.spigotmc:spigot-api:1.8.8-R0.1-SNAPSHOT'
    }

    publishing {
        repositories {
            maven {
                url = 'https://nexus.mrcubee.net/repository/minecraft'
                credentials {
                    username = System.getenv("MAVEN_USERNAME")
                    password = System.getenv("MAVEN_PASSWORD")
                }
            }
        }
        publications {
            shadow(MavenPublication) {
                from components.java
                pom {
                    name = project.name
                    description = project.description
                    url = 'https://github.com/MrCubee/ExpressGUI'
                    developers {
                        developer {
                            id = 'mrcubee'
                            name = 'MrCubee'
                            email = 'contact@mrcubee.net'
                        }
                    }
                }
            }
        }
    }
}