db-analyser: add DumpStakeDistributions pass

Author: nfrisby

ouroboros-consensus-cardano/app/DBAnalyser/Parsers.hs

@@ -120,6 +120,10 @@ parseAnalysis = asum [
         ]
     , benchmarkLedgerOpsParser
     , getBlockApplicationMetrics
+    , flag' DumpStakeDistributions $ mconcat [
+          long "dump-stake-distributions"
+        , help "Show the stake distribution for each epoch of some processed block"
+        ]
     , pure OnlyValidation
     ]
 

ouroboros-consensus-cardano/src/unstable-cardano-tools/Cardano/Tools/DBAnalyser/Analysis.hs

@@ -25,6 +25,8 @@ module Cardano.Tools.DBAnalyser.Analysis (
   , runAnalysis
   ) where
 
+import           Cardano.Ledger.Crypto (StandardCrypto)
+import qualified Cardano.Ledger.PoolDistr as SL
 import qualified Cardano.Slotting.Slot as Slotting
 import qualified Cardano.Tools.DBAnalyser.Analysis.BenchmarkLedgerOps.FileWriting as F
 import qualified Cardano.Tools.DBAnalyser.Analysis.BenchmarkLedgerOps.SlotDataPoint as DP
@@ -115,6 +117,7 @@ runAnalysis analysisName = case go analysisName of
     go (ReproMempoolAndForge nBks)                       = mkAnalysis $ reproMempoolForge nBks
     go (BenchmarkLedgerOps mOutfile lgrAppMode)          = mkAnalysis $ benchmarkLedgerOps mOutfile lgrAppMode
     go (GetBlockApplicationMetrics nrBlocks mOutfile)    = mkAnalysis $ getBlockApplicationMetrics nrBlocks mOutfile
+    go DumpStakeDistributions                            = mkAnalysis $ dumpStakeDistributions
 
     mkAnalysis ::
          forall startFrom. SingI startFrom
@@ -218,6 +221,7 @@ data TraceEvent blk =
     --   * monotonic time to call 'Mempool.getSnapshotFor'
     --   * total time spent in the mutator when calling 'Mempool.getSnapshotFor'
     --   * total time spent in gc when calling 'Mempool.getSnapshotFor'
+  | DumpStakeDistribution EpochNo (SL.PoolDistr StandardCrypto)
 
 instance (HasAnalysis blk, LedgerSupportsProtocol blk) => Show (TraceEvent blk) where
   show (StartedEvent analysisName)        = "Started " <> (show analysisName)
@@ -271,7 +275,14 @@ instance (HasAnalysis blk, LedgerSupportsProtocol blk) => Show (TraceEvent blk)
     , "mutSnap " <> show mutSnap
     , "gcSnap " <> show gcSnap
     ]
