From 320cd150b6f0c6225ea3b04cc1e5736a46ed8300 Mon Sep 17 00:00:00 2001
From: Marco Cipriani <marco.cipriani.01@gmail.com>
Date: Sun, 5 Sep 2021 11:43:42 +0200
Subject: [PATCH] Gradle 7.1 and Kotlin KTS

---
 build.gradle                             | 88 ------------------------
 build.gradle.kts                         | 81 ++++++++++++++++++++++
 gradle/wrapper/gradle-wrapper.properties |  2 +-
 settings.gradle                          |  1 -
 settings.gradle.kts                      |  1 +
 5 files changed, 83 insertions(+), 90 deletions(-)
 delete mode 100644 build.gradle
 create mode 100644 build.gradle.kts
 delete mode 100644 settings.gradle
 create mode 100644 settings.gradle.kts

diff --git a/build.gradle b/build.gradle
deleted file mode 100644
index d1c8009..0000000
--- a/build.gradle
+++ /dev/null
@@ -1,88 +0,0 @@
-apply plugin: 'java-library'
-apply plugin: 'idea'
-apply plugin: 'maven'
-
-repositories {
-    mavenCentral()
-    maven { url 'https://jitpack.io' }
-}
-
-test {
-    useJUnitPlatform()
-}
-
-sourceCompatibility = 1.8
-targetCompatibility = 1.8
-
-group 'org.indilib.i4j'
-description = 'INDIForJava-driver'
-version '2.0.2'
-
-dependencies {
-    api 'com.github.INDIForJava:INDIForJava-core:2.0.1'
-}
-
-jar {
-    archivesBaseName = project.name
-    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
-    manifest {
-        from 'META-INF/MANIFEST.MF'
-    }
-}
-
-task sourcesJar(type: Jar, dependsOn: classes) {
-    from sourceSets.main.allSource
-    classifier "sources"
-    extension "jar"
-}
-
-task javadocJar(type: Jar) {
-    classifier "javadoc"
-    from javadoc
-}
-
-task fatJar(type: Jar, dependsOn: classes) {
-    from sourceSets.main.allSource
-    classifier "sources"
-    extension "jar"
-    destinationDirectory = file("build/")
-    from {
-        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
-    }
-}
-
-artifacts {
-    archives javadocJar, sourcesJar
-}
-
-configure(install.repositories.mavenInstaller) {
-    pom.project {
-        inceptionYear = '2012'
-        name = project.name
-        packaging = 'jar'
-        description = project.description
-
-        url = 'https://github.com/INDIForJava/INDIForJava-driver'
-
-        scm {
-            connection = 'git@github.com:INDIForJava/INDIForJava-driver.git'
-            developerConnection = 'git@github.com:INDIForJava/INDIForJava-driver.git'
-            url = 'https://github.com/INDIForJava/INDIForJava-driver'
-        }
-
-        licenses {
-            license {
-                name = 'GNU Lesser General Public License'
-                url = 'https://www.gnu.org/licenses/lgpl-3.0.txt'
-            }
-        }
-
-        developers {
-            developer {
-                id = 'marcocipriani01'
-                name = 'Marco Cipriani'
-                email = 'marco.cipriani.01@gmail.com'
-            }
-        }
-    }
-}
\ No newline at end of file
diff --git a/build.gradle.kts b/build.gradle.kts
new file mode 100644
index 0000000..ba0169c
--- /dev/null
+++ b/build.gradle.kts
@@ -0,0 +1,81 @@
+plugins {
+    id("java-library")
+    id("maven-publish")
+    id("idea")
+}
+
+group = "org.indilib.i4j"
+description = "INDIForJava-driver"
+version = "2.0.2"
+
+repositories {
+    mavenCentral()
+    maven {
+        url = uri("https://jitpack.io")
+    }
+}
+
+java {
+    sourceCompatibility = JavaVersion.VERSION_1_8
+    targetCompatibility = JavaVersion.VERSION_1_8
+}
+
+dependencies {
+    api("com.github.INDIForJava:INDIForJava-core:2.0.2")
+}
+
+tasks.jar {
+    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
+    manifest {
+        from("META-INF/MANIFEST.MF")
+    }
+}
+
+tasks {
+    val sourcesJar by creating(Jar::class) {
+        archiveClassifier.set("sources")
+        from(sourceSets.main.get().allSource)
+    }
+
+    val javadocJar by creating(Jar::class) {
+        dependsOn.add(javadoc)
+        archiveClassifier.set("javadoc")
+        from(javadoc)
+    }
+
+    artifacts {
+        archives(sourcesJar)
+        archives(javadocJar)
+        archives(jar)
+    }
+}
+
+publishing {
+    publications {
+        create<MavenPublication>("mavenJava") {
+            pom {
+                name.set(project.name)
+                description.set("INDIForJava is a set of libraries to implement clients and servers that follow the INDI protocol, designed to operate astronomical instrumentation.")
+                url.set("https://github.com/INDIForJava/INDIForJava-driver")
+                licenses {
+                    license {
+                        name.set("GNU Lesser General Public License")
+                        url.set("https://www.gnu.org/licenses/lgpl-3.0.txt")
+                    }
+                }
+                developers {
+                    developer {
+                        id.set("marcocipriani01")
+                        name.set("Marco Cipriani")
+                        email.set("marco.cipriani.01@gmail.com")
+                    }
+                }
+                scm {
+                    connection.set("scm:git:git://github.com/INDIForJava/INDIForJava-driver.git")
+                    developerConnection.set("scm:git:ssh://github.com/INDIForJava/INDIForJava-driver.git")
+                    url.set("https://github.com/INDIForJava/INDIForJava-driver")
+                }
+            }
+        }
+    }
+}
\ No newline at end of file
diff --git a/gradle/wrapper/gradle-wrapper.properties b/gradle/wrapper/gradle-wrapper.properties
index da9702f..69a9715 100644
--- a/gradle/wrapper/gradle-wrapper.properties
+++ b/gradle/wrapper/gradle-wrapper.properties
@@ -1,5 +1,5 @@
 distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
-distributionUrl=https\://services.gradle.org/distributions/gradle-6.8-bin.zip
+distributionUrl=https\://services.gradle.org/distributions/gradle-7.1-bin.zip
 zipStoreBase=GRADLE_USER_HOME
 zipStorePath=wrapper/dists
diff --git a/settings.gradle b/settings.gradle
deleted file mode 100644
index 134e34d..0000000
--- a/settings.gradle
+++ /dev/null
@@ -1 +0,0 @@
-rootProject.name = 'INDIForJava-driver'
diff --git a/settings.gradle.kts b/settings.gradle.kts
new file mode 100644
index 0000000..d7a9892
--- /dev/null
+++ b/settings.gradle.kts
@@ -0,0 +1 @@
+rootProject.name = "INDIForJava-driver"