gmxManageOneMath.cmake

#
# This file is part of the GROMACS molecular simulation package.
#
# Copyright 2024- The GROMACS Authors
# and the project initiators Erik Lindahl, Berk Hess and David van der Spoel.
# Consult the AUTHORS/COPYING files and https://www.gromacs.org for details.
#
# GROMACS is free software; you can redistribute it and/or
# modify it under the terms of the GNU Lesser General Public License
# as published by the Free Software Foundation; either version 2.1
# of the License, or (at your option) any later version.
#
# GROMACS is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# Lesser General Public License for more details.
#
# You should have received a copy of the GNU Lesser General Public
# License along with GROMACS; if not, see
# https://www.gnu.org/licenses, or write to the Free Software Foundation,
# Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
#
# If you want to redistribute modifications to GROMACS, please
# consider that scientific software is very special. Version
# control is crucial - bugs must be traceable. We will be happy to
# consider code for inclusion in the official distribution, but
# derived work must not be called official GROMACS. Details are found
# in the README & COPYING files - if they are missing, get the
# official version at https://www.gromacs.org.
#
# To help us fund GROMACS development, we humbly ask that you cite
# the research papers on the package. Check out https://www.gromacs.org.
# 
# Copyright 2024- Codeplay Software Ltd.

# Manage OneMath, GPU FFT library used with SYCL.

function(gmx_manage_onemath)
    # Find quietly the second time.
    if (oneMath_FIND_QUIETLY_AFTER_FIRST_RUN)
        set(oneMath_FIND_QUIETLY TRUE)
    endif()
    find_package(oneMath REQUIRED 0.6)
    set(oneMath_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find oneMath")

    set(BACKEND_COUNT 0)
    if(GMX_DPCPP_HAVE_CUDA_TARGET)
        if(NOT TARGET ONEMATH::onemath_dft_cufft)
            message(WARNING "GROMACS SYCL is targetting NVIDIA GPU, but oneMath interface library was not built with the cuFFT backend.")
        else()
            math(EXPR BACKEND_COUNT "${BACKEND_COUNT}+1")
        endif()
    endif()
    if(GMX_DPCPP_HAVE_HIP_TARGET)
        if(NOT TARGET ONEMATH::onemath_dft_rocfft)
            message(WARNING "GROMACS SYCL is targetting AMD GPU, but oneMath interface library was not built with the rocFFT backend.")
        else()
            math(EXPR BACKEND_COUNT "${BACKEND_COUNT}+1")
        endif()
    endif()
    if(GMX_DPCPP_HAVE_INTEL_TARGET)
        if(NOT TARGET ONEMATH::onemath_dft_mklgpu)
            message(WARNING "GROMACS SYCL is targetting Intel GPU, but oneMath interface library was not built with the MKLGPU backend.")
        else()
            math(EXPR BACKEND_COUNT "${BACKEND_COUNT}+1")
        endif()
    endif()

    if(${BACKEND_COUNT} EQUAL 0)
        message(FATAL_ERROR "oneMath interface library was not compatible with -fsycl-targets")
    endif()

    if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "2024.2" AND CMAKE_CXX_COMPILER_ID MATCHES "IntelLLVM")
        message(WARNING "DPC++ version ${CMAKE_CXX_COMPILER_VERSION} < 2024.2 may cause segfault at end of GROMACS run")
    endif()
endfunction()