build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '2.7.10'
    id 'io.spring.dependency-management' version '1.1.6'
    id "org.asciidoctor.jvm.convert" version "3.3.2"
    id 'com.epages.restdocs-api-spec' version '0.16.2'
    id 'org.hidetake.swagger.generator' version '2.19.2'
    id 'jacoco'
    id 'org.ec4j.editorconfig' version '0.0.3'
    id 'checkstyle'
    id 'org.jetbrains.kotlin.jvm' version '1.8.0'
    id 'org.jlleitschuh.gradle.ktlint' version '12.1.0'
    id 'org.jetbrains.kotlin.kapt' version '1.8.0'
    id 'org.jetbrains.kotlin.plugin.lombok' version '1.8.0'
}


jacoco {
    toolVersion = "0.8.10"
}

subprojects {

    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'org.springframework.boot'

    apply plugin: 'org.asciidoctor.jvm.convert'
    apply plugin: 'jacoco'
    apply plugin: 'org.ec4j.editorconfig'

    /**
     * 코틀린
     */
    apply plugin: 'kotlin'
    apply plugin: 'org.jetbrains.kotlin.jvm'
    /**
     * 코틀린에서 Java의 롬복 사용
     * (코틀린 클래스의 적용이 아닌 롬복이 적용된 Java 클래스를 사용하기 위함)
     */
    apply plugin: 'org.jetbrains.kotlin.kapt'
    apply plugin: 'org.jetbrains.kotlin.plugin.lombok'
    /**
     * 코드 컨벤션
     */
    apply plugin: 'org.jlleitschuh.gradle.ktlint'
    apply plugin: 'checkstyle'


    repositories {
        mavenCentral()
    }
    kapt {
        keepJavacAnnotationProcessors = true
        showProcessorStats = true
    }

    dependencies {
        implementation 'org.springframework.boot:spring-boot-starter-web'

        implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
        implementation 'io.github.microutils:kotlin-logging:3.0.5'

        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'
        testImplementation 'org.springframework.boot:spring-boot-starter-test'
        testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

        testImplementation 'org.springframework.restdocs:spring-restdocs-mockmvc'
        testImplementation 'com.epages:restdocs-api-spec-mockmvc:0.16.2'
        implementation 'org.springframework.cloud:spring-cloud-starter-aws:2.2.6.RELEASE'
        runtimeOnly 'com.h2database:h2'
        runtimeOnly 'com.mysql:mysql-connector-j'
        testImplementation 'io.findify:s3mock_2.13:0.2.6'


        // 캐싱 관련
        implementation 'org.springframework.boot:spring-boot-starter-cache'
        implementation 'com.github.ben-manes.caffeine:caffeine'

        // @mwiede의 포크 버전 jsch 추가 - ssh 터널링을 통한 DB 접속
        implementation 'com.github.mwiede:jsch:0.2.21'


        /**
         * 시큐리티 관련
         */
        /*
            로그인 관련
             */
        implementation 'org.springframework.boot:spring-boot-starter-security'
        // Cognito
        implementation 'software.amazon.awssdk:cognitoidentityprovider:2.20.66'
        implementation 'org.springframework.boot:spring-boot-starter-oauth2-client'
        implementation 'org.springframework.security:spring-security-oauth2-jose'
        implementation 'org.thymeleaf.extras:thymeleaf-extras-springsecurity5'

        /**
         * jpa
         **/
        implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    }

    println("root Directory : ${rootDir}")
    checkstyle {
        maxWarnings = 0
        configFile = file("${rootDir}/config/naver-checkstyle-rules.xml")
        configProperties = ["suppressionFile": "${rootDir}/config/naver-checkstyle-suppressions.xml"]
        toolVersion = "8.42"
    }
    tasks.named('test') {
        useJUnitPlatform()
    }

    jacocoTestReport {
        dependsOn test
        reports {
            html.required = true
            xml.required = true
        }
    }

    jacocoTestCoverageVerification {
        violationRules {
            rule {
                enabled = true
                element = 'CLASS'
                limit {
                    counter = 'LINE'
                    value = 'COVEREDRATIO'
                }
                excludes = [
                        "com.server.computer_science.**.**",
                        "**.*Application*",
                        "**.*Config*",
                        "**/domain",
                        "**/*Interceptor*",
                        "**/*Exception*"
                ]
            }
        }
    }
    group = 'com.study.computer-science'
    version = '0.0.1-SNAPSHOT'
    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(11)
        }
    }
    kotlin {
        jvmToolchain {
            languageVersion = JavaLanguageVersion.of(11)
        }
    }
}


bootJar.enabled = false
jar.enabled = false