Mask / Fill Value in Immersed BC Set to NaN in Output?

[darosaj]

Hi,

Thanks so much for creating this amazing tool/package!

I'm wondering if there is a way to pass in the desired FillValue / Masked Value for the cells that are under the Immersed Boundary Grid?

Specifically, I'm looking to see if I can set the FillValue to be NaN for easier processing and visualization after the simulation?

Additionally, a general Immersed Boundary question:

When applying the Immersed BC such as this:

u_bcs = FieldBoundaryConditions( immersed=ValueBoundaryCondition(0))

Does this immersed BC apply to the bottom of the grid, even where the specified fitted bottom is already at the domain boundary?
Ie: The seamount example.

Or would I have to specify both the immersed=ValueBoundaryCondition(0), and bottom=ValueBoundaryCondition(0) to get a no slip boundary over the entire bottom of the domain.

Thank you!

[glwagner]

Hmm, I was going to say yes, the immersed boundary condition applies to the bottom because

Oceananigans.jl/src/ImmersedBoundaries/partial_cell_bottom.jl

Line 85 in 90086fd

@inbounds bottom_field[i, j, 1] = clamp(zb, domain_bottom, domain_top)

but then I noticed that this may not be the case for GridFittedBottom. So I will do a test, stand by. We may need to fix that.

As for the fill value, this is the subject of PR #3092 but it has not seen movement in a while. I agree, it would be nice to fill with something like NaNs before outputting.

It is possible to call mask_immersed_field(f, NaN) in post-processing, however (if you are wise enough to use Julia also for post-processing 😇 😄 )

[glwagner]

This script:

using Oceananigans
using Oceananigans.Units

grid = RectilinearGrid(size=(128, 128), halo=(4, 4),
                       x=(-64, 64), z=(0, 128),
                       topology=(Periodic, Flat, Bounded))

mountain(x) = -1 + 4 * exp(-x^2 / 32)
grid = ImmersedBoundaryGrid(grid, GridFittedBottom(mountain))
#grid = ImmersedBoundaryGrid(grid, PartialCellBottom(mountain))

flux_bc = FluxBoundaryCondition(1e-7)
b_bcs = FieldBoundaryConditions(immersed=flux_bc)

model = NonhydrostaticModel(; grid, tracers=:b, buoyancy=BuoyancyTracer(),
                            advection = WENO(), boundary_conditions = (; b=b_bcs))

ϵ(x, z) = 1e-3 * randn()
set!(model, u=ϵ, v=ϵ)

simulation = Simulation(model, Δt=10, stop_time=1hours)
conjure_time_step_wizard!(simulation, cfl=0.5)
progress(sim) = @info string(iteration(sim), ", time: ", prettytime(sim))
add_callback!(simulation, progress, IterationInterval(10))
run!(simulation)

using GLMakie
b = model.tracers.b
heatmap(b)
current_figure()

produces

grid = ImmersedBoundaryGrid(grid, PartialCellBottom(mountain)) looks identical.

But using b_bcs = FieldBoundaryConditions(immersed=flux_bc, bottom=flux_bc) produces

so... I was wrong actually, and the answer is that the immersed flux only applies on immersed boundaries and not the bottom.

[glwagner]

Note, be careful about signs. Immersed fluxes point inwards. But boundary fluxes point in the "positive-direction". So while a positive flux is heating on the bottom, it's cooling on the top. Well, it's not hard to demonstrate this, just use

b_bcs = FieldBoundaryConditions(immersed=flux_bc, bottom=flux_bc, top=flux_bc) to get

The inconsistency in flux sign convention does disturb me a little bit but we haven't had the courage to break literally everyone's scripts.

[glwagner]

This is cool

grid = RectilinearGrid(size=(128, 128), halo=(4, 4),
                       x=(-64, 64), z=(-64, 64),
                       topology=(Periodic, Flat, Bounded))

circle(x, z) = (x^2 + z^2) < 16^2
grid = ImmersedBoundaryGrid(grid, GridFittedBoundary(circle))

or using

flux_func(x, z, t) = ifelse(z > 0, 1e-7, -1e-7)
flux_bc = FluxBoundaryCondition(flux_func)

[glwagner]

just having fun

flux_func(x, z, t) = ifelse(z > 0, -1e-7, 1e-7)

[darosaj]

That is really cool!

[darosaj]

Thank you!

That is great to know (both on the immersed boundary question and the NaN question as well).

I'll make sure to add whatever Boundary Condition on the immersed, also on the bottom. (and I'll be wary of the sign convention as well)

I will definitely try that mask_immersed in post processing in Julia as well. (I'm new to Julia so I'm still learning and have been doing some of my post processing in python)

[glwagner]

I mean, that's totally fair. It'd be nice to have a immersed_value kwarg for the output writers.