build.gradle

plugins {
  id 'org.springframework.boot' version '2.3.0.M4'
  id 'io.spring.dependency-management' version '1.0.9.RELEASE'
  id 'java'

  // expand variables defined in dotenv
  id "co.uzzu.dotenv.gradle" version "1.1.0"

  id "com.diffplug.gradle.spotless" version "3.30.0"
  id 'jacoco'

  id "org.sonarqube" version "2.8"
}

group = 'tech.gruppone.stalker'
version = '1.0.0'
sourceCompatibility = '11'

configurations {
  developmentOnly

  runtimeClasspath {
    extendsFrom developmentOnly
  }

  compileOnly {
    extendsFrom annotationProcessor
  }
}

repositories {
  mavenCentral()
  maven { url 'https://repo.spring.io/milestone' }
}

dependencies {
//  Supports built in (or custom) endpoints that let you monitor and manage your application - such as application health, metrics, sessions, etc.
  implementation 'org.springframework.boot:spring-boot-starter-actuator'

//  Provides Reactive Relational Database Connectivity to persist data in SQL stores using Spring Data in reactive applications.
  implementation 'org.springframework.boot:spring-boot-starter-data-r2dbc'

//  Send email using Java Mail and Spring Framework's JavaMailSender.
  implementation 'org.springframework.boot:spring-boot-starter-mail'

//  Build reactive web applications with Spring WebFlux and Netty.
  implementation 'org.springframework.boot:spring-boot-starter-webflux'

//  Highly customizable authentication and access-control framework for Spring applications.
  // implementation 'org.springframework.boot:spring-boot-starter-security'

//  Java annotation library which helps to reduce boilerplate code.
  compileOnly 'org.projectlombok:lombok'

//  Provides fast application restarts, LiveReload, and configurations for enhanced development experience.
  developmentOnly 'org.springframework.boot:spring-boot-devtools'

  // MySQL JDBC and R2DBC driver.
  implementation 'dev.miku:r2dbc-mysql:0.8.1.RELEASE'

 // Provides support for JSON web Token
  implementation 'io.jsonwebtoken:jjwt-api:0.11.1'
  implementation 'io.jsonwebtoken:jjwt-jackson:0.11.1'

  runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.11.1'
  runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.11.1'

  // Generate metadata for developers to offer contextual help and "code completion" when working with custom configuration keys (ex.application.properties/.yml files).
  annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'

  annotationProcessor 'org.projectlombok:lombok'

  testImplementation('org.springframework.boot:spring-boot-starter-test') {
    exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
  }

  testImplementation 'io.projectreactor:reactor-test'
  //testImplementation 'org.springframework.security:spring-security-test'

  // ---------------------------------------------------------------------------------

  // influxdb 1.x java client
  implementation 'org.influxdb:influxdb-java:2.17'

  // ---------------------------------------------------------------------------------

  // LDAP client
  implementation 'org.apache.directory.api:api-all:2.0.1'
}


test {
  useJUnitPlatform()

  failFast = false

  finalizedBy {
    jacocoTestReport
  }
}

processResources {
  filesMatching('application.properties') {
    expand(project.properties)
  }
}

// this fails if the variables are not present
ext {
  mysqlRootPassword = "${env.MYSQL_ROOT_PASSWORD.value}"
  influxdbAdminPassword = "${env.INFLUXDB_ADMIN_PASSWORD.value}"
  jwtSecret = "${env.JWT_SECRET.value}"
  emailAccountPassword = "${env.EMAIL_ACCOUNT_PASSWORD.value}"
}

tasks.register("printCurrentSecrets") {
    doLast {
        println "MYSQL_ROOT_PASSWORD: ${env.MYSQL_ROOT_PASSWORD.value}"
        println "INFLUXDB_ADMIN_PASSWORD: ${env.INFLUXDB_ADMIN_PASSWORD.value}"
        println "JWT_SECRET: ${env.JWT_SECRET.value}"
        println "EMAIL_ACCOUNT_PASSWORD: ${env.EMAIL_ACCOUNT_PASSWORD.value}"
    }
}

// ===============================
// = FORMATTING
// ===============================

spotless {
  // already enforced with a different method
  enforceCheck false

  java {
    target '**/*.java'

    googleJavaFormat("1.7")

    endWithNewline()
    removeUnusedImports()
    trimTrailingWhitespace()
  }

  encoding 'UTF-8'
  lineEndings("UNIX")
}


// ===============================
// = LINTERS
// ===============================

tasks.withType(JavaCompile) {
  options.encoding = 'UTF-8'
  options.compilerArgs = [
    '-Xlint:all',
    '-Xlint:-processing',
    '-Werror'
  ]
}

// TODO add checkstyle plugin configuration

// ===============================
// = TESTING AND COVERAGE
// ===============================

jacocoTestReport {
  reports {
    xml.enabled true
    csv.enabled false
    html.enabled true
  }

  dependsOn {
    test
  }
}

jacocoTestCoverageVerification {
  violationRules {
    rule {
      limit {
        minimum = 0.8
      }
    }
  }

  dependsOn {
    jacocoTestReport
  }
}

// check {
//   dependsOn {
//     jacocoTestCoverageVerification
//   }
// }

// ===============================
// = SONARCLOUD
// ===============================

sonarqube {
  properties {
    property "sonar.sourceEncoding", "UTF-8"

    property "sonar.projectName", "stalker-server"
    property "sonar.projectKey", "GruppOne_stalker-server"
    property "sonar.organization", "grupp-one"

    property "sonar.host.url", "https://sonarcloud.io"
    property "sonar.login", "${env.SONARCLOUD_LOGIN.orNull()}"

    property 'sonar.coverage.jacoco.xmlReportPaths', "${buildDir}/reports/jacoco/test/jacocoTestReport.xml"
  }
}

tasks.findByName('sonarqube').mustRunAfter('check')
tasks.findByName('test').mustRunAfter('spotlessApply')