forked from apb2006/xqparserperf
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathxquery30.ebfn
695 lines (693 loc) · 20.8 KB
/
xquery30.ebfn
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
XQuery ::= Module EOF
Module ::= VersionDecl? ( LibraryModule | MainModule )
VersionDecl
::= 'xquery' ( 'encoding' StringLiteral | 'version' StringLiteral ( 'encoding' StringLiteral )? ) Separator
MainModule
::= Prolog QueryBody
LibraryModule
::= ModuleDecl Prolog
ModuleDecl
::= 'module' 'namespace' NCName '=' URILiteral Separator
Prolog ::= ( ( DefaultNamespaceDecl | Setter | NamespaceDecl | Import ) Separator )* ( ( ContextItemDecl | AnnotatedDecl | OptionDecl ) Separator )*
Separator
::= ';'
Setter ::= BoundarySpaceDecl
| DefaultCollationDecl
| BaseURIDecl
| ConstructionDecl
| OrderingModeDecl
| EmptyOrderDecl
| CopyNamespacesDecl
| DecimalFormatDecl
BoundarySpaceDecl
::= 'declare' 'boundary-space' ( 'preserve' | 'strip' )
DefaultCollationDecl
::= 'declare' 'default' 'collation' URILiteral
BaseURIDecl
::= 'declare' 'base-uri' URILiteral
ConstructionDecl
::= 'declare' 'construction' ( 'strip' | 'preserve' )
OrderingModeDecl
::= 'declare' 'ordering' ( 'ordered' | 'unordered' )
EmptyOrderDecl
::= 'declare' 'default' 'order' 'empty' ( 'greatest' | 'least' )
CopyNamespacesDecl
::= 'declare' 'copy-namespaces' PreserveMode ',' InheritMode
PreserveMode
::= 'preserve'
| 'no-preserve'
InheritMode
::= 'inherit'
| 'no-inherit'
DecimalFormatDecl
::= 'declare' ( 'decimal-format' EQName | 'default' 'decimal-format' ) ( DFPropertyName '=' StringLiteral )*
DFPropertyName
::= 'decimal-separator'
| 'grouping-separator'
| 'infinity'
| 'minus-sign'
| 'NaN'
| 'percent'
| 'per-mille'
| 'zero-digit'
| 'digit'
| 'pattern-separator'
Import ::= SchemaImport
| ModuleImport
SchemaImport
::= 'import' 'schema' SchemaPrefix? URILiteral ( 'at' URILiteral ( ',' URILiteral )* )?
SchemaPrefix
::= 'namespace' NCName '='
| 'default' 'element' 'namespace'
ModuleImport
::= 'import' 'module' ( 'namespace' NCName '=' )? URILiteral ( 'at' URILiteral ( ',' URILiteral )* )?
NamespaceDecl
::= 'declare' 'namespace' NCName '=' URILiteral
DefaultNamespaceDecl
::= 'declare' 'default' ( 'element' | 'function' ) 'namespace' URILiteral
AnnotatedDecl
::= 'declare' Annotation* ( VarDecl | FunctionDecl )
Annotation
::= '%' EQName ( '(' Literal ( ',' Literal )* ')' )?
VarDecl ::= 'variable' '$' VarName TypeDeclaration? ( ':=' VarValue | 'external' ( ':=' VarDefaultValue )? )
VarValue ::= ExprSingle
VarDefaultValue
::= ExprSingle
ContextItemDecl
::= 'declare' 'context' 'item' ( 'as' ItemType )? ( ':=' VarValue | 'external' ( ':=' VarDefaultValue )? )
FunctionDecl
::= 'function' EQName '(' ParamList? ')' ( 'as' SequenceType )? ( FunctionBody | 'external' )
ParamList
::= Param ( ',' Param )*
Param ::= '$' EQName TypeDeclaration?
FunctionBody
::= EnclosedExpr
EnclosedExpr
::= '{' Expr '}'
OptionDecl
::= 'declare' 'option' EQName StringLiteral
QueryBody
::= Expr
Expr ::= ExprSingle ( ',' ExprSingle )*
ExprSingle
::= FLWORExpr
| QuantifiedExpr
| SwitchExpr
| TypeswitchExpr
| IfExpr
| TryCatchExpr
| OrExpr
FLWORExpr
::= InitialClause IntermediateClause* ReturnClause
InitialClause
::= ForClause
| LetClause
| WindowClause
IntermediateClause
::= InitialClause
| WhereClause
| GroupByClause
| OrderByClause
| CountClause
ForClause
::= 'for' ForBinding ( ',' ForBinding )*
ForBinding
::= '$' VarName TypeDeclaration? AllowingEmpty? PositionalVar? 'in' ExprSingle
AllowingEmpty
::= 'allowing' 'empty'
PositionalVar
::= 'at' '$' VarName
LetClause
::= 'let' LetBinding ( ',' LetBinding )*
LetBinding
::= '$' VarName TypeDeclaration? ':=' ExprSingle
WindowClause
::= 'for' ( TumblingWindowClause | SlidingWindowClause )
TumblingWindowClause
::= 'tumbling' 'window' '$' VarName TypeDeclaration? 'in' ExprSingle WindowStartCondition WindowEndCondition?
SlidingWindowClause
::= 'sliding' 'window' '$' VarName TypeDeclaration? 'in' ExprSingle WindowStartCondition WindowEndCondition
WindowStartCondition
::= 'start' WindowVars 'when' ExprSingle
WindowEndCondition
::= 'only'? 'end' WindowVars 'when' ExprSingle
WindowVars
::= ( '$' CurrentItem )? PositionalVar? ( 'previous' '$' PreviousItem )? ( 'next' '$' NextItem )?
CurrentItem
::= EQName
PreviousItem
::= EQName
NextItem ::= EQName
CountClause
::= 'count' '$' VarName
WhereClause
::= 'where' ExprSingle
GroupByClause
::= 'group' 'by' GroupingSpecList
GroupingSpecList
::= GroupingSpec ( ',' GroupingSpec )*
GroupingSpec
::= '$' VarName ( 'collation' URILiteral )?
OrderByClause
::= ( 'order' 'by' | 'stable' 'order' 'by' ) OrderSpecList
OrderSpecList
::= OrderSpec ( ',' OrderSpec )*
OrderSpec
::= ExprSingle OrderModifier
OrderModifier
::= ( 'ascending' | 'descending' )? ( 'empty' ( 'greatest' | 'least' ) )? ( 'collation' URILiteral )?
ReturnClause
::= 'return' ExprSingle
QuantifiedExpr
::= ( 'some' | 'every' ) '$' VarName TypeDeclaration? 'in' ExprSingle ( ',' '$' VarName TypeDeclaration? 'in' ExprSingle )* 'satisfies' ExprSingle
SwitchExpr
::= 'switch' '(' Expr ')' SwitchCaseClause+ 'default' 'return' ExprSingle
SwitchCaseClause
::= ( 'case' SwitchCaseOperand )+ 'return' ExprSingle
SwitchCaseOperand
::= ExprSingle
TypeswitchExpr
::= 'typeswitch' '(' Expr ')' CaseClause+ 'default' ( '$' VarName )? 'return' ExprSingle
CaseClause
::= 'case' ( '$' VarName 'as' )? SequenceTypeUnion 'return' ExprSingle
SequenceTypeUnion
::= SequenceType ( '|' SequenceType )*
IfExpr ::= 'if' '(' Expr ')' 'then' ExprSingle 'else' ExprSingle
TryCatchExpr
::= TryClause CatchClause+
TryClause
::= 'try' '{' TryTargetExpr '}'
TryTargetExpr
::= Expr
CatchClause
::= 'catch' CatchErrorList '{' Expr '}'
CatchErrorList
::= NameTest ( '|' NameTest )*
OrExpr ::= AndExpr ( 'or' AndExpr )*
AndExpr ::= ComparisonExpr ( 'and' ComparisonExpr )*
ComparisonExpr
::= RangeExpr ( ( ValueComp | GeneralComp | NodeComp ) RangeExpr )?
RangeExpr
::= AdditiveExpr ( 'to' AdditiveExpr )?
AdditiveExpr
::= MultiplicativeExpr ( ( '+' | '-' ) MultiplicativeExpr )*
MultiplicativeExpr
::= UnionExpr ( ( '*' | 'div' | 'idiv' | 'mod' ) UnionExpr )*
UnionExpr
::= IntersectExceptExpr ( ( 'union' | '|' ) IntersectExceptExpr )*
IntersectExceptExpr
::= InstanceofExpr ( ( 'intersect' | 'except' ) InstanceofExpr )*
InstanceofExpr
::= TreatExpr ( 'instance' 'of' SequenceType )?
TreatExpr
::= CastableExpr ( 'treat' 'as' SequenceType )?
CastableExpr
::= CastExpr ( 'castable' 'as' SingleType )?
CastExpr ::= UnaryExpr ( 'cast' 'as' SingleType )?
UnaryExpr
::= ( '-' | '+' )* ValueExpr
ValueExpr
::= ValidateExpr
| PathExpr
| ExtensionExpr
GeneralComp
::= '='
| '!='
| '<'
| '<='
| '>'
| '>='
ValueComp
::= 'eq'
| 'ne'
| 'lt'
| 'le'
| 'gt'
| 'ge'
NodeComp ::= 'is'
| '<<'
| '>>'
ValidateExpr
::= 'validate' ( ValidationMode | 'type' TypeName )? '{' Expr '}'
ValidationMode
::= 'lax'
| 'strict'
ExtensionExpr
::= Pragma+ '{' Expr? '}'
Pragma ::= '(#' S? EQName ( S PragmaContents )? '#)'
/* ws: explicit */
PathExpr ::= '/' ( RelativePathExpr / )
| '//' RelativePathExpr
| RelativePathExpr
RelativePathExpr
::= StepExpr ( ( '/' | '//' ) StepExpr )*
StepExpr ::= PostfixExpr
| AxisStep
AxisStep ::= ( ReverseStep | ForwardStep ) PredicateList
ForwardStep
::= ForwardAxis NodeTest
| AbbrevForwardStep
ForwardAxis
::= 'child' '::'
| 'descendant' '::'
| 'attribute' '::'
| 'self' '::'
| 'descendant-or-self' '::'
| 'following-sibling' '::'
| 'following' '::'
AbbrevForwardStep
::= '@'? NodeTest
ReverseStep
::= ReverseAxis NodeTest
| AbbrevReverseStep
ReverseAxis
::= 'parent' '::'
| 'ancestor' '::'
| 'preceding-sibling' '::'
| 'preceding' '::'
| 'ancestor-or-self' '::'
AbbrevReverseStep
::= '..'
NodeTest ::= KindTest
| NameTest
NameTest ::= EQName
| Wildcard
PostfixExpr
::= PrimaryExpr ( Predicate | ArgumentList )*
ArgumentList
::= '(' ( Argument ( ',' Argument )* )? ')'
PredicateList
::= Predicate*
Predicate
::= '[' Expr ']'
PrimaryExpr
::= Literal
| VarRef
| ParenthesizedExpr
| ContextItemExpr
| FunctionCall
| OrderedExpr
| UnorderedExpr
| Constructor
| FunctionItemExpr
Literal ::= NumericLiteral
| StringLiteral
NumericLiteral
::= IntegerLiteral
| DecimalLiteral
| DoubleLiteral
VarRef ::= '$' VarName
VarName ::= EQName
ParenthesizedExpr
::= '(' Expr? ')'
ContextItemExpr
::= '.'
OrderedExpr
::= 'ordered' '{' Expr '}'
UnorderedExpr
::= 'unordered' '{' Expr '}'
FunctionCall
::= FunctionName ArgumentList
Argument ::= ExprSingle
| ArgumentPlaceholder
ArgumentPlaceholder
::= '?'
Constructor
::= DirectConstructor
| ComputedConstructor
DirectConstructor
::= DirElemConstructor
| DirCommentConstructor
| DirPIConstructor
DirElemConstructor
::= '<' QName DirAttributeList ( '/>' | '>' DirElemContent* '</' QName S? '>' )
/* ws: explicit */
DirAttributeList
::= ( S ( QName S? '=' S? DirAttributeValue )? )*
/* ws: explicit */
DirAttributeValue
::= '"' ( EscapeQuot | QuotAttrValueContent )* '"'
| "'" ( EscapeApos | AposAttrValueContent )* "'"
/* ws: explicit */
QuotAttrValueContent
::= QuotAttrContentChar
| CommonContent
AposAttrValueContent
::= AposAttrContentChar
| CommonContent
DirElemContent
::= DirectConstructor
| CDataSection
| CommonContent
| ElementContentChar
CommonContent
::= PredefinedEntityRef
| CharRef
| '{{'
| '}}'
| EnclosedExpr
DirCommentConstructor
::= '<!--' DirCommentContents '-->'
/* ws: explicit */
DirPIConstructor
::= '<?' PITarget ( S DirPIContents )? '?>'
/* ws: explicit */
CDataSection
::= '<![CDATA[' CDataSectionContents ']]>'
/* ws: explicit */
ComputedConstructor
::= CompDocConstructor
| CompElemConstructor
| CompAttrConstructor
| CompNamespaceConstructor
| CompTextConstructor
| CompCommentConstructor
| CompPIConstructor
CompDocConstructor
::= 'document' '{' Expr '}'
CompElemConstructor
::= 'element' ( EQName | '{' Expr '}' ) '{' ContentExpr? '}'
ContentExpr
::= Expr
CompAttrConstructor
::= 'attribute' ( EQName | '{' Expr '}' ) '{' Expr? '}'
CompNamespaceConstructor
::= 'namespace' ( Prefix | '{' PrefixExpr '}' ) '{' URIExpr? '}'
Prefix ::= NCName
PrefixExpr
::= Expr
URIExpr ::= Expr
CompTextConstructor
::= 'text' '{' Expr '}'
CompCommentConstructor
::= 'comment' '{' Expr '}'
CompPIConstructor
::= 'processing-instruction' ( NCName | '{' Expr '}' ) '{' Expr? '}'
FunctionItemExpr
::= LiteralFunctionItem
| InlineFunction
LiteralFunctionItem
::= EQName '#' IntegerLiteral
InlineFunction
::= 'function' '(' ParamList? ')' ( 'as' SequenceType )? EnclosedExpr
SingleType
::= AtomicOrUnionType '?'?
TypeDeclaration
::= 'as' SequenceType
SequenceType
::= 'empty-sequence' '(' ')'
| ItemType ( OccurrenceIndicator / )
OccurrenceIndicator
::= '?'
| '*'^OccurrenceIndicator
| '+'
ItemType ::= KindTest
| 'item' '(' ')'
| FunctionTest
| AtomicOrUnionType
| ParenthesizedItemType
AtomicOrUnionType
::= EQName
KindTest ::= DocumentTest
| ElementTest
| AttributeTest
| SchemaElementTest
| SchemaAttributeTest
| PITest
| CommentTest
| TextTest
| NamespaceNodeTest
| AnyKindTest
AnyKindTest
::= 'node' '(' ')'
DocumentTest
::= 'document-node' '(' ( ElementTest | SchemaElementTest )? ')'
TextTest ::= 'text' '(' ')'
CommentTest
::= 'comment' '(' ')'
NamespaceNodeTest
::= 'namespace-node' '(' ')'
PITest ::= 'processing-instruction' '(' ( NCName | StringLiteral )? ')'
AttributeTest
::= 'attribute' '(' ( AttribNameOrWildcard ( ',' TypeName )? )? ')'
AttribNameOrWildcard
::= AttributeName
| '*'
SchemaAttributeTest
::= 'schema-attribute' '(' AttributeDeclaration ')'
AttributeDeclaration
::= AttributeName
ElementTest
::= 'element' '(' ( ElementNameOrWildcard ( ',' TypeName '?'? )? )? ')'
ElementNameOrWildcard
::= ElementName
| '*'
SchemaElementTest
::= 'schema-element' '(' ElementDeclaration ')'
ElementDeclaration
::= ElementName
AttributeName
::= EQName
ElementName
::= EQName
TypeName ::= EQName
FunctionTest
::= Annotation* ( AnyFunctionTest | TypedFunctionTest )
AnyFunctionTest
::= 'function' '(' '*' ')'
TypedFunctionTest
::= 'function' '(' ( SequenceType ( ',' SequenceType )* )? ')' 'as' SequenceType
ParenthesizedItemType
::= '(' ItemType ')'
EQName ::= FunctionName
| 'attribute'
| 'comment'
| 'document-node'
| 'element'
| 'empty-sequence'
| 'function'
| 'if'
| 'item'
| 'namespace-node'
| 'node'
| 'processing-instruction'
| 'schema-attribute'
| 'schema-element'
| 'switch'
| 'text'
| 'typeswitch'
FunctionName
::= EQName^Token
| 'ancestor'
| 'ancestor-or-self'
| 'and'
| 'ascending'
| 'case'
| 'cast'
| 'castable'
| 'child'
| 'collation'
| 'count'
| 'declare'
| 'default'
| 'descendant'
| 'descendant-or-self'
| 'descending'
| 'div'
| 'document'
| 'else'
| 'empty'
| 'end'
| 'eq'
| 'every'
| 'except'
| 'following'
| 'following-sibling'
| 'for'
| 'ge'
| 'group'
| 'gt'
| 'idiv'
| 'import'
| 'instance'
| 'intersect'
| 'is'
| 'le'
| 'let'
| 'lt'
| 'mod'
| 'module'
| 'namespace'
| 'ne'
| 'only'
| 'or'
| 'order'
| 'ordered'
| 'parent'
| 'preceding'
| 'preceding-sibling'
| 'return'
| 'satisfies'
| 'self'
| 'some'
| 'stable'
| 'start'
| 'to'
| 'treat'
| 'try'
| 'union'
| 'unordered'
| 'validate'
| 'where'
| 'xquery'
NCName ::= NCName^Token
| 'and'
| 'ascending'
| 'case'
| 'cast'
| 'castable'
| 'collation'
| 'count'
| 'default'
| 'descending'
| 'div'
| 'else'
| 'empty'
| 'end'
| 'eq'
| 'except'
| 'for'
| 'ge'
| 'group'
| 'gt'
| 'idiv'
| 'instance'
| 'intersect'
| 'is'
| 'le'
| 'let'
| 'lt'
| 'mod'
| 'ne'
| 'only'
| 'or'
| 'order'
| 'return'
| 'satisfies'
| 'stable'
| 'start'
| 'to'
| 'treat'
| 'union'
| 'where'
Whitespace
::= S^WS
| Comment
/* ws: definition */
Comment ::= '(:' ( CommentContents | Comment )* ':)'
/* ws: explicit */
<?TOKENS?>
EOF ::= $
PragmaContents
::= ( Char* - ( Char* '#)' Char* ) ) & '#'
DirCommentContents
::= ( ( Char - '-' ) | '-' ( Char - '-' ) )*
/* ws: explicit */
DirPIContents
::= ( Char* - ( Char* '?>' Char* ) ) & '?'
/* ws: explicit */
CDataSectionContents
::= ( Char* - ( Char* ']]>' Char* ) ) & ']]'
/* ws: explicit */
Wildcard ::= '*'
| NCName ':' '*'
| '*' ':' NCName
| URILiteral ':' '*'
/* ws: explicit */
EQName ::= QName
| URIQualifiedName
URIQualifiedName
::= URILiteral ':' NCName
/* ws: explicit */
URILiteral
::= StringLiteral
IntegerLiteral
::= Digits
DecimalLiteral
::= '.' Digits
| Digits '.' [0-9]*
/* ws: explicit */
DoubleLiteral
::= ( '.' Digits | Digits ( '.' [0-9]* )? ) [eE] [+#x2D]? Digits
/* ws: explicit */
StringLiteral
::= '"' ( PredefinedEntityRef | CharRef | EscapeQuot | [^"&] )* '"'
| "'" ( PredefinedEntityRef | CharRef | EscapeApos | [^'&] )* "'"
/* ws: explicit */
PredefinedEntityRef
::= '&' ( 'lt' | 'gt' | 'amp' | 'quot' | 'apos' ) ';'
/* ws: explicit */
EscapeQuot
::= '""'
EscapeApos
::= "''"
ElementContentChar
::= Char - [{}<&]
QuotAttrContentChar
::= Char - ["{}<&]
AposAttrContentChar
::= Char - ['{}<&]
PITarget ::= Name - ( ( 'X' | 'x' ) ( 'M' | 'm' ) ( 'L' | 'l' ) )
NameStartChar
::= ':'
| [A-Z]
| '_'
| [a-z]
| [#x00C0-#x00D6]
| [#x00D8-#x00F6]
| [#x00F8-#x02FF]
| [#x0370-#x037D]
| [#x037F-#x1FFF]
| [#x200C-#x200D]
| [#x2070-#x218F]
| [#x2C00-#x2FEF]
| [#x3001-#xD7FF]
| [#xF900-#xFDCF]
| [#xFDF0-#xFFFD]
| [#x10000-#xEFFFF]
NameChar ::= NameStartChar
| '-'
| '.'
| [0-9]
| #x00B7
| [#x0300-#x036F]
| [#x203F-#x2040]
Name ::= NameStartChar NameChar*
CharRef ::= '&#' [0-9]+ ';'
| '&#x' [0-9a-fA-F]+ ';'
NCName ::= Name - ( Char* ':' Char* )
QName ::= PrefixedName
| UnprefixedName
PrefixedName
::= Prefix ':' LocalPart
UnprefixedName
::= LocalPart
Prefix ::= NCName
LocalPart
::= NCName
S ::= ( #x0020 | #x0009 | #x000D | #x000A )+
Char ::= #x0009
| #x000A
| #x000D
| [#x0020-#xD7FF]
| [#xE000-#xFFFD]
| [#x10000-#x10FFFF]
Digits ::= [0-9]+
CommentContents
::= ( ( [^(:] | '('+ [^(:] | ':'+ [^:)] )+ | '(' ) '('* & '('
| ( ( [^(:] | '('+ [^(:] | ':'+ [^:)] )+ | ':' ) ':'* & ':'
'*' << Wildcard '*'^OccurrenceIndicator
EQName^Token
<< 'ancestor' 'ancestor-or-self' 'and' 'ascending' 'attribute' 'case' 'cast' 'castable' 'child' 'collation' 'comment' 'count' 'declare' 'default' 'descendant' 'descendant-or-self' 'descending' 'div' 'document' 'document-node' 'element' 'else' 'empty' 'empty-sequence' 'end' 'eq' 'every' 'except' 'following' 'following-sibling' 'for' 'function' 'ge' 'group' 'gt' 'idiv' 'if' 'import' 'instance' 'intersect' 'is' 'item' 'le' 'let' 'lt' 'mod' 'module' 'namespace' 'namespace-node' 'ne' 'node' 'only' 'or' 'order' 'ordered' 'parent' 'preceding' 'preceding-sibling' 'processing-instruction' 'return' 'satisfies' 'schema-attribute' 'schema-element' 'self' 'some' 'stable' 'start' 'switch' 'text' 'to' 'treat' 'try' 'typeswitch' 'union' 'unordered' 'validate' 'where' 'xquery'
NCName^Token
<< 'and' 'ascending' 'case' 'cast' 'castable' 'collation' 'count' 'default' 'descending' 'div' 'else' 'empty' 'end' 'eq' 'except' 'for' 'ge' 'group' 'gt' 'idiv' 'instance' 'intersect' 'is' 'le' 'let' 'lt' 'mod' 'ne' 'only' 'or' 'order' 'return' 'satisfies' 'stable' 'start' 'to' 'treat' 'union' 'where'