zshrc

. ~/.zprofile
. ~/.scripts/zsh-jump

# Plugins
if which brew &>/dev/null && which z &>/dev/null; then
    . `brew --prefix`/etc/profile.d/z.sh
fi

# ZSH Move
autoload -Uz zmv

# Completion
autoload -Uz compinit
zstyle ':completion:*' completer _complete _ignored
zstyle :compinstall filename "$HOME/.zshrc"
compinit

# VCS
autoload -Uz vcs_info
zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat '%b%F{1}:%F{3}%r'
zstyle ':vcs_info:*' actionformats '.%F{2}%b%F{3}.%F{1}%a%f'
zstyle ':vcs_info:*' formats '.%F{2}%b%%f'
zstyle ':vcs_info:*' enable git svn hg

# Auto Mime Type Running
autoload -Uz zsh-mime-setup
autoload -Uz pick-web-browser
zstyle ':mime:*' mailcap ~/.mailcap
# Example: to make it not background an app
# zstyle ':mime:.txt:' flags needsterminal
zsh-mime-setup
alias -s html=pick-web-browser

# Colors
autoload -Uz colors
autoload -Uz zsh/terminfo
if [[ "$terminfo[colors]" -ge 8 ]]; then
    colors
fi
for color in RED GREEN YELLOW BLUE MAGENTA CYAN WHITE; do
    eval PR_$color='%{$terminfo[bold]$fg[${(L)color}]%}'
    eval PR_LIGHT_$color='%{$fg[${(L)color}]%}'
    (( count = $count + 1 ))
done
PR_NO_COLOUR="%{$terminfo[sgr0]%}"

### ZSH options
# pushd options
setopt auto_pushd           # pushes visited dirs on a stack to popd
setopt pushd_silent         # pushd silently
setopt pushd_to_home        # "pushd" w/o args takes you home
# completion options
setopt auto_list            # outputs completion opts immediately on ambig
setopt list_types           # shows types of possible completion opts
setopt complete_in_word     # complete while in mid of word, and don't move cursor
setopt extended_glob        # extra zsh glob features
# history options
setopt share_history        # all zsh sessions merge history
setopt hist_ignore_dups     # don't put duplicates in history
setopt hist_reduce_blanks   # remove extra spaces hist commands
# input/output options
setopt aliases              # expand aliases
setopt clobber              # allow > and >> to clobber/create files
setopt interactive_comments # allow comments in interactive shell
# job control options
setopt no_hup               # don't kill bg jobs as terminal ends
unsetopt notify             # output status of bg'd jobs just before prompt
# prompt options
setopt prompt_subst         # allow param expansion, command subst, arith in prompt
# misc
unsetopt beep               # never beep please
setopt auto_cd              # you can cd by just typing a folder name
setopt vi                   # vim mode

#Aliases
alias -g ugster="aapachin@ugster05.student.cs.uwaterloo.ca"
alias -g uwask="aapachin@acesulfame-potassium.csclub.uwaterloo.ca"
alias -g uwcsc="aapachin@csclub.uwaterloo.ca"
alias -g uw="aapachin@linux028.student.cs.uwaterloo.ca"
alias    althack='telnet nethack.alt.org'
alias    caocrawl='ssh joshua@crawl.akrasiac.org'
alias    date='date +"~ %I:%M %p on %A, the %eth of %B ~"'
alias    ftp="gftp-text"
alias    music="ncmpcpp"
alias    pwmd="pwd" # I typo this 90% of the time
alias    top="htop"
alias    tram="transmission-remote"
alias    tree='tree -AC'
alias    vim='nvim'
alias    govim='GOPATH=$PWD vim'
alias    open=xdg-open

# Variables
HISTFILE=~/.histfile
HISTSIZE=1000
SAVEHIST=1000
export PROMPT='$PR_GREEN%m$PR_WHITE.$PR_BLUE%n$PR_WHITE $PR_MAGENTA%c\
$PR_WHITE${vcs_info_msg_0_}: '
preexec () { echo -ne "\e[0m" } # removes colour after the prompt input

# ZSH HOOKS
# Needed for revision control identification
precmd_vcs() {
        vcs_info
}
# Add your function to these lists to register a hook
precmd_functions+=("precmd_vcs")
chpwd_functions+=()
zshexit_functions+=()

# Modified cd/ls functions
TODO_OPTIONS="--summary"

ls()
{
        /bin/ls --color -G "$@"
}

# For old find compat, automatically add searchdir of '.' if none supplied
find()
{
    if [[ ! -d "$1" && "$1" == -* ]]; then
        /usr/bin/find . $@
    else
        /usr/bin/find $@
    fi
}

up()
{
    local cdstr=""
    for x in $(seq $1); do
        cdstr+="../"
    done
    builtin cd ${cdstr}
}

# Execute these as a terminal opens
date

# Nugbase-web style source
if [ -f './scripts/source-me.sh' ]; then
    source './scripts/source-me.sh' &> /dev/null
    echo '~ loaded ./scripts/source-me.sh ~'
fi

# Secrets: OpenAI / ChatGPT if available
if [ -f ~/.secret/openai.sh ]; then
    source ~/.secret/openai.sh
    echo '~ loaded secrets ~'
fi

if ! type "ag" > /dev/null; then
    echo '-> ag not installed'
fi
# Generated by fzf.git/install script
[ -f ~/.fzf.zsh ] && source ~/.fzf.zsh
if ! type "fzf" > /dev/null; then
    echo '-> fzf not installed'
    echo 'recommend: git clone --depth 1 https://github.com/junegunn/fzf.git ~/.fzf && ~/.fzf/install'
fi

# The next line updates PATH for the Google Cloud SDK.
if [ -f '/Users/lung/Programs/google-cloud-sdk/path.zsh.inc' ]; then . '/Users/lung/Programs/google-cloud-sdk/path.zsh.inc'; fi

# The next line enables shell command completion for gcloud.
if [ -f '/Users/lung/Programs/google-cloud-sdk/completion.zsh.inc' ]; then . '/Users/lung/Programs/google-cloud-sdk/completion.zsh.inc'; fi