-
+  show (DumpStakeDistribution eno pd) =
+      intercalate "\t"
+    $ (\ss -> show eno : show (SL.pdTotalActiveStake pd) : show (Map.size mp) : ss)
+    $ [ show (keyhash, SL.individualTotalPoolStake x, SL.individualPoolStake x)
+      | (keyhash, x) <- Map.assocs mp
+      ]
+    where
+      mp = SL.unPoolDistr pd
 
 {-------------------------------------------------------------------------------
   Analysis: show block and slot number and hash for all blocks
@@ -863,6 +874,40 @@ reproMempoolForge numBlks env = do
           -- this flushes blk from the mempool, since every tx in it is now on the chain
           void $ Mempool.syncWithLedger mempool
 
+{-------------------------------------------------------------------------------
+  Analysis: print out the stake distibution for each epoch
+-------------------------------------------------------------------------------}
+
+dumpStakeDistributions ::
+  forall blk.
+  ( HasAnalysis blk,
+    LedgerSupportsProtocol blk
+  ) =>
+  Analysis blk StartFromLedgerState
+dumpStakeDistributions env = do
+    void $ processAll db registry GetBlock startFrom limit (initLedger, Nothing) process
+    pure Nothing
+  where
+    AnalysisEnv {db, cfg, limit, registry, startFrom, tracer} = env
+
+    FromLedgerState initLedger = startFrom
+
+    process
+      :: (ExtLedgerState blk, Maybe EpochNo)
+      -> blk
+      -> IO (ExtLedgerState blk, Maybe EpochNo)
+    process (oldLedger, mbEpoch) blk = do
+      let lcfg      = ExtLedgerCfg cfg
+          newLedger = tickThenReapply lcfg blk oldLedger
+          lst       = ledgerState newLedger
+
+      (,) newLedger <$> case HasAnalysis.epochPoolDistr lst of
+          Just (epoch, pd)
+            | mbEpoch /= Just epoch ->
+              Just epoch <$ traceWith tracer (DumpStakeDistribution epoch pd)
+
+          _ -> pure mbEpoch
+
 {-------------------------------------------------------------------------------
   Auxiliary: processing all blocks in the DB
 -------------------------------------------------------------------------------}

ouroboros-consensus-cardano/src/unstable-cardano-tools/Cardano/Tools/DBAnalyser/Block/Byron.hs

@@ -41,6 +41,8 @@ instance HasAnalysis ByronBlock where
     -- metrics for the Byron era only.
     blockApplicationMetrics = []
 
+    epochPoolDistr _lst = Nothing
+
 instance HasProtocolInfo ByronBlock where
     data Args ByronBlock =
       ByronBlockArgs {

ouroboros-consensus-cardano/src/unstable-cardano-tools/Cardano/Tools/DBAnalyser/Block/Cardano.hs

@@ -91,6 +91,16 @@ analyseBlock f =
     p :: Proxy HasAnalysis
     p = Proxy
 
+analyseLedgerState ::
+     (forall blk. HasAnalysis blk => LedgerState blk -> a)
+  -> LedgerState (CardanoBlock StandardCrypto) -> a
+analyseLedgerState f =
+      hcollapse
+    . hcmap (Proxy @HasAnalysis) (K . f . currentState)
+    . Telescope.tip
+    . getHardForkState
+    . hardForkLedgerStatePerEra
+
 -- | Lift a function polymorphic over all block types supporting `HasAnalysis`
 -- into a corresponding function over `CardanoBlock.`
 analyseWithLedgerState ::
@@ -299,6 +309,8 @@ instance (HasAnnTip (CardanoBlock StandardCrypto), GetPrevHash (CardanoBlock Sta
         )
       ]
 
+  epochPoolDistr = analyseLedgerState epochPoolDistr
+
 dispatch ::
      LedgerState (CardanoBlock StandardCrypto)
   -> (LedgerState ByronBlock -> IO Builder)

ouroboros-consensus-cardano/src/unstable-cardano-tools/Cardano/Tools/DBAnalyser/Block/Shelley.hs

@@ -5,6 +5,7 @@
 {-# LANGUAGE ScopedTypeVariables #-}
 {-# LANGUAGE TypeApplications #-}
 {-# LANGUAGE TypeFamilies #-}
+{-# LANGUAGE TypeOperators #-}
 {-# LANGUAGE UndecidableInstances #-}
 
 {-# OPTIONS_GHC -Wno-orphans #-}
@@ -49,11 +50,13 @@ import qualified Ouroboros.Consensus.Shelley.Ledger.Block as Shelley
 import           Ouroboros.Consensus.Shelley.Node (Nonce (..),
                      ProtocolParamsShelleyBased (..), ShelleyGenesis,
                      protocolInfoShelley)
+import           Ouroboros.Consensus.Shelley.Protocol.Abstract (ProtoCrypto)
 import           Text.Builder (decimal)
 
 -- | Usable for each Shelley-based era
 instance ( ShelleyCompatible proto era
          , PerEraAnalysis era
+         , ProtoCrypto proto ~ StandardCrypto
          ) => HasAnalysis (ShelleyBlock proto era) where
 
   countTxOutputs blk = case Shelley.shelleyBlockRaw blk of
@@ -103,6 +106,13 @@ instance ( ShelleyCompatible proto era
     -- metrics for Shelley-only eras.
   blockApplicationMetrics = []
 
+  epochPoolDistr lst =
+      Just (SL.nesEL nes, SL.nesPd nes)
+    where
+      nes = shelleyLedgerState lst
+
+-----
+
 class PerEraAnalysis era where
     txExUnitsSteps :: Maybe (Core.Tx era -> Word64)
 

ouroboros-consensus-cardano/src/unstable-cardano-tools/Cardano/Tools/DBAnalyser/HasAnalysis.hs

@@ -8,6 +8,8 @@ module Cardano.Tools.DBAnalyser.HasAnalysis (
   , WithLedgerState (..)
   ) where
 
+import           Cardano.Ledger.Crypto (StandardCrypto)
+import           Cardano.Ledger.Shelley.API (PoolDistr)
 import           Data.Map.Strict (Map)
 import           Ouroboros.Consensus.Block
 import           Ouroboros.Consensus.HeaderValidation (HasAnnTip (..))
@@ -58,6 +60,16 @@ class (HasAnnTip blk, GetPrevHash blk, Condense (HeaderHash blk)) => HasAnalysis
   -- the IO monad.
   blockApplicationMetrics :: [(Builder, WithLedgerState blk -> IO Builder)]
 
+  -- | The epoch number of the block's slot, and the stake distribution used
+  -- for the leader schedule of that epoch
+  --
+  -- This pool distribution should match 'protocolLedgerView', for example.
+  --
+  -- It should return 'Nothing' if and only if the block is in the Byron era.
+  epochPoolDistr ::
+       LedgerState blk
+    -> Maybe (EpochNo, PoolDistr StandardCrypto)
+
 class HasProtocolInfo blk where
   data Args blk
   mkProtocolInfo :: Args blk -> IO (ProtocolInfo blk)

ouroboros-consensus-cardano/src/unstable-cardano-tools/Cardano/Tools/DBAnalyser/Types.hs

@@ -38,6 +38,7 @@ data AnalysisName =
     -- The metrics will be written to the provided file path, or to
     -- the standard output if no file path is specified.
   | GetBlockApplicationMetrics NumberOfBlocks (Maybe FilePath)
+  | DumpStakeDistributions
   deriving Show
 
 data AnalysisResult =