-
Notifications
You must be signed in to change notification settings - Fork 10
/
Copy pathtiresias.asm
201 lines (178 loc) · 2.84 KB
/
tiresias.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
;
; tiresias
; x86 is turing-complete without data fetches
; domas, @xoreaxeaxeax
;
USE32
global _start
section .text
%macro simcall 1
mov esi, %%retsim
jmp %1
%%retsim:
%endmacro
%macro simfetch 2
mov edi, %2
shl edi, 3
add edi, %1
mov esi, %%retsim
jmp edi
%%retsim:
%endmacro
%macro simwrite 2
mov edi, %2
shl edi, 3
add edi, %1+1
mov [edi], eax
%%retsim:
%endmacro
_start:
mov ebp, 0
.read_program:
simcall read_byte
simwrite program, ebp
inc ebp
cmp al, '#'
jnz .read_program
.execute:
simcall fetch_ip
simfetch program, eax
cmp al, 0
je .exit
cmp al, '>'
je .increment_dp
cmp al, '<'
je .decrement_dp
cmp al, '+'
je .increment_data
cmp al, '-'
je .decrement_data
cmp al, '.'
je .output
cmp al, ','
je .input
cmp al, '['
je .forward
cmp al, ']'
je .backward
jmp .done
.increment_dp:
simcall fetch_dp
inc eax
mov [dp], eax
jmp .done
.decrement_dp:
simcall fetch_dp
dec eax
mov [dp], eax
jmp .done
.increment_data:
simcall fetch_dp
mov edx, eax
simfetch data, edx
inc eax
simwrite data, edx
jmp .done
.decrement_data:
simcall fetch_dp
mov edx, eax
simfetch data, edx
dec eax
simwrite data, edx
jmp .done
.output:
simcall fetch_dp
simfetch data, eax
simcall write_byte
jmp .done
.input:
simcall read_byte
mov edx, eax
simcall fetch_dp
mov ecx, eax
mov eax, edx
simwrite data, ecx
jmp .done
.forward:
simcall fetch_dp
simfetch data, eax
cmp al, 0
jne .done
mov ecx, 1
.forward.seek:
simcall fetch_ip
inc eax
mov [ip], eax
simfetch program, eax
cmp al, ']'
je .forward.seek.dec
cmp al, '['
je .forward.seek.inc
jmp .forward.seek
.forward.seek.inc:
inc ecx
jmp .forward.seek
.forward.seek.dec:
dec ecx
cmp ecx, 0
je .done
jmp .forward.seek
.backward:
simcall fetch_dp
simfetch data, eax
cmp al, 0
je .done
mov ecx, 1
.backward.seek:
simcall fetch_ip
dec eax
mov [ip], eax
simfetch program, eax
cmp al, '['
je .backward.seek.dec
cmp al, ']'
je .backward.seek.inc
jmp .backward.seek
.backward.seek.inc:
inc ecx
jmp .backward.seek
.backward.seek.dec:
dec ecx
cmp ecx, 0
je .done
jmp .backward.seek
.done:
simcall fetch_ip
inc eax
mov [ip], eax
jmp .execute
.exit:
mov eax, 1
mov ebx, 0
int 0x80
section .data
read_byte:
mov ebx, 0
mov ecx, io
mov edx, 1
mov eax, 3
int 0x80
db 0xb8
io: dd 0
jmp esi
write_byte:
mov ebx, 1
mov [io], eax
mov ecx, io
mov edx, 1
mov eax, 4
int 0x80
jmp esi
fetch_ip: db 0xb8 ; mov eax, xxxxxxxx
ip: dd 0
jmp esi
fetch_dp: db 0xb8 ; mov eax, xxxxxxxx
dp: dd 0
jmp esi
data: times 30000 db 0xb8, 0, 0, 0, 0, 0xff, 0xe6, 0x90 ; mov eax, xxxxxxxx, jmp esi, nop
program: times 30000 db 0xb8, 0, 0, 0, 0, 0xff, 0xe6, 0x90 ; mov eax, xxxxxxxx, jmp esi, nop