build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            url 'https://plugins.gradle.org/m2/'
        }
    }
    dependencies {
        classpath 'org.springframework.boot:spring-boot-gradle-plugin:2.1.3.RELEASE'
        classpath 'org.liquibase:liquibase-gradle-plugin:1.2.4'
        classpath 'mysql:mysql-connector-java:5.1.45'
        classpath 'gradle.plugin.com.palantir.gradle.docker:gradle-docker:0.13.0'
    }
}

group 'enterprise_webapp'
version '3.0-SNAPSHOT'

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'org.springframework.boot'
apply plugin: 'io.spring.dependency-management'
apply plugin: 'org.liquibase.gradle'

sourceCompatibility = JavaVersion.VERSION_11
targetCompatibility = JavaVersion.VERSION_11

repositories {
    mavenCentral()
}

dependencies {
    compile("org.springframework.boot:spring-boot-starter-web")
    compile("org.springframework.boot:spring-boot-starter-jdbc")
    compile("org.springframework.boot:spring-boot-starter-data-jpa")
    compile("mysql:mysql-connector-java:5.1.45")
    compile('org.hibernate:hibernate-entitymanager:5.2.2.Final') {
        force = true
    }
    compile("com.google.code.gson:gson:2.8.2")
    compile("org.springframework.boot:spring-boot-starter-activemq")
    compile("org.springframework.boot:spring-boot-actuator")

    testCompile("junit:junit:4.12")
    testCompile("org.springframework.boot:spring-boot-starter-test")
    testCompile('com.h2database:h2:1.4.197')
}

springBoot {
    buildInfo()
}

liquibase {
    Properties props = new Properties()
    props.load(new FileInputStream(file("$projectDir/src/main/resources/db_connections.properties")))

    activities {
        main {
            classpath "$projectDir/rdbms_flow"
            changeLogFile props['liquibase.changelogfile']
            url props['datasource.url']
            username props['datasource.username']
            password props['datasource.password']
        }
        runList = 'main'
    }
}

apply plugin: 'com.palantir.docker'

docker {
    name "${project.group}/${bootJar.baseName}"
    copySpec.from("build/libs").into("/")
    buildArgs(['JAR_FILE': "remote_banking-3.0-SNAPSHOT.jar"])
}