build.gradle

description = 'Public App Remote SDK demo app'
/*
 * Copyright (c) 2015-2018 Spotify AB
 *
 * Licensed to the Apache Software Foundation (ASF) under one
 * or more contributor license agreements.  See the NOTICE file
 * distributed with this work for additional information
 * regarding copyright ownership.  The ASF licenses this file
 * to you under the Apache License, Version 2.0 (the
 * "License"); you may not use this file except in compliance
 * with the License.  You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */

apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'

android {

    buildToolsVersion androidBuildTools
    compileSdkVersion androidCompileSdk.toString().toInteger()

    signingConfigs {
        debug {
            storeFile file('keystore/example.keystore')
            storePassword 'example'
            keyAlias 'example_alias'
            keyPassword 'example'
        }
    }

    sourceSets {
        main.java.srcDirs += 'src/main/kotlin'
    }

    defaultConfig {
        applicationId 'com.spotify.android.appremote.demo'

        minSdkVersion androidMinSdk.toString().toInteger()
        targetSdkVersion androidTargetSdk.toString().toInteger()

        versionName appRemoteSampleVersionName
        versionCode appRemoteSampleVersionCode.toString().toInteger()
    }

    buildFeatures {
        viewBinding true
    }

    buildTypes {
        debug {
            debuggable true
            signingConfig signingConfigs.debug
        }
        release {
            minifyEnabled true
            shrinkResources true
            proguardFiles getDefaultProguardFile(
                    'proguard-android-optimize.txt'),
                    'proguard-rules.pro'
        }
    }
    flavorDimensions "sampleLanguage"
    productFlavors {
        ktSample {
            dimension "sampleLanguage"
        }

        javaSample {
            dimension "sampleLanguage"
        }
    }

    lintOptions {
        disable = ['LintError', 'IllegalInvocation']
    }

    packagingOptions {
        pickFirst 'META-INF/LICENSE'
        pickFirst 'META-INF/NOTICE'
    }
}

repositories {
    jcenter()
}

dependencies {
    implementation files("../app-remote-lib/spotify-app-remote-release-${appRemoteSampleVersionName}.aar")

    implementation "androidx.appcompat:appcompat:$appCompatVersion"
    implementation 'androidx.gridlayout:gridlayout:1.0.0'
    implementation 'androidx.constraintlayout:constraintlayout:2.0.4'
    implementation "androidx.lifecycle:lifecycle-runtime-ktx:2.3.1"
    implementation "com.google.code.gson:gson:2.8.6"
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlinVersion"
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:$kotlinCoroutinesVersion"
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-android:$kotlinCoroutinesVersion"
}