build.gradle

plugins {
    id 'org.springframework.boot' version '2.6.6'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    id 'java'
    id 'idea'
    id 'jacoco'
    id 'io.freefair.lombok' version '6.4.1'
}

repositories {
    mavenCentral()
    maven {
        url "https://github.com/stil4m/maven-repository/raw/master/releases/"
    }
}

java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

dependencies {
    // Some dependency versions are managed by Spring Boot, refer to
    // https://docs.spring.io/spring-boot/docs/current/reference/html/appendix-dependency-versions.html
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-mail'
    implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
    implementation 'org.springframework.boot:spring-boot-starter-logging'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-json'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-aop'

    // DONT UPGRADE TO 8+, NO SUPPORT FOR POSTGRES 9.6
    implementation 'org.flywaydb:flyway-core:7.15.0'
    implementation 'com.google.guava:guava:31.1-jre'
    implementation 'nl.stil4m:mollie-api:2.7.0'
    implementation 'net.logstash.logback:logstash-logback-encoder:7.0.1'

    runtimeOnly 'org.hsqldb:hsqldb'
    runtimeOnly 'org.postgresql:postgresql'

    testImplementation 'org.springframework.boot:spring-boot-starter-test'

    // rest-assured 4.3+ ships with Groovy 3.0, which doesn't play nice with Gradle (yet)
    testImplementation 'io.rest-assured:rest-assured:4.5.1'
    testImplementation 'io.rest-assured:json-path:4.5.1'
    testImplementation 'io.rest-assured:xml-path:4.5.1'

    developmentOnly 'org.springframework.boot:spring-boot-devtools'
}

jacocoTestReport {
    reports {
        xml.required = true
        html.required = false
    }
}

test {
    useJUnitPlatform()
}

check.dependsOn jacocoTestReport