build.gradle

plugins {
  id 'maven-publish'
  id 'java'
  id 'eclipse'
  id 'idea'
  id 'net.minecraftforge.licenser' version '1.0.1'
  id 'net.minecraftforge.gradleutils' version '[2.3,2.4)'
  id 'net.minecraftforge.gradle' version '[6.0,6.1)'
}

repositories {
    mavenCentral()
}

changelog {
    from '1.0'
}

ext {
    GIT_REPO = 'LexManos/CobbleForDays'
}

dependencies {
    minecraft 'net.minecraftforge:forge:1.21-51.0.28'
    // Hack fix for now, force jopt-simple to be exactly 5.0.4 because Mojang ships that version, but some transtive dependencies request 6.0+ 
    implementation('net.sf.jopt-simple:jopt-simple:5.0.4') { version { strictly '5.0.4' } }
}

sourceSets {
    main {
        resources {
            srcDirs += ['src/generated/resources']
        }
    }
}

minecraft {
    mappings channel: 'official', version: '1.21'
    //accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg')
    runs {
        client {
            workingDirectory project.file('run')
            //property 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'
            property 'forge.logging.console.level', 'debug'

            mods {
                cobblefordays {
                    source sourceSets.main
                }
            }
        }

        server {
            workingDirectory project.file('run')
            //property 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'
            property 'forge.logging.console.level', 'debug'

            mods {
                cobblefordays {
                    source sourceSets.main
                }
            }
        }

        data {
            workingDirectory project.file('run')
            //property 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'
            property 'forge.logging.console.level', 'debug'
            args '--mod', 'cobblefordays', '--all', '--output', file('src/generated/resources/'), '--existing', sourceSets.main.resources.srcDirs[0]
            mods {
                cobblefordays {
                    source sourceSets.main
                }
            }
        }
    }
}

group = 'net.minecraftforge.lex'
version = gradleutils.tagOffsetVersion
logger.lifecycle('Version: ' + version)
java.toolchain.languageVersion = JavaLanguageVersion.of(21)
java.withSourcesJar()

license {
  header project.file('LICENSE-header.txt')
  newLine false
}

ext {
    changelog = rootProject.file('build/changelog.txt')
    MANIFEST = manifest{
        attributes([
            'Specification-Title':      project.name,
            'Specification-Vendor':     'Forge Development LLC',
            'Specification-Version':    project.version,
            'Implementation-Title':     project.name,
            'Implementation-Version':   project.version,
            'Implementation-Vendor':    'Forge Development LLC'
        ] as LinkedHashMap)
    }
}

compileJava {
    options.encoding = 'UTF-8'
}

sourceSets.each {
    def dir = layout.buildDirectory.dir("sourcesSets/$it.name")
    it.output.resourcesDir = dir
    it.java.destinationDirectory = dir
}

jar {
    manifest.from(MANIFEST)
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            pom {
                name = project.archivesBaseName
                packaging = 'jar'
                url = "https://github.com/${GIT_REPO}"

                scm {
                    url = "https://github.com/${GIT_REPO}"
                    connection = "scm:git:git://github.com/${GIT_REPO}.git"
                    developerConnection = "scm:git:git@github.com:${GIT_REPO}.git"
                }

                issueManagement {
                    system = 'github'
                    url = "https://github.com/${GIT_REPO}/issues"
                }

                developers {
                    developer {
                        id = 'LexManos'
                        name = 'Lex Manos'
                    }
                }
            }
        }
    }
    repositories {
        maven gradleutils.publishingForgeMaven
    }
